[gentoo-commits] repo/gentoo:master commit in: dev-python/qiskit-terra/

["Michał Górny" <mgorny@gentoo.org>]

commit:     e0ea7da6d585934ffd232d6fcae31d3bc80eb927
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Thu Oct 26 02:13:17 2023 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Thu Oct 26 02:13:17 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=e0ea7da6

dev-python/qiskit-terra: Bump to 0.25.3

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/qiskit-terra/Manifest                   |   1 +
 dev-python/qiskit-terra/qiskit-terra-0.25.3.ebuild | 188 +++++++++++++++++++++
 2 files changed, 189 insertions(+)

diff --git a/dev-python/qiskit-terra/Manifest b/dev-python/qiskit-terra/Manifest
index df08ffda80e6..61a46a1ab8d6 100644
--- a/dev-python/qiskit-terra/Manifest
+++ b/dev-python/qiskit-terra/Manifest
@@ -47,6 +47,7 @@ DIST pyo3-macros-backend-0.19.1.crate 49916 BLAKE2B 930774ee7ec936bbefc4ea81e249
 DIST pyo3-macros-backend-0.19.2.crate 49962 BLAKE2B 9d8a032c2205f55d2431b6bbc40df153339e08479df3a8a65506ade7d1f3d17cfaf664cbd09eaec9acff3f5a248598e37427d0c5a531eaf527137803adf49834 SHA512 fd708e6fdbd54ef7c676bedc62070175bac6b8f7ae11231578196dbf552b163a8a2499a1266f786bb6bfb85517fe83610902137d59a5c42efcb1a27c4235a07e
 DIST qiskit-0.25.1.gh.tar.gz 12138283 BLAKE2B 6fcc24f01888d1e1e8a2dbc491f361d1fb2afd306cfa5da9ffd26e7448224a210ce3e7ab1ecf04efb36be7c85a6ccbf71a8d4817a291fe0af1b66e6297d1e6e1 SHA512 bc1fefcabacfaa65cef35f0a9fbdb04f42a188ef811e2115b0e44dbc85d2cb8f2c6c1403e0d59728b7f69b5ff7420808abd8aafa422640ad5df967275f763523
 DIST qiskit-0.25.2.gh.tar.gz 12330466 BLAKE2B 6bf11f841372a4be5e836457c87ce30b70a93f4e00cdd4af32f17bcbe9af5fd6c09f92f6734888c899ddf5dba59fa3b249995dcf85df2606b55a727562e4dc0e SHA512 e6b19990ad3e4e540817b8134e772bbcb772f9755cde6fe3a7e241bc4f0bc92f501bfd0ef52311394e7297e685aeb1d2c1a8494fce54dc784fe84c16884f507f
+DIST qiskit-0.25.3.gh.tar.gz 12335701 BLAKE2B b9263523c908fa755cfb811398d6c8dda146fb1e0210be23336db272aa3bebadca24c44ecad27f79973af1a24fd5e7345d08c4ed7634168860d69421fa758c3b SHA512 27dfa1da4a61cadd1fa9fa412cfa79fd4824b2bed586a73ec69481a07c0598691288bbd851f0821b5d509eb93c6ff585b8b8fc83ce1a3e8091cc1d35c4960250
 DIST qiskit-terra-0.25.0.gh.tar.gz 10378062 BLAKE2B 6c5a30f9e3d8ffb8ac6415b1afbe4965031aae5e9959d9aa6b5a0fe7f269e0d61958161be5c67a22f861a8ba474ba37d197e51ac1b89340725729be0a6906cab SHA512 9c50c71a956d46858dc7e9d3634dc71f71a079c89b2651eb5dd5e921628bd64e73c6779dc70cbac5b6186c7374023ac6b036472213ce447aee6817fd0a433288
 DIST quote-1.0.28.crate 28382 BLAKE2B 9fb16c3bb2a7fec3d8138ffec1f58277061f4a643c9051e1f6525f9e347ed9de41a3797eb3140a6dd828526eb4114c1f7ca562151dc933f338d64b175ed35d9f SHA512 846d718153f78cbae6dc714caa9413a5d5964bcc5e032f5c6c5356c62c33bf22635955ebdff0dede69ba1c9657387e65d61de7c537f6f56f8060721dfa52d735
 DIST rand-0.8.5.crate 87113 BLAKE2B 516f26bb2a969d0d79e957818133f35d2c0b4d9f1b401098ea23c5b80d27599e842b9298c0c5e46e2a6cb6953857bf8a9fb71ec9366c5ce6708cf17df14f179c SHA512 8b33a8988906ba5e2057a9a84bdd11f867a5536c22f5056eec59ed4ec4e3a6da2fd773da4c0510d343762e5a4ea0f007db4c4a7cef87a47f90e36c1a84d86fb2

diff --git a/dev-python/qiskit-terra/qiskit-terra-0.25.3.ebuild b/dev-python/qiskit-terra/qiskit-terra-0.25.3.ebuild
new file mode 100644
index 000000000000..e6bed22000a8
--- /dev/null
+++ b/dev-python/qiskit-terra/qiskit-terra-0.25.3.ebuild
@@ -0,0 +1,188 @@
+# Copyright 2022-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..11} )
+
+CRATES="
+	ahash@0.7.6
+	ahash@0.8.3
+	autocfg@1.1.0
+	bitflags@1.3.2
+	cfg-if@1.0.0
+	crossbeam-channel@0.5.8
+	crossbeam-deque@0.8.3
+	crossbeam-epoch@0.9.14
+	crossbeam-utils@0.8.15
+	either@1.8.1
+	fixedbitset@0.4.2
+	getrandom@0.2.9
+	hashbrown@0.12.3
+	hermit-abi@0.2.6
+	indexmap@1.9.3
+	indoc@1.0.9
+	itertools@0.10.5
+	libc@0.2.144
+	libm@0.2.7
+	lock_api@0.4.9
+	matrixmultiply@0.3.7
+	memoffset@0.8.0
+	memoffset@0.9.0
+	ndarray@0.15.6
+	num-bigint@0.4.3
+	num-complex@0.4.3
+	num-integer@0.1.45
+	num-traits@0.2.15
+	num_cpus@1.15.0
+	numpy@0.19.0
+	once_cell@1.17.2
+	parking_lot@0.12.1
+	parking_lot_core@0.9.7
+	petgraph@0.6.3
+	ppv-lite86@0.2.17
+	priority-queue@1.3.1
+	proc-macro2@1.0.59
+	pyo3-build-config@0.19.2
+	pyo3-ffi@0.19.2
+	pyo3-macros-backend@0.19.2
+	pyo3-macros@0.19.2
+	pyo3@0.19.2
+	quote@1.0.28
+	rand@0.8.5
+	rand_chacha@0.3.1
+	rand_core@0.6.4
+	rand_distr@0.4.3
+	rand_pcg@0.3.1
+	rawpointer@0.2.1
+	rayon-cond@0.2.0
+	rayon-core@1.11.0
+	rayon@1.7.0
+	redox_syscall@0.2.16
+	rustc-hash@1.1.0
+	rustworkx-core@0.13.1
+	scopeguard@1.1.0
+	smallvec@1.10.0
+	syn@1.0.109
+	target-lexicon@0.12.7
+	unicode-ident@1.0.9
+	unindent@0.1.11
+	version_check@0.9.4
+	wasi@0.11.0+wasi-snapshot-preview1
+	windows-sys@0.45.0
+	windows-targets@0.42.2
+	windows_aarch64_gnullvm@0.42.2
+	windows_aarch64_msvc@0.42.2
+	windows_i686_gnu@0.42.2
+	windows_i686_msvc@0.42.2
+	windows_x86_64_gnu@0.42.2
+	windows_x86_64_gnullvm@0.42.2
+	windows_x86_64_msvc@0.42.2
+"
+
+inherit cargo distutils-r1 multiprocessing optfeature
+
+MY_P=qiskit-${PV}
+DESCRIPTION="Terra is the foundation on which Qiskit is built"
+HOMEPAGE="
+	https://github.com/Qiskit/qiskit/
+	https://pypi.org/project/qiskit-terra/
+"
+SRC_URI="
+	https://github.com/Qiskit/qiskit/archive/${PV}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+	${CARGO_CRATE_URIS}
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="Apache-2.0"
+# Dependent crate licenses
+LICENSE+="
+	Apache-2.0 Apache-2.0-with-LLVM-exceptions BSD-2 MIT
+	Unicode-DFS-2016
+	|| ( LGPL-3 MPL-2.0 )
+"
+SLOT="0"
+IUSE="+visualization"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	>=dev-python/rustworkx-0.13.0[${PYTHON_USEDEP}]
+	>=dev-python/numpy-1.17[${PYTHON_USEDEP}]
+	>=dev-python/ply-3.10[${PYTHON_USEDEP}]
+	>=dev-python/psutil-5[${PYTHON_USEDEP}]
+	>=dev-python/scipy-1.5[${PYTHON_USEDEP}]
+	>=dev-python/sympy-1.3[${PYTHON_USEDEP}]
+	>=dev-python/dill-0.3[${PYTHON_USEDEP}]
+	>=dev-python/python-constraint-1.4[${PYTHON_USEDEP}]
+	>=dev-python/python-dateutil-2.8.0[${PYTHON_USEDEP}]
+	>=dev-python/stevedore-3.0.0[${PYTHON_USEDEP}]
+	<dev-python/symengine-0.10[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		dev-python/typing-extensions[${PYTHON_USEDEP}]
+	' 3.10)
+	visualization? (
+		>=dev-python/matplotlib-3.3[${PYTHON_USEDEP}]
+		>=dev-python/ipywidgets-7.3.0[${PYTHON_USEDEP}]
+		dev-python/pydot[${PYTHON_USEDEP}]
+		>=dev-python/pillow-4.2.1[${PYTHON_USEDEP}]
+		>=dev-python/pylatexenc-1.4[${PYTHON_USEDEP}]
+		>=dev-python/seaborn-0.9.0[${PYTHON_USEDEP}]
+		>=dev-python/pygments-2.4[${PYTHON_USEDEP}]
+	)
+"
+BDEPEND="
+	>=dev-python/cython-0.27.1[${PYTHON_USEDEP}]
+	test? (
+		app-text/poppler[png]
+		>=dev-python/ddt-1.4.4[${PYTHON_USEDEP}]
+		>=dev-python/hypothesis-4.24.3[${PYTHON_USEDEP}]
+		>=dev-python/networkx-2.2[${PYTHON_USEDEP}]
+		dev-python/pytest-xdist[${PYTHON_USEDEP}]
+		dev-python/qiskit-aer[${PYTHON_USEDEP}]
+		>=sci-libs/scikit-learn-0.20.0[${PYTHON_USEDEP}]
+	)
+"
+
+# Files built without CFLAGS/LDFLAGS, acceptable for rust
+QA_FLAGS_IGNORED="
+	usr/lib.*/py.*/site-packages/qiskit/_accelerate.*.so
+	usr/lib.*/py.*/site-packages/qiskit/_qasm2.*.so
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	# strip forcing -Werror from tests that also leaks to other packages
+	sed -i -e '/filterwarnings.*error/d' qiskit/test/base.py || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# TODO
+		test/python/circuit/test_equivalence.py::TestEquivalenceLibraryVisualization::test_equivalence_draw
+		test/python/primitives/test_backend_estimator.py::TestBackendEstimator::test_bound_pass_manager
+		test/python/primitives/test_backend_sampler.py::TestBackendSampler::test_bound_pass_manager
+		test/python/transpiler/test_unitary_synthesis_plugin.py::TestUnitarySynthesisPlugin
+		test/python/visualization/test_dag_drawer.py::TestDagDrawer::test_dag_drawer_no_register
+	)
+
+	local EPYTEST_IGNORE=(
+		# Breaks xdist
+		test/python/qasm2/test_parse_errors.py
+	)
+
+	rm -rf qiskit || die
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	# Run the Python test suite rather than everything under test/ which
+	# includes the 'randomized' suite. Upstream run that in a separate CI job.
+	# Note: use -p timeout --timeout 500 if debugging hanging tests.
+	epytest -p xdist -n "$(makeopts_jobs)" --dist=worksteal test/python
+}
+
+pkg_postinst() {
+	optfeature "qiskit.circuit.classicalfunction support" dev-python/tweedledum
+}