From mboxrd@z Thu Jan 1 00:00:00 1970
Return-Path: <gentoo-commits+bounces-1559870-garchives=archives.gentoo.org@lists.gentoo.org>
Received: from lists.gentoo.org (pigeon.gentoo.org [208.92.234.80])
(using TLSv1.3 with cipher TLS_AES_256_GCM_SHA384 (256/256 bits)
key-exchange X25519 server-signature RSA-PSS (2048 bits))
(No client certificate requested)
by finch.gentoo.org (Postfix) with ESMTPS id 4DCF615814C
for <garchives@archives.gentoo.org>; Wed, 4 Oct 2023 17:43:51 +0000 (UTC)
Received: from pigeon.gentoo.org (localhost [127.0.0.1])
by pigeon.gentoo.org (Postfix) with SMTP id 8985F2BC109;
Wed, 4 Oct 2023 17:43:50 +0000 (UTC)
Received: from smtp.gentoo.org (woodpecker.gentoo.org [140.211.166.183])
(using TLSv1.3 with cipher TLS_AES_256_GCM_SHA384 (256/256 bits)
key-exchange X25519 server-signature RSA-PSS (4096 bits))
(No client certificate requested)
by pigeon.gentoo.org (Postfix) with ESMTPS id 6C0482BC109
for <gentoo-commits@lists.gentoo.org>; Wed, 4 Oct 2023 17:43:50 +0000 (UTC)
Received: from oystercatcher.gentoo.org (oystercatcher.gentoo.org [148.251.78.52])
(using TLSv1.3 with cipher TLS_AES_256_GCM_SHA384 (256/256 bits)
key-exchange X25519 server-signature RSA-PSS (4096 bits))
(No client certificate requested)
by smtp.gentoo.org (Postfix) with ESMTPS id 8182D335D0D
for <gentoo-commits@lists.gentoo.org>; Wed, 4 Oct 2023 17:43:49 +0000 (UTC)
Received: from localhost.localdomain (localhost [IPv6:::1])
by oystercatcher.gentoo.org (Postfix) with ESMTP id CC6D999C
for <gentoo-commits@lists.gentoo.org>; Wed, 4 Oct 2023 17:43:47 +0000 (UTC)
From: "Michał Górny" <mgorny@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Content-Transfer-Encoding: 8bit
Content-type: text/plain; charset=UTF-8
Reply-To: gentoo-dev@lists.gentoo.org, "Michał Górny" <mgorny@gentoo.org>
Message-ID: <1696441414.b2ec8436b538ec2a8141e022cb14a6ac722540b2.mgorny@gentoo>
Subject: [gentoo-commits] repo/gentoo:master commit in: dev-python/django/
X-VCS-Repository: repo/gentoo
X-VCS-Files: dev-python/django/Manifest dev-python/django/django-4.2.6.ebuild
X-VCS-Directories: dev-python/django/
X-VCS-Committer: mgorny
X-VCS-Committer-Name: Michał Górny
X-VCS-Revision: b2ec8436b538ec2a8141e022cb14a6ac722540b2
X-VCS-Branch: master
Date: Wed, 4 Oct 2023 17:43:47 +0000 (UTC)
Precedence: bulk
List-Post: <mailto:gentoo-commits@lists.gentoo.org>
List-Help: <mailto:gentoo-commits+help@lists.gentoo.org>
List-Unsubscribe: <mailto:gentoo-commits+unsubscribe@lists.gentoo.org>
List-Subscribe: <mailto:gentoo-commits+subscribe@lists.gentoo.org>
List-Id: Gentoo Linux mail <gentoo-commits.gentoo.org>
X-BeenThere: gentoo-commits@lists.gentoo.org
X-Auto-Response-Suppress: DR, RN, NRN, OOF, AutoReply
X-Archives-Salt: ae1d1f19-d3af-4bda-88c0-ced894ac76e3
X-Archives-Hash: ff153ddcd9c657b18ec7bd9b62f9fe0d
commit: b2ec8436b538ec2a8141e022cb14a6ac722540b2
Author: Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Wed Oct 4 16:51:18 2023 +0000
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Wed Oct 4 17:43:34 2023 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=b2ec8436
dev-python/django: Bump to 4.2.6
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>
dev-python/django/Manifest | 2 +
dev-python/django/django-4.2.6.ebuild | 98 +++++++++++++++++++++++++++++++++++
2 files changed, 100 insertions(+)
diff --git a/dev-python/django/Manifest b/dev-python/django/Manifest
index 46847fde1cc5..0ecd4ab9dcde 100644
--- a/dev-python/django/Manifest
+++ b/dev-python/django/Manifest
@@ -4,3 +4,5 @@ DIST Django-4.1.11.checksum.txt 2564 BLAKE2B 55021666213384900c1871d939594bcb38b
DIST Django-4.1.11.tar.gz 10511539 BLAKE2B 9c4c5d6d1d56f064737dc38fe6e8ace77ca166790471806c701040afb4b05034104d4f70a177ee65aab3f41b7e52418b254148cb72e9db61a77c97fb57808ce0 SHA512 00e546c26f5a5f5f3d15b1524922a9d25d04b1b5291ee669369462831ba0c9027ca1369ac1a442b6f2216c453b89acade777513ac1a93ca3274b7e9291bf9d60
DIST Django-4.2.5.checksum.txt 2554 BLAKE2B 7c0e9719a28a19bccbf8dc95e2d4ea07f5307b6df44f2d47c1a2a426a3021f0e1c0f83e93df256c64bb11a9d5d45605b9fe22ac5ae20d70f8fcb5a69d5859979 SHA512 4aaab80511a0442fb65ead16a468e2d2a152f1fea6c9a631e79933c6be43e0077aa443cbe13c6a9776b5a897b57c976d9b7b3e1472156b1a3e3f7d865ca79eb3
DIST Django-4.2.5.tar.gz 10418606 BLAKE2B 271745dce0ec4d03f118afb328d0154e3e42a29775cb05dd8271f114770e568da19f0c9e3a2dd28379ad0e7dd0d89db37cd64856d2af5927fbe02fccd7bf1e91 SHA512 bf6a7bbb8f0a47d1e97ad9a231340567e5ee10bf399be6ff0edc2538db8cb8a082ea93529954140e7fab0672654e6fe9238d61381419495b53737b4a6dc9de1e
+DIST Django-4.2.6.checksum.txt 2572 BLAKE2B 1bdd9b4a11e80bcbb7c857c25bd9666b1a14c9aeebe3654afe4c54232dc105bb2843d6444b1ab17c86cd19f4722bdfca537291f42d1b4f82e551b44c27cb8e1e SHA512 7857a1d666c4dc9605bfe89e2c6f6ff7dc863ae2c5bb8846d8e83d9cc59592cce2240204b688adba4ebeb7f5279a54ccd4150654ffbed27e1ffc2c4c436ed950
+DIST Django-4.2.6.tar.gz 10407018 BLAKE2B d2d365d234aecd730bcffd64cdfaee283933779be339d1baa75cf490fe7477248feb079c8716f3c8dc570c54bf6af94ce9864908f1efdbf69e5b6e9369126cf7 SHA512 bfd36ae6f7c4393bad45e97d6d43b370fb37d7e21cd115a6f6b730bb38ad11c6ccdcef94d5ddcd09e8eb9107a51ff486ec79b39cf3f4250d0ae1af000820cd82
diff --git a/dev-python/django/django-4.2.6.ebuild b/dev-python/django/django-4.2.6.ebuild
new file mode 100644
index 000000000000..0afb8410b128
--- /dev/null
+++ b/dev-python/django/django-4.2.6.ebuild
@@ -0,0 +1,98 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..12} )
+PYTHON_REQ_USE='sqlite?,threads(+)'
+
+inherit bash-completion-r1 distutils-r1 optfeature verify-sig
+
+DESCRIPTION="High-level Python web framework"
+HOMEPAGE="
+ https://www.djangoproject.com/
+ https://github.com/django/django/
+ https://pypi.org/project/Django/
+"
+SRC_URI="
+ https://media.djangoproject.com/releases/$(ver_cut 1-2)/${P^}.tar.gz
+ verify-sig? ( https://media.djangoproject.com/pgp/${P^}.checksum.txt )
+"
+S="${WORKDIR}/${P^}"
+
+LICENSE="BSD"
+# admin fonts: Roboto (media-fonts/roboto)
+LICENSE+=" Apache-2.0"
+# admin icons, jquery, xregexp.js
+LICENSE+=" MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~sparc ~x86 ~x64-macos"
+IUSE="doc sqlite test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+ <dev-python/asgiref-4[${PYTHON_USEDEP}]
+ >=dev-python/asgiref-3.6.0[${PYTHON_USEDEP}]
+ >=dev-python/sqlparse-0.3.1[${PYTHON_USEDEP}]
+"
+BDEPEND="
+ test? (
+ $(python_gen_impl_dep sqlite)
+ ${RDEPEND}
+ dev-python/docutils[${PYTHON_USEDEP}]
+ dev-python/jinja[${PYTHON_USEDEP}]
+ dev-python/numpy[${PYTHON_USEDEP}]
+ dev-python/pillow[webp,${PYTHON_USEDEP}]
+ dev-python/pyyaml[${PYTHON_USEDEP}]
+ dev-python/selenium[${PYTHON_USEDEP}]
+ dev-python/tblib[${PYTHON_USEDEP}]
+ sys-devel/gettext
+ )
+ verify-sig? ( >=sec-keys/openpgp-keys-django-20230606 )
+"
+
+PATCHES=(
+ "${FILESDIR}"/django-4.0-bashcomp.patch
+ "${FILESDIR}"/django-4.2.3-py312.patch
+)
+
+distutils_enable_sphinx docs --no-autodoc
+
+VERIFY_SIG_OPENPGP_KEY_PATH=${BROOT}/usr/share/openpgp-keys/django.asc
+
+src_unpack() {
+ if use verify-sig; then
+ cd "${DISTDIR}" || die
+ verify-sig_verify_signed_checksums \
+ "${P^}.checksum.txt" sha256 "${P^}.tar.gz"
+ cd "${WORKDIR}" || die
+ fi
+
+ default
+}
+
+python_test() {
+ # Tests have non-standard assumptions about PYTHONPATH,
+ # and don't work with ${BUILD_DIR}/lib.
+ PYTHONPATH=. "${EPYTHON}" tests/runtests.py --settings=test_sqlite -v2 ||
+ die "Tests fail with ${EPYTHON}"
+}
+
+python_install_all() {
+ newbashcomp extras/django_bash_completion ${PN}-admin
+ bashcomp_alias ${PN}-admin django-admin.py
+
+ distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+ optfeature_header "Additional Backend support can be enabled via:"
+ optfeature "MySQL backend support" dev-python/mysqlclient
+ optfeature "PostgreSQL backend support" dev-python/psycopg:2
+ optfeature_header
+ optfeature "GEO Django" "sci-libs/gdal[geos]"
+ optfeature "Memcached support" dev-python/pylibmc dev-python/python-memcached
+ optfeature "ImageField Support" dev-python/pillow
+ optfeature "Password encryption" dev-python/bcrypt
+}