[gentoo-commits] repo/gentoo:master commit in: dev-ruby/bigdecimal/

["Hans de Graaff" <graaff@gentoo.org>]

commit:     8038355b3aa88682795772fcabc148c0a2e79cf3
Author:     Hans de Graaff <graaff <AT> gentoo <DOT> org>
AuthorDate: Fri Oct 13 05:36:57 2023 +0000
Commit:     Hans de Graaff <graaff <AT> gentoo <DOT> org>
CommitDate: Fri Oct 13 05:37:19 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=8038355b

dev-ruby/bigdecimal: fix gemspec

Signed-off-by: Hans de Graaff <graaff <AT> gentoo.org>

 dev-ruby/bigdecimal/bigdecimal-3.1.4-r1.ebuild | 32 ++++++++++++++++++++++++++
 1 file changed, 32 insertions(+)

diff --git a/dev-ruby/bigdecimal/bigdecimal-3.1.4-r1.ebuild b/dev-ruby/bigdecimal/bigdecimal-3.1.4-r1.ebuild
new file mode 100644
index 000000000000..d2aa1a8266e2
--- /dev/null
+++ b/dev-ruby/bigdecimal/bigdecimal-3.1.4-r1.ebuild
@@ -0,0 +1,32 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+USE_RUBY="ruby31 ruby32"
+
+RUBY_FAKEGEM_BINWRAP=""
+RUBY_FAKEGEM_EXTENSIONS=(ext/bigdecimal/extconf.rb)
+RUBY_FAKEGEM_EXTRADOC="CHANGES.md README.md"
+RUBY_FAKEGEM_GEMSPEC="bigdecimal.gemspec"
+
+inherit ruby-fakegem
+
+DESCRIPTION="Arbitrary-precision decimal floating-point number library for Ruby"
+HOMEPAGE="https://github.com/ruby/bigdecimal"
+SRC_URI="https://github.com/ruby/bigdecimal/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="|| ( Ruby-BSD BSD-2 )"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x64-solaris"
+SLOT="0"
+IUSE="test"
+
+all_ruby_prepare() {
+	sed -e '/^source_version/,/^end/ s:^:#:' \
+		-e "/s.version/ s/= source_version/= '${PV}'/" \
+		-e "/s.name/ s/= name/= 'bigdecimal'/" \
+		-i ${RUBY_FAKEGEM_GEMSPEC} || die
+}
+
+each_ruby_test() {
+	${RUBY} -Ilib:test:. -rtest/lib/helper -e "Dir['test/**/test_*.rb'].each { require _1 }" || die
+}