[gentoo-commits] repo/gentoo:master commit in: media-libs/libsndfile/

["David Seifert" <soap@gentoo.org>]

commit:     7c4d8320f5370b02cc3da79ffa2d38a779688ae3
Author:     David Seifert <soap <AT> gentoo <DOT> org>
AuthorDate: Sun Aug 13 09:35:37 2023 +0000
Commit:     David Seifert <soap <AT> gentoo <DOT> org>
CommitDate: Sun Aug 13 09:35:37 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=7c4d8320

media-libs/libsndfile: add 1.2.2

Signed-off-by: David Seifert <soap <AT> gentoo.org>

 media-libs/libsndfile/Manifest                |  1 +
 media-libs/libsndfile/libsndfile-1.2.2.ebuild | 77 +++++++++++++++++++++++++++
 2 files changed, 78 insertions(+)

diff --git a/media-libs/libsndfile/Manifest b/media-libs/libsndfile/Manifest
index 46aab5d7a6c4..01445e104bff 100644
--- a/media-libs/libsndfile/Manifest
+++ b/media-libs/libsndfile/Manifest
@@ -1 +1,2 @@
 DIST libsndfile-1.2.0.tar.xz 730268 BLAKE2B cb13fde9b9f44c6279a9ee7741457824eb41fc17261bf9c669d757e9e506eba2c3d4ad259e4625b8a11c82308188cc19f7399e9d1fc0299a3a11794e4b653e47 SHA512 c0dee6b33cd3c619aa13ec2854a5480e826640ca98a438758346194e83752af576a39f9de118824f0d0c61288632d87b489dc5793c025296e0f15564d87ca12a
+DIST libsndfile-1.2.2.tar.xz 730760 BLAKE2B bc8e49983d9ad9dfd98984e2ffef501c6f576480e556e9f9ef91c7d597524cc1bb8baed15dfef8e239f72c42136c524117029eb8271f3a2c9d607fee490279b5 SHA512 a6e3ea3ac5d91befaa99f6a31a3fac44e7b7c11f1de4698167317a461d5a19a2651d47486a920b34400f18367b4f6173bf0c1c9ba80eb682cece1b5beee352a0

diff --git a/media-libs/libsndfile/libsndfile-1.2.2.ebuild b/media-libs/libsndfile/libsndfile-1.2.2.ebuild
new file mode 100644
index 000000000000..4adcb3826f99
--- /dev/null
+++ b/media-libs/libsndfile/libsndfile-1.2.2.ebuild
@@ -0,0 +1,77 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..12} pypy3 )
+
+if [[ ${PV} == *9999 ]]; then
+	inherit autotools git-r3
+	EGIT_REPO_URI="https://github.com/libsndfile/libsndfile.git"
+else
+	SRC_URI="https://github.com/libsndfile/libsndfile/releases/download/${PV}/${P}.tar.xz"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x64-solaris"
+fi
+inherit python-any-r1 multilib-minimal
+
+DESCRIPTION="C library for reading and writing files containing sampled sound"
+HOMEPAGE="https://libsndfile.github.io/libsndfile/"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+IUSE="alsa minimal sqlite test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	!minimal? (
+		media-libs/flac:=[${MULTILIB_USEDEP}]
+		media-libs/libogg:=[${MULTILIB_USEDEP}]
+		media-libs/libvorbis:=[${MULTILIB_USEDEP}]
+		media-libs/opus:=[${MULTILIB_USEDEP}]
+		media-sound/lame:=[${MULTILIB_USEDEP}]
+		media-sound/mpg123:=[${MULTILIB_USEDEP}]
+	)
+	alsa? ( media-libs/alsa-lib:= )
+	sqlite? ( dev-db/sqlite )"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	virtual/pkgconfig
+	test? ( ${PYTHON_DEPS} )"
+if [[ ${PV} == *9999 ]]; then
+	BDEPEND+="
+		${PYTHON_DEPS}
+		sys-devel/autogen
+	"
+fi
+
+pkg_setup() {
+	if use test || [[ ${PV} == *9999 ]]; then
+		python-any-r1_pkg_setup
+	fi
+}
+
+src_prepare() {
+	default
+
+	[[ ${PV} == *9999 ]] && eautoreconf
+}
+
+multilib_src_configure() {
+	ECONF_SOURCE="${S}" econf \
+		--disable-octave \
+		--disable-static \
+		--disable-werror \
+		$(use_enable !minimal external-libs) \
+		$(use_enable !minimal mpeg) \
+		$(multilib_native_enable full-suite) \
+		$(multilib_native_use_enable alsa) \
+		$(multilib_native_use_enable sqlite) \
+		PYTHON="${EPYTHON}"
+}
+
+multilib_src_install_all() {
+	einstalldocs
+
+	# no static archives
+	find "${ED}" -name '*.la' -delete || die
+}