[gentoo-commits] repo/gentoo:master commit in: app-emulation/86Box/

["Conrad Kostecki" <conikost@gentoo.org>]

commit:     3a3c5cf71f90d8f0f712a2b18204e0a53df23346
Author:     Conrad Kostecki <conikost <AT> gentoo <DOT> org>
AuthorDate: Wed Oct  4 16:46:01 2023 +0000
Commit:     Conrad Kostecki <conikost <AT> gentoo <DOT> org>
CommitDate: Wed Oct  4 16:46:01 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=3a3c5cf7

app-emulation/86Box: add 4.0

Signed-off-by: Conrad Kostecki <conikost <AT> gentoo.org>

 app-emulation/86Box/86Box-4.0.ebuild | 77 ++++++++++++++++++++++++++++++++++++
 app-emulation/86Box/Manifest         |  1 +
 2 files changed, 78 insertions(+)

diff --git a/app-emulation/86Box/86Box-4.0.ebuild b/app-emulation/86Box/86Box-4.0.ebuild
new file mode 100644
index 000000000000..e7aba1c39380
--- /dev/null
+++ b/app-emulation/86Box/86Box-4.0.ebuild
@@ -0,0 +1,77 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake flag-o-matic
+
+DESCRIPTION="Emulator of x86-based machines based on PCem"
+HOMEPAGE="https://github.com/86Box/86Box"
+SRC_URI="https://github.com/${PN}/${PN}/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="dinput experimental +fluidsynth +munt new-dynarec +openal +qt5 +threads"
+
+DEPEND="
+	app-emulation/faudio
+	dev-libs/libevdev
+	media-libs/freetype:2=
+	media-libs/libpng:=
+	media-libs/libsdl2
+	media-libs/openal
+	media-libs/rtmidi
+	net-libs/libslirp
+	sys-libs/zlib
+	qt5? ( x11-libs/libXi )
+"
+
+RDEPEND="
+	${DEPEND}
+	fluidsynth? ( media-sound/fluidsynth )
+	munt? ( media-libs/munt-mt32emu )
+	openal? ( media-libs/openal )
+	qt5? (
+		dev-qt/qtcore:5
+		dev-qt/qtgui:5
+		dev-qt/qtnetwork:5
+		dev-qt/qtopengl:5
+		dev-qt/qttranslations:5
+		dev-qt/qtwidgets:5
+		kde-frameworks/extra-cmake-modules
+	)
+"
+
+BDEPEND="virtual/pkgconfig"
+
+src_configure() {
+	# LTO needs to be filtered
+	# See https://bugs.gentoo.org/854507
+	filter-lto
+	append-flags -fno-strict-aliasing
+
+	local mycmakeargs=(
+		-DCPPTHREADS="$(usex threads)"
+		-DDEV_BRANCH="$(usex experimental)"
+		-DDINPUT="$(usex dinput)"
+		-DDYNAREC="ON"
+		-DMUNT_EXTERNAL="$(usex munt)"
+		-DFLUIDSYNTH="$(usex fluidsynth)"
+		-DMINITRACE="OFF"
+		-DMUNT="$(usex munt)"
+		-DNEW_DYNAREC="$(usex new-dynarec)"
+		-DOPENAL="$(usex openal)"
+		-DPREFER_STATIC="OFF"
+		-DRTMIDI="ON"
+		-DQT="$(usex qt5)"
+		-DRELEASE="ON"
+	)
+
+	cmake_src_configure
+}
+
+pkg_postinst() {
+	elog "In order to use 86Box, you will need some roms for various emulated systems."
+	elog "See https://github.com/86Box/roms for more information."
+}

diff --git a/app-emulation/86Box/Manifest b/app-emulation/86Box/Manifest
index 60085919aa58..38878222668a 100644
--- a/app-emulation/86Box/Manifest
+++ b/app-emulation/86Box/Manifest
@@ -1 +1,2 @@
 DIST 86Box-3.11.tar.gz 4593971 BLAKE2B 0b2771492910f0c11835104e5ef7495ca052414a959e27732ec0d72bc6a6f4cb46c386f0642042425cfd4c4aa1b16e24e027e53034ffae618d9c51aff282cdf7 SHA512 4705f0bb7186a19b8a74450132a73c01e9fae80809e7cebf2ef0294100081ff6a27e0f81dbc661596a8d1cd7b04afc5dddb3e990dd10951a37a48de338c49a77
+DIST 86Box-4.0.tar.gz 5200746 BLAKE2B 74f702d7be42ee84a4ca337e13bb77ec3fb89b1e78018807d8ced63e474905799f1cf6bf7c093f17dedcc6da0c07b0283f9e2c490f3b3f7ba3c4f1689988b8d4 SHA512 8465e86e44bb5fa260f0550479e877a0f4a407eb59a00db8bab6764fecb292b8c9a370451eb71adbf84db990d7ea70e001cd1b2bc096c95caa7526901d20833e