[gentoo-commits] repo/gentoo:master commit in: dev-python/qtconsole/

["Michał Górny" <mgorny@gentoo.org>]

commit:     c5ab8e36259f43b67b6c47467c1539147a0b16a8
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Sat Sep  2 17:54:12 2023 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Sat Sep  2 19:03:30 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=c5ab8e36

dev-python/qtconsole: Reenable virtualx

I can no longer reproduce the segfaults when using virtualx, so let's
reenable full testing.

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/qtconsole/qtconsole-5.4.3-r1.ebuild | 67 ++++++++++++++++++++++++++
 1 file changed, 67 insertions(+)

diff --git a/dev-python/qtconsole/qtconsole-5.4.3-r1.ebuild b/dev-python/qtconsole/qtconsole-5.4.3-r1.ebuild
new file mode 100644
index 000000000000..2dd67dae4c33
--- /dev/null
+++ b/dev-python/qtconsole/qtconsole-5.4.3-r1.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..11} )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1 pypi virtualx
+
+DESCRIPTION="Qt-based console for Jupyter with support for rich media output"
+HOMEPAGE="
+	https://jupyter.org/
+	https://github.com/jupyter/qtconsole/
+	https://pypi.org/project/qtconsole/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+
+RDEPEND="
+	>=dev-python/ipykernel-4.1[${PYTHON_USEDEP}]
+	dev-python/ipython_genutils[${PYTHON_USEDEP}]
+	dev-python/jupyter-core[${PYTHON_USEDEP}]
+	>=dev-python/jupyter-client-4.1.1[${PYTHON_USEDEP}]
+	dev-python/packaging[${PYTHON_USEDEP}]
+	dev-python/pygments[${PYTHON_USEDEP}]
+	>=dev-python/pyzmq-17.1[${PYTHON_USEDEP}]
+	>=dev-python/traitlets-5.2.2_p1[${PYTHON_USEDEP}]
+	>=dev-python/QtPy-2.0.1[${PYTHON_USEDEP},gui,printsupport,svg]
+"
+BDEPEND="
+	test? (
+		dev-python/flaky[${PYTHON_USEDEP}]
+		dev-python/pytest-qt[${PYTHON_USEDEP}]
+		dev-python/QtPy[${PYTHON_USEDEP},svg,testlib]
+	)
+"
+
+PDEPEND="
+	dev-python/ipython[${PYTHON_USEDEP}]
+"
+
+distutils_enable_sphinx docs/source dev-python/sphinx-rtd-theme
+distutils_enable_tests pytest
+
+src_test() {
+	virtx distutils-r1_src_test
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# TODO; expects exact HTML, so perhaps fragile
+		qtconsole/tests/test_jupyter_widget.py::TestJupyterWidget::test_other_output
+	)
+	local -x QT_API
+	for QT_API in pyqt5 pyqt6 pyside2 pyside6; do
+		if has_version "dev-python/QtPy[${QT_API}]"; then
+			local -x PYTEST_QT_API=${QT_API}
+			einfo "Testing with ${QT_API}"
+			nonfatal epytest ||
+				die "Tests failed with ${EPYTHON} / ${QT_API}"
+		fi
+	done
+}