[gentoo-commits] repo/proj/guru:dev commit in: media-video/manimgl/

["Henri Gasc" <gasc@eurecom.fr>]

commit:     897e413946696b8980db21c0280f95cce0570017
Author:     Henri Gasc <gasc <AT> eurecom <DOT> fr>
AuthorDate: Wed Sep  6 08:31:16 2023 +0000
Commit:     Henri Gasc <gasc <AT> eurecom <DOT> fr>
CommitDate: Wed Sep  6 08:31:40 2023 +0000
URL:        https://gitweb.gentoo.org/repo/proj/guru.git/commit/?id=897e4139

media-video/manimgl: new package, add 1.6.1

Signed-off-by: Henri Gasc <gasc <AT> eurecom.fr>

 media-video/manimgl/Manifest             |  1 +
 media-video/manimgl/manimgl-1.6.1.ebuild | 83 ++++++++++++++++++++++++++++++++
 media-video/manimgl/metadata.xml         | 14 ++++++
 3 files changed, 98 insertions(+)

diff --git a/media-video/manimgl/Manifest b/media-video/manimgl/Manifest
new file mode 100644
index 0000000000..469a5da8d1
--- /dev/null
+++ b/media-video/manimgl/Manifest
@@ -0,0 +1 @@
+DIST manimgl-1.6.1.gh.tar.gz 1043281 BLAKE2B 70c0d4b893e1b15b536fd98e0584d2e5676802e2165407ed0cd62878120ce7f3ff43bf7eec8e16c12c95494322118215689f4138ff9dc190c86be206aa57124c SHA512 30f0675551474c690ee5dc1c9200db6aad114b0ffb14a6245f7d8edb00db9a375e291448df10a8b603527aaafba8930a445e825dd3ee3293dc125f3cfd46fee3

diff --git a/media-video/manimgl/manimgl-1.6.1.ebuild b/media-video/manimgl/manimgl-1.6.1.ebuild
new file mode 100644
index 0000000000..69c3bc7b5d
--- /dev/null
+++ b/media-video/manimgl/manimgl-1.6.1.ebuild
@@ -0,0 +1,83 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..11} )
+
+inherit distutils-r1
+
+DESCRIPTION="Animation engine for explanatory math videos"
+HOMEPAGE="https://github.com/3b1b/manim https://pypi.org/project/manimgl/"
+SRC_URI="https://github.com/3b1b/manim/archive/refs/tags/v${PV}.tar.gz -> ${P}.gh.tar.gz"
+
+S="${WORKDIR}/manim-${PV}"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="doc"
+
+RDEPEND="
+	dev-python/colour[${PYTHON_USEDEP}]
+	dev-python/fonttools[${PYTHON_USEDEP}]
+	dev-python/ipython[${PYTHON_USEDEP}]
+	dev-python/isosurfaces[${PYTHON_USEDEP}]
+	=dev-python/ManimPango-0.4*[${PYTHON_USEDEP}]
+	dev-python/mapbox_earcut[${PYTHON_USEDEP}]
+	dev-python/matplotlib[${PYTHON_USEDEP}]
+	dev-python/moderngl[${PYTHON_USEDEP}]
+	dev-python/moderngl-window[${PYTHON_USEDEP}]
+	dev-python/numpy[${PYTHON_USEDEP}]
+	dev-python/pillow[${PYTHON_USEDEP}]
+	dev-python/pydub[${PYTHON_USEDEP}]
+	dev-python/pygments[${PYTHON_USEDEP}]
+	dev-python/pyopengl[${PYTHON_USEDEP}]
+	dev-python/pyperclip[${PYTHON_USEDEP}]
+	dev-python/pyrr[${PYTHON_USEDEP}]
+	dev-python/pyyaml[${PYTHON_USEDEP}]
+	dev-python/rich[${PYTHON_USEDEP}]
+	dev-python/scipy[${PYTHON_USEDEP}]
+	dev-python/screeninfo[${PYTHON_USEDEP}]
+	dev-python/skia-pathops[${PYTHON_USEDEP}]
+	>=dev-python/svgelements-1.8.1[${PYTHON_USEDEP}]
+	dev-python/sympy[${PYTHON_USEDEP}]
+	dev-python/tqdm[${PYTHON_USEDEP}]
+	dev-python/validators[${PYTHON_USEDEP}]
+	app-text/texlive
+	media-libs/mesa
+	media-video/ffmpeg
+	x11-libs/pango
+	$(python_gen_cond_dep '
+		dev-python/typing-extensions[${PYTHON_USEDEP}]
+	' python3_{7..10})
+"
+# typing-extensions is needed for python < 3.11
+# so, only python3.10 should work too (because of PYTHON_COMPAT)
+
+BDEPEND="
+	doc? (
+		dev-python/furo[${PYTHON_USEDEP}]
+		dev-python/jinja2-cli[${PYTHON_USEDEP}]
+		dev-python/sphinx[${PYTHON_USEDEP}]
+		dev-python/sphinx-copybutton[${PYTHON_USEDEP}]
+	)
+"
+
+DEPEND="${RDEPEND}"
+
+python_compile_all() {
+	use doc && emake -C "${S}/docs" man && mv "${S}/docs/build/man/manim.1" "${S}/docs/build/man/${PN}.1"
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+	if use doc; then
+		doman "${S}/docs/build/man/${PN}.1"
+		docinto examples
+		dodoc example_scenes.py
+		dodoc docs/example.py
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+}

diff --git a/media-video/manimgl/metadata.xml b/media-video/manimgl/metadata.xml
new file mode 100644
index 0000000000..31e06ba7b6
--- /dev/null
+++ b/media-video/manimgl/metadata.xml
@@ -0,0 +1,14 @@
+<?xml version='1.0' encoding='UTF-8'?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>gasc@eurecom.fr</email>
+		<name>Gasc Henri</name>
+	</maintainer>
+	<upstream>
+		<remote-id type="pypi">manimgl</remote-id>
+		<remote-id type="github">3b1b/manim</remote-id>
+		<doc>https://3b1b.github.io/manim/</doc>
+		<changelog>https://github.com/3b1b/manim/releases</changelog>
+	</upstream>
+</pkgmetadata>