From mboxrd@z Thu Jan 1 00:00:00 1970
Return-Path: <gentoo-commits+bounces-1555031-garchives=archives.gentoo.org@lists.gentoo.org>
Received: from lists.gentoo.org (pigeon.gentoo.org [208.92.234.80])
(using TLSv1.3 with cipher TLS_AES_256_GCM_SHA384 (256/256 bits)
key-exchange X25519 server-signature RSA-PSS (2048 bits))
(No client certificate requested)
by finch.gentoo.org (Postfix) with ESMTPS id 2EB32158089
for <garchives@archives.gentoo.org>; Sat, 16 Sep 2023 14:07:28 +0000 (UTC)
Received: from pigeon.gentoo.org (localhost [127.0.0.1])
by pigeon.gentoo.org (Postfix) with SMTP id 389B02BC026;
Sat, 16 Sep 2023 14:07:27 +0000 (UTC)
Received: from smtp.gentoo.org (woodpecker.gentoo.org [140.211.166.183])
(using TLSv1.3 with cipher TLS_AES_256_GCM_SHA384 (256/256 bits)
key-exchange X25519 server-signature RSA-PSS (4096 bits) server-digest SHA256)
(No client certificate requested)
by pigeon.gentoo.org (Postfix) with ESMTPS id E6B192BC026
for <gentoo-commits@lists.gentoo.org>; Sat, 16 Sep 2023 14:07:26 +0000 (UTC)
Received: from oystercatcher.gentoo.org (oystercatcher.gentoo.org [148.251.78.52])
(using TLSv1.3 with cipher TLS_AES_256_GCM_SHA384 (256/256 bits)
key-exchange X25519 server-signature RSA-PSS (4096 bits))
(No client certificate requested)
by smtp.gentoo.org (Postfix) with ESMTPS id ED07B335D2E
for <gentoo-commits@lists.gentoo.org>; Sat, 16 Sep 2023 14:07:25 +0000 (UTC)
Received: from localhost.localdomain (localhost [IPv6:::1])
by oystercatcher.gentoo.org (Postfix) with ESMTP id 6EBEC11BD
for <gentoo-commits@lists.gentoo.org>; Sat, 16 Sep 2023 14:07:24 +0000 (UTC)
From: "Matt Turner" <mattst88@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Content-Transfer-Encoding: 8bit
Content-type: text/plain; charset=UTF-8
Reply-To: gentoo-dev@lists.gentoo.org, "Matt Turner" <mattst88@gentoo.org>
Message-ID: <1694873240.b168e705c5286526ae3096e9313f1e74de009b84.mattst88@gentoo>
Subject: [gentoo-commits] repo/gentoo:master commit in: gnome-extra/evolution-data-server/
X-VCS-Repository: repo/gentoo
X-VCS-Files: gnome-extra/evolution-data-server/Manifest gnome-extra/evolution-data-server/evolution-data-server-3.50.0.ebuild
X-VCS-Directories: gnome-extra/evolution-data-server/
X-VCS-Committer: mattst88
X-VCS-Committer-Name: Matt Turner
X-VCS-Revision: b168e705c5286526ae3096e9313f1e74de009b84
X-VCS-Branch: master
Date: Sat, 16 Sep 2023 14:07:24 +0000 (UTC)
Precedence: bulk
List-Post: <mailto:gentoo-commits@lists.gentoo.org>
List-Help: <mailto:gentoo-commits+help@lists.gentoo.org>
List-Unsubscribe: <mailto:gentoo-commits+unsubscribe@lists.gentoo.org>
List-Subscribe: <mailto:gentoo-commits+subscribe@lists.gentoo.org>
List-Id: Gentoo Linux mail <gentoo-commits.gentoo.org>
X-BeenThere: gentoo-commits@lists.gentoo.org
X-Auto-Response-Suppress: DR, RN, NRN, OOF, AutoReply
X-Archives-Salt: 531d08d2-8bde-4436-8351-da0bd8644785
X-Archives-Hash: 77042842ef3db6e4de32726fa80a3e26
commit: b168e705c5286526ae3096e9313f1e74de009b84
Author: Guillermo Joandet <gjoandet <AT> gmail <DOT> com>
AuthorDate: Fri Sep 15 16:02:26 2023 +0000
Commit: Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Sat Sep 16 14:07:20 2023 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=b168e705
gnome-extra/evolution-data-server: Version bump to 3.50.0
Signed-off-by: Guillermo Joandet <gjoandet <AT> gmail.com>
Signed-off-by: Matt Turner <mattst88 <AT> gentoo.org>
gnome-extra/evolution-data-server/Manifest | 1 +
.../evolution-data-server-3.50.0.ebuild | 149 +++++++++++++++++++++
2 files changed, 150 insertions(+)
diff --git a/gnome-extra/evolution-data-server/Manifest b/gnome-extra/evolution-data-server/Manifest
index 1de67ace7a3a..25a3bc852d91 100644
--- a/gnome-extra/evolution-data-server/Manifest
+++ b/gnome-extra/evolution-data-server/Manifest
@@ -1 +1,2 @@
DIST evolution-data-server-3.48.4.tar.xz 4906356 BLAKE2B 13cbd21d8f6829d052227d3d328439d5f00a2cda2384ffeace791a563ed8acdcd707729ae032dbdbe16e530b2e6205c006412f1cbaa03e8fb6d669c2c75d67bd SHA512 35bc6653efdb70a110f39499945516408090f101319a3080c87f6e14f886e0f9283225c4c5b6a4c2af418b9928c5eb7fba2d319481c81af1fa87f7dd930f7215
+DIST evolution-data-server-3.50.0.tar.xz 4964568 BLAKE2B 1239bab5563e645ebf3999d1977f5b13fdbb155f70fef85904c0cbc06abba64bf79a1c9417749df1ee2f381a757f06d43e0eea1eb064ef5d6250058d9d66c823 SHA512 30a04721304e4447fbe5dccc6992ca38fd7e4ed4a6f8c846def34ee8097d31db3139b0f3b89a64c59af71b9dcd6108bfcdd60b36098b85ad96aee63f9ed5bba5
diff --git a/gnome-extra/evolution-data-server/evolution-data-server-3.50.0.ebuild b/gnome-extra/evolution-data-server/evolution-data-server-3.50.0.ebuild
new file mode 100644
index 000000000000..259c2227a577
--- /dev/null
+++ b/gnome-extra/evolution-data-server/evolution-data-server-3.50.0.ebuild
@@ -0,0 +1,149 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake db-use flag-o-matic gnome2 vala virtualx
+
+DESCRIPTION="Evolution groupware backend"
+HOMEPAGE="https://wiki.gnome.org/Apps/Evolution https://gitlab.gnome.org/GNOME/evolution-data-server"
+
+# Note: explicitly "|| ( LGPL-2 LGPL-3 )", not "LGPL-2+".
+LICENSE="|| ( LGPL-2 LGPL-3 ) BSD Sleepycat"
+SLOT="0/64-11-21-4-2-27-2-27-4-0" # subslot = libcamel-1.2/libebackend-1.2/libebook-1.2/libebook-contacts-1.2/libecal-2.0/libedata-book-1.2/libedata-cal-2.0/libedataserver-1.2/libedataserverui-1.2/libedataserverui4-1.0 soname version
+
+IUSE="berkdb +gnome-online-accounts +gtk gtk-doc +introspection ldap kerberos oauth vala +weather"
+REQUIRED_USE="
+ oauth? ( gtk )
+ vala? ( introspection )
+"
+
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~loong ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+
+# berkdb needed only for migrating old addressbook data from <3.13 versions, bug #519512
+# glib-2.70 for build-time optional GPowerProfileMonitor
+RDEPEND="
+ >=app-crypt/libsecret-0.5[crypt]
+ >=dev-db/sqlite-3.7.17:3
+ >=dev-libs/glib-2.70:2
+ >=dev-libs/libical-3.0.8:=[glib,introspection?]
+ >=dev-libs/libxml2-2
+ >=dev-libs/nspr-4.4
+ >=dev-libs/nss-3.9
+ >=net-libs/libsoup-3.1.1:3.0
+ >=dev-libs/json-glib-1.0.4
+
+ dev-libs/icu:=
+ sys-libs/zlib:=
+ virtual/libiconv
+
+ berkdb? ( >=sys-libs/db-4:= )
+ gtk? (
+ >=x11-libs/gtk+-3.20:3
+ >=gui-libs/gtk-4.4:4
+ >=media-libs/libcanberra-0.25[gtk3]
+
+ oauth? (
+ >=net-libs/webkit-gtk-2.34.0:4.1
+ >=net-libs/webkit-gtk-2.39.90:6
+ )
+ )
+ gnome-online-accounts? ( >=net-libs/gnome-online-accounts-3.8:= )
+ introspection? ( >=dev-libs/gobject-introspection-0.9.12:= )
+ kerberos? ( virtual/krb5:= )
+ ldap? ( >=net-nds/openldap-2:= )
+ weather? ( >=dev-libs/libgweather-4.2.0:4= )
+"
+DEPEND="${RDEPEND}
+ vala? ( $(vala_depend)
+ >=net-libs/libsoup-3.1.1:3.0[vala]
+ dev-libs/libical[vala]
+ )
+"
+BDEPEND="
+ dev-util/gdbus-codegen
+ dev-util/glib-utils
+ dev-util/gperf
+ gtk-doc? (
+ >=dev-util/gtk-doc-1.14
+ dev-util/gi-docgen
+ app-text/docbook-xml-dtd:4.1.2
+ )
+ >=dev-util/intltool-0.35.5
+ >=sys-devel/gettext-0.18.3
+ virtual/pkgconfig
+"
+
+# Some tests fail due to missing locales.
+# Also, dbus tests are flaky, bugs #397975 #501834
+# It looks like a nightmare to disable those for now.
+RESTRICT="!test? ( test )"
+
+# global scope PATCHES or DOCS array mustn't be used due to double default_src_prepare call
+src_prepare() {
+ use vala && vala_setup
+ cmake_src_prepare
+ gnome2_src_prepare
+
+ eapply "${FILESDIR}"/3.36.5-gtk-doc-1.32-compat.patch
+
+ # Make CMakeLists versioned vala enabled
+ sed -e "s;\(find_program(VALAC\) valac);\1 ${VALAC});" \
+ -e "s;\(find_program(VAPIGEN\) vapigen);\1 ${VAPIGEN});" \
+ -i "${S}"/CMakeLists.txt || die
+}
+
+src_configure() {
+ # /usr/include/db.h is always db-1 on FreeBSD
+ # so include the right dir in CPPFLAGS
+ use berkdb && append-cppflags "-I$(db_includedir)"
+
+ # phonenumber does not exist in tree
+ local mycmakeargs=(
+ -DSYSCONF_INSTALL_DIR="${EPREFIX}"/etc
+# -DENABLE_GI_DOCGEN=$(usex gtk-doc)
+ -DENABLE_GTK_DOC=$(usex gtk-doc)
+ -DWITH_PRIVATE_DOCS=$(usex gtk-doc)
+ -DENABLE_SCHEMAS_COMPILE=OFF
+ -DENABLE_INTROSPECTION=$(usex introspection)
+ -DWITH_KRB5=$(usex kerberos)
+ -DWITH_KRB5_INCLUDES=$(usex kerberos "${EPREFIX}"/usr "")
+ -DWITH_KRB5_LIBS=$(usex kerberos "${EPREFIX}"/usr/$(get_libdir) "")
+ -DWITH_OPENLDAP=$(usex ldap)
+ -DWITH_PHONENUMBER=OFF
+ -DENABLE_SMIME=ON
+ -DENABLE_GTK=$(usex gtk)
+ -DENABLE_GTK4=$(usex gtk)
+ -DENABLE_CANBERRA=$(usex gtk)
+ -DENABLE_OAUTH2_WEBKITGTK=$(usex oauth)
+ -DENABLE_OAUTH2_WEBKITGTK4=$(usex oauth)
+ -DENABLE_EXAMPLES=OFF
+ -DENABLE_GOA=$(usex gnome-online-accounts)
+ -DWITH_LIBDB=$(usex berkdb "${EPREFIX}"/usr OFF)
+ # ENABLE_BACKTRACES requires libdwarf ?
+ -DENABLE_IPV6=ON
+ -DENABLE_WEATHER=$(usex weather)
+ -DENABLE_LARGEFILE=ON
+ -DENABLE_VALA_BINDINGS=$(usex vala)
+ -DENABLE_TESTS=$(usex test)
+ )
+ cmake_src_configure
+}
+
+src_compile() {
+ cmake_src_compile
+}
+
+src_test() {
+ virtx cmake_src_test
+}
+
+src_install() {
+ cmake_src_install
+
+ if use ldap; then
+ insinto /etc/openldap/schema
+ doins "${FILESDIR}"/calentry.schema
+ dosym ../../../usr/share/${PN}/evolutionperson.schema /etc/openldap/schema/evolutionperson.schema
+ fi
+}