[gentoo-commits] repo/gentoo:master commit in: dev-util/heaptrack/

["Andreas Sturmlechner" <asturm@gentoo.org>]

commit:     9e9c0e1fbd50eae0c6afa203e22c81a983761c7a
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Mon Oct  2 18:02:16 2023 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Tue Oct  3 19:20:55 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=9e9c0e1f

dev-util/heaptrack: add 1.5.0

Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 dev-util/heaptrack/Manifest               |  1 +
 dev-util/heaptrack/heaptrack-1.5.0.ebuild | 71 +++++++++++++++++++++++++++++++
 2 files changed, 72 insertions(+)

diff --git a/dev-util/heaptrack/Manifest b/dev-util/heaptrack/Manifest
index cb37c6e788cd..704ded416de6 100644
--- a/dev-util/heaptrack/Manifest
+++ b/dev-util/heaptrack/Manifest
@@ -1 +1,2 @@
 DIST heaptrack-1.4.0.tar.xz 5526100 BLAKE2B ffb912bc080cf966d670fcafcce682ddc5793878b73b8480b40aaf6b3c9596e892b646f9ca2ce40c195ed32d595e265e9c3a49095ac725b95a0845b2c4a7a81a SHA512 8d34356c9ecf2f9901e15ff7f24e6772e35d31ea9634d7b3ce5615df6f4f7ed024a7a4336f3b6fca648632c4c1693411641782fe60bf4cfeeb1d07d8607636a4
+DIST heaptrack-1.5.0.tar.xz 5447668 BLAKE2B f4a69311267daf9439e264bf8bb9802db41abb3fa766e5dfc8fcfe39c58feab2d0fe32710c6b5a2d63715e8b013e4a81e2984de425be871e253b1b2567a1dca2 SHA512 b52cc63a29d67dade85f40a7f9abb43e104762b9c853385f501d37fcbcef90fdcdfc93e2900c71b5a47c773bf98fe75f66f8b6a9e31a12610b6deec20d9736aa

diff --git a/dev-util/heaptrack/heaptrack-1.5.0.ebuild b/dev-util/heaptrack/heaptrack-1.5.0.ebuild
new file mode 100644
index 000000000000..55b236232d02
--- /dev/null
+++ b/dev-util/heaptrack/heaptrack-1.5.0.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake kde.org xdg-utils
+
+DESCRIPTION="Fast heap memory profiler"
+HOMEPAGE="https://apps.kde.org/heaptrack/
+https://milianw.de/blog/heaptrack-a-heap-memory-profiler-for-linux"
+SRC_URI="mirror://kde/stable/${PN}/${PV}/${P}.tar.xz"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="+gui test zstd"
+
+RESTRICT="!test? ( test )"
+
+DEPEND="
+	dev-libs/boost:=[zstd?,zlib]
+	sys-libs/libunwind:=
+	sys-libs/zlib
+	gui? (
+		dev-libs/kdiagram:5
+		dev-qt/qtcore:5
+		dev-qt/qtgui:5
+		dev-qt/qtwidgets:5
+		kde-frameworks/kconfig:5
+		kde-frameworks/kconfigwidgets:5
+		kde-frameworks/kcoreaddons:5
+		kde-frameworks/ki18n:5
+		kde-frameworks/kio:5
+		kde-frameworks/kitemmodels:5
+		kde-frameworks/kwidgetsaddons:5
+		kde-frameworks/threadweaver:5
+	)
+	zstd? ( app-arch/zstd:= )
+"
+RDEPEND="${DEPEND}
+	gui? ( >=kde-frameworks/kf-env-4 )
+"
+BDEPEND="gui? ( kde-frameworks/extra-cmake-modules:5 )"
+
+src_prepare() {
+	cmake_src_prepare
+	rm -rf 3rdparty/boost-zstd || die # ensure no bundling
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DHEAPTRACK_BUILD_GUI=$(usex gui)
+		-DBUILD_TESTING=$(usex test)
+		$(cmake_use_find_package zstd ZSTD)
+	)
+	cmake_src_configure
+}
+
+pkg_postinst() {
+	if use gui; then
+		xdg_desktop_database_update
+		xdg_icon_cache_update
+	fi
+}
+
+pkg_postrm() {
+	if use gui; then
+		xdg_desktop_database_update
+		xdg_icon_cache_update
+	fi
+}