[gentoo-commits] repo/gentoo:master commit in: dev-python/immutables/

["Michał Górny" <mgorny@gentoo.org>]

commit:     1af4114210eb0ed18c4014b8b71a9d2bf4a64978
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Tue Aug 15 01:51:24 2023 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Tue Aug 15 02:39:19 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=1af41142

dev-python/immutables: Bump to 0.20

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/immutables/Manifest               |  1 +
 dev-python/immutables/immutables-0.20.ebuild | 51 ++++++++++++++++++++++++++++
 dev-python/immutables/metadata.xml           |  6 ++++
 3 files changed, 58 insertions(+)

diff --git a/dev-python/immutables/Manifest b/dev-python/immutables/Manifest
index a3c018b52751..892c3cff90bf 100644
--- a/dev-python/immutables/Manifest
+++ b/dev-python/immutables/Manifest
@@ -1 +1,2 @@
 DIST immutables-0.19.gh.tar.gz 85695 BLAKE2B b6457bd4e61c79ffc4ae83c1be3845ea1914ef6604ee8b0886c1ab24dba96e226444af5adc1032dc36e6f3058acac8a8f0289ce97f97874b02aae85eb3bc2ee1 SHA512 b1027e9ab4a304dcb953037a1ea4af082d0524255bcf3f3f368deda85b9a9e5b1c556638aab7a10cbf200fc14b85c8b739f212035f8ead1dff941b8f6da09668
+DIST immutables-0.20.gh.tar.gz 88169 BLAKE2B fb76793d8d908ea35999a9d3d36cdb6cc2021fda07d0822b23bf1eb7fe02031ac26a7aa3e83e890af24b949eedf6d81089a3670e96f9873a60339d0da44d2484 SHA512 b20a661e4a9161a2fe3db674aac8e84a36dd3e56083e6f6d6b1261a00d38adc136c0a2dce67243a5a4cd5b0568aa48a9d4c758fb27cf74e055f378a501c0f725

diff --git a/dev-python/immutables/immutables-0.20.ebuild b/dev-python/immutables/immutables-0.20.ebuild
new file mode 100644
index 000000000000..6f992abd2324
--- /dev/null
+++ b/dev-python/immutables/immutables-0.20.ebuild
@@ -0,0 +1,51 @@
+# Copyright 2019-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( pypy3 python3_{10..12} )
+
+inherit distutils-r1
+
+DESCRIPTION="A high-performance immutable mapping type for Python"
+HOMEPAGE="
+	https://github.com/MagicStack/immutables/
+	https://pypi.org/project/immutables/
+"
+SRC_URI="
+	https://github.com/MagicStack/${PN}/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+IUSE="+native-extensions"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	sed -i -e '/mypy/d' tests/conftest.py || die
+	# NB: upstream never builds extensions on PyPy
+	if ! use native-extensions; then
+		sed -i -e '/ext_modules=/d' setup.py || die
+	fi
+	distutils-r1_src_prepare
+}
+
+python_compile() {
+	# upstream controls NDEBUG explicitly
+	use debug && local -x DEBUG_IMMUTABLES=1
+	distutils-r1_python_compile
+}
+
+python_test() {
+	local EPYTEST_IGNORE=(
+		tests/test_mypy.py
+	)
+
+	rm -rf immutables || die
+	epytest
+}

diff --git a/dev-python/immutables/metadata.xml b/dev-python/immutables/metadata.xml
index 40858156f47d..853993018918 100644
--- a/dev-python/immutables/metadata.xml
+++ b/dev-python/immutables/metadata.xml
@@ -8,4 +8,10 @@
 		<remote-id type="pypi">immutables</remote-id>
 		<remote-id type="github">MagicStack/immutables</remote-id>
 	</upstream>
+	<use>
+		<flag name="native-extensions">
+			Compiles native "C" extensions (speedups, instead of using Python
+			fallback code).
+		</flag>
+	</use>
 </pkgmetadata>