From mboxrd@z Thu Jan 1 00:00:00 1970
Return-Path: <gentoo-commits+bounces-1551115-garchives=archives.gentoo.org@lists.gentoo.org>
Received: from lists.gentoo.org (pigeon.gentoo.org [208.92.234.80])
(using TLSv1.3 with cipher TLS_AES_256_GCM_SHA384 (256/256 bits)
key-exchange X25519 server-signature RSA-PSS (2048 bits))
(No client certificate requested)
by finch.gentoo.org (Postfix) with ESMTPS id AD0D215800A
for <garchives@archives.gentoo.org>; Fri, 1 Sep 2023 15:14:00 +0000 (UTC)
Received: from pigeon.gentoo.org (localhost [127.0.0.1])
by pigeon.gentoo.org (Postfix) with SMTP id E457F2BC014;
Fri, 1 Sep 2023 15:13:59 +0000 (UTC)
Received: from smtp.gentoo.org (woodpecker.gentoo.org [IPv6:2001:470:ea4a:1:5054:ff:fec7:86e4])
(using TLSv1.3 with cipher TLS_AES_256_GCM_SHA384 (256/256 bits)
key-exchange X25519 server-signature RSA-PSS (4096 bits) server-digest SHA256)
(No client certificate requested)
by pigeon.gentoo.org (Postfix) with ESMTPS id C953A2BC014
for <gentoo-commits@lists.gentoo.org>; Fri, 1 Sep 2023 15:13:59 +0000 (UTC)
Received: from oystercatcher.gentoo.org (oystercatcher.gentoo.org [148.251.78.52])
(using TLSv1.3 with cipher TLS_AES_256_GCM_SHA384 (256/256 bits)
key-exchange X25519 server-signature RSA-PSS (4096 bits) server-digest SHA256)
(No client certificate requested)
by smtp.gentoo.org (Postfix) with ESMTPS id 0F49F33BEF1
for <gentoo-commits@lists.gentoo.org>; Fri, 1 Sep 2023 15:13:59 +0000 (UTC)
Received: from localhost.localdomain (localhost [IPv6:::1])
by oystercatcher.gentoo.org (Postfix) with ESMTP id 75F2910F8
for <gentoo-commits@lists.gentoo.org>; Fri, 1 Sep 2023 15:13:57 +0000 (UTC)
From: "Matt Turner" <mattst88@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Content-Transfer-Encoding: 8bit
Content-type: text/plain; charset=UTF-8
Reply-To: gentoo-dev@lists.gentoo.org, "Matt Turner" <mattst88@gentoo.org>
Message-ID: <1693580676.28d01fabb1b13cb9716703e4b0e7f2c312df64a1.mattst88@gentoo>
Subject: [gentoo-commits] repo/gentoo:master commit in: gnome-extra/gnome-software/
X-VCS-Repository: repo/gentoo
X-VCS-Files: gnome-extra/gnome-software/Manifest gnome-extra/gnome-software/gnome-software-45_rc.ebuild
X-VCS-Directories: gnome-extra/gnome-software/
X-VCS-Committer: mattst88
X-VCS-Committer-Name: Matt Turner
X-VCS-Revision: 28d01fabb1b13cb9716703e4b0e7f2c312df64a1
X-VCS-Branch: master
Date: Fri, 1 Sep 2023 15:13:57 +0000 (UTC)
Precedence: bulk
List-Post: <mailto:gentoo-commits@lists.gentoo.org>
List-Help: <mailto:gentoo-commits+help@lists.gentoo.org>
List-Unsubscribe: <mailto:gentoo-commits+unsubscribe@lists.gentoo.org>
List-Subscribe: <mailto:gentoo-commits+subscribe@lists.gentoo.org>
List-Id: Gentoo Linux mail <gentoo-commits.gentoo.org>
X-BeenThere: gentoo-commits@lists.gentoo.org
X-Auto-Response-Suppress: DR, RN, NRN, OOF, AutoReply
X-Archives-Salt: 5a8ae266-f2a9-4550-ac79-073f01d4d823
X-Archives-Hash: f8a204ec827b7af34c4ef364d6f047fb
commit: 28d01fabb1b13cb9716703e4b0e7f2c312df64a1
Author: Guillermo Joandet <gjoandet <AT> gmail <DOT> com>
AuthorDate: Fri Sep 1 12:12:00 2023 +0000
Commit: Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Fri Sep 1 15:04:36 2023 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=28d01fab
gnome-extra/gnome-software: Version bump to 45_rc
Signed-off-by: Guillermo Joandet <gjoandet <AT> gmail.com>
Closes: https://github.com/gentoo/gentoo/pull/32549
Signed-off-by: Matt Turner <mattst88 <AT> gentoo.org>
gnome-extra/gnome-software/Manifest | 1 +
.../gnome-software/gnome-software-45_rc.ebuild | 106 +++++++++++++++++++++
2 files changed, 107 insertions(+)
diff --git a/gnome-extra/gnome-software/Manifest b/gnome-extra/gnome-software/Manifest
index f446a8dc09e3..ca96e4e2c33f 100644
--- a/gnome-extra/gnome-software/Manifest
+++ b/gnome-extra/gnome-software/Manifest
@@ -1,2 +1,3 @@
DIST gnome-software-44.4.tar.xz 2426404 BLAKE2B 6f60ffd115ad0e11b619118ae5e665fb35c70621adefe4c532481ab3742c8e2c6a5a0790dae29b2fcf0311f89fda93c323e5bc24b185bbbe95e62a687f71930d SHA512 97eaa33b4dd91a6865ee7eeee28e5acf3cf5fbd6a72a60cf5a7c528f79f6f0684014d1169318314b8efce23c1c29e7d24a71193998ced930584a50494137cf8b
DIST gnome-software-45.beta.tar.xz 2450776 BLAKE2B b14af00c87682a56a54b3cba394be57e0994a56671ccbb2016aecd492401f54e068973f7bd6278c1b55f02f0d8e1ef9de9d3408dbe2ff30634c9f78e80be044b SHA512 d4218b56478c9e7e83adf4fb8daec8d0730f5ce16cca0a0c59962894a0abb2d21c356a55f232d266aaaa4f15b21c21bc5904cc1f7b6db4d94db8889019fea092
+DIST gnome-software-45.rc.tar.xz 2466120 BLAKE2B e8d741872831f8259ce6b1dc6472250544a6aaa5c412464ddf103839fcf6907e752ae261d9ac78215d069e05bcdd2acfc0673f0db647b00f506f9206d9410843 SHA512 674c89619419cb7622bed3ce1453c31460d51ba6716db3d8bfc79829ca619e24d1f9c954f2fe72d96156e2e6dbaaf151faa29c97425b0cac132ec3e49871fb79
diff --git a/gnome-extra/gnome-software/gnome-software-45_rc.ebuild b/gnome-extra/gnome-software/gnome-software-45_rc.ebuild
new file mode 100644
index 000000000000..3ae5fd156fec
--- /dev/null
+++ b/gnome-extra/gnome-software/gnome-software-45_rc.ebuild
@@ -0,0 +1,106 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit gnome.org gnome2-utils meson virtualx xdg
+
+DESCRIPTION="Gnome install & update software"
+HOMEPAGE="https://wiki.gnome.org/Apps/Software https://gitlab.gnome.org/GNOME/gnome-software"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="flatpak +firmware gnome gtk-doc sysprof udev test"
+
+RDEPEND="
+ >=dev-libs/appstream-0.14.0:0=
+ >=x11-libs/gdk-pixbuf-2.32.0:2
+ >=dev-libs/libxmlb-0.1.7:=
+ >=gui-libs/gtk-4.10.0:4
+ >=dev-libs/glib-2.70.0:2
+ >=dev-libs/json-glib-1.6.0
+ >=net-libs/libsoup-3.0:3.0
+ >=gui-libs/libadwaita-1.3_rc:1
+ sysprof? ( >=dev-util/sysprof-capture-3.40.1:4 )
+ gnome? ( >=gnome-base/gsettings-desktop-schemas-3.18.0 )
+ sys-auth/polkit
+ firmware? ( >=sys-apps/fwupd-1.5.6 )
+ flatpak? (
+ >=sys-apps/flatpak-1.14.0-r1
+ dev-util/ostree
+ )
+ udev? ( dev-libs/libgudev )
+ >=gnome-base/gsettings-desktop-schemas-3.11.5
+"
+DEPEND="${RDEPEND}
+ test? ( dev-libs/libglib-testing )
+"
+BDEPEND="
+ dev-libs/libxml2:2
+ dev-util/gdbus-codegen
+ >=sys-devel/gettext-0.19.8
+ virtual/pkgconfig
+ gtk-doc? (
+ dev-util/gtk-doc
+ app-text/docbook-xml-dtd:4.3
+ )
+"
+
+src_prepare() {
+ default
+ xdg_environment_reset
+
+ sed -i -e '/install_data.*README\.md.*share\/doc\/gnome-software/d' meson.build || die
+ # We don't need language packs download support, and it fails tests in 3.34.2 for us (if they are enabled)
+ sed -i -e '/subdir.*fedora-langpacks/d' plugins/meson.build || die
+}
+
+src_configure() {
+ local emesonargs=(
+ $(meson_use test tests)
+ $(meson_feature gnome gsettings_desktop_schemas) # Honoring of GNOME date format settings.
+ -Dman=true
+ -Dpackagekit=false
+ # -Dpackagekit_autoremove
+ -Dpolkit=true
+ -Deos_updater=false # Endless OS updater
+ $(meson_use firmware fwupd)
+ $(meson_use flatpak)
+ -Dmalcontent=false
+ -Drpm_ostree=false
+ -Dwebapps=true
+ -Dhardcoded_foss_webapps=true
+ -Dhardcoded_proprietary_webapps=true
+ $(meson_use udev gudev)
+ -Dapt=false
+ -Dsnap=false
+ -Dexternal_appstream=false
+ $(meson_use gtk-doc gtk_doc)
+ -Dhardcoded_curated=true
+ # TODO: Will this be beneficial to us with flatpak at least? If
+ # enabled, it shows some apps under installed (probably merely due to
+ # /usr/share/app-info presence), but launching and removal of them is
+ # broken
+ -Ddefault_featured_apps=false
+ -Dmogwai=false #TODO?
+ $(meson_feature sysprof)
+ -Dprofile=''
+ -Dsoup2=false
+ )
+ meson_src_configure
+}
+
+src_test() {
+ virtx dbus-run-session meson test -C "${BUILD_DIR}" || die
+}
+
+pkg_postinst() {
+ xdg_pkg_postinst
+ gnome2_schemas_update
+}
+
+pkg_postrm() {
+ xdg_pkg_postrm
+ gnome2_schemas_update
+}