[gentoo-commits] repo/gentoo:master commit in: games-util/cartridges/

["Maciej Barć" <xgqt@gentoo.org>]

commit:     7ece46add92a0d0f3b91866f3c9eb92af9f9ac5e
Author:     Maciej Barć <xgqt <AT> gentoo <DOT> org>
AuthorDate: Sat Sep 16 12:52:03 2023 +0000
Commit:     Maciej Barć <xgqt <AT> gentoo <DOT> org>
CommitDate: Sat Sep 16 14:47:34 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=7ece46ad

games-util/cartridges: add live 9999

Signed-off-by: Maciej Barć <xgqt <AT> gentoo.org>

 games-util/cartridges/cartridges-9999.ebuild | 58 ++++++++++++++++++++++++++++
 1 file changed, 58 insertions(+)

diff --git a/games-util/cartridges/cartridges-9999.ebuild b/games-util/cartridges/cartridges-9999.ebuild
new file mode 100644
index 000000000000..05c8ac27f772
--- /dev/null
+++ b/games-util/cartridges/cartridges-9999.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..12} )
+
+inherit gnome2-utils meson python-single-r1 xdg
+
+DESCRIPTION="Simple game launcher written in Python using GTK4 and Libadwaita"
+HOMEPAGE="https://github.com/kra-mo/cartridges/"
+
+if [[ ${PV} == *9999* ]] ; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/kra-mo/${PN}.git"
+else
+	SRC_URI="https://github.com/kra-mo/${PN}/archive/v${PV}.tar.gz
+		-> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+LICENSE="GPL-3+"
+SLOT="0"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="
+	${PYTHON_DEPS}
+	gui-libs/gtk:4[introspection]
+	gui-libs/libadwaita:1[introspection]
+	$(python_gen_cond_dep '
+		dev-python/pygobject:3[${PYTHON_USEDEP}]
+	')
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	dev-libs/appstream-glib
+	dev-util/blueprint-compiler
+	dev-util/desktop-file-utils
+"
+
+PATCHES=( "${FILESDIR}"/${PN}-1.5.4-dont-validate-appstream.patch )
+
+src_install() {
+	meson_src_install
+
+	python_fix_shebang "${ED}"/usr/bin
+	python_optimize "${ED}"/usr/share/cartridges/cartridges
+}
+
+pkg_postinst() {
+	gnome2_schemas_update
+	xdg_pkg_postinst
+}
+
+pkg_postrm() {
+	gnome2_schemas_update
+	xdg_pkg_postrm
+}