[gentoo-commits] repo/gentoo:master commit in: dev-python/testtools/

["Sam James" <sam@gentoo.org>]

commit:     aa3a4aa3961c81edf41334987867c9c025895445
Author:     Eli Schwartz <eschwartz93 <AT> gmail <DOT> com>
AuthorDate: Wed Oct 18 02:54:53 2023 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Wed Oct 25 02:22:26 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=aa3a4aa3

dev-python/testtools: remove outdated runtime dependency on six

Removed upstream in 2.5.0:
https://github.com/testing-cabal/testtools/commit/8e8bf526b760b1c49c0ec1b1a0f4bd91bd34115a

Signed-off-by: Eli Schwartz <eschwartz93 <AT> gmail.com>
Closes: https://github.com/gentoo/gentoo/pull/33500
Signed-off-by: Sam James <sam <AT> gentoo.org>

 dev-python/testtools/testtools-2.6.0-r2.ebuild | 51 ++++++++++++++++++++++++++
 1 file changed, 51 insertions(+)

diff --git a/dev-python/testtools/testtools-2.6.0-r2.ebuild b/dev-python/testtools/testtools-2.6.0-r2.ebuild
new file mode 100644
index 000000000000..c697f34611ea
--- /dev/null
+++ b/dev-python/testtools/testtools-2.6.0-r2.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..12} pypy3 )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Extensions to the Python standard library unit testing framework"
+HOMEPAGE="
+	https://github.com/testing-cabal/testtools/
+	https://pypi.org/project/testtools/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 sparc x86 ~amd64-linux ~x86-linux ~x64-macos"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-python/pbr-0.11[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		>=dev-python/fixtures-2.0.0[${PYTHON_USEDEP}]
+		dev-python/testscenarios[${PYTHON_USEDEP}]
+		dev-python/testresources[${PYTHON_USEDEP}]
+	)
+"
+PDEPEND="
+	>=dev-python/fixtures-2.0.0[${PYTHON_USEDEP}]
+"
+
+distutils_enable_sphinx doc
+
+src_prepare() {
+	# very fragile to formatting changes (broken on py3.10 & pypy3)
+	sed -i -e 's:test_syntax_error(:_&:' \
+		testtools/tests/test_testresult.py || die
+
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	"${PYTHON}" -m testtools.run testtools.tests.test_suite ||
+		die "tests failed under ${EPYTHON}"
+}