[gentoo-commits] repo/gentoo:master commit in: dev-db/mycli/

["Michał Górny" <mgorny@gentoo.org>]

commit:     5558d8b5fd4c0abc82e196f31f7a5c7880f4dbe3
Author:     Alfred Wingate <parona <AT> protonmail <DOT> com>
AuthorDate: Fri Aug 11 20:42:43 2023 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Sat Aug 12 02:22:16 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=5558d8b5

dev-db/mycli: add 1.27.0

Signed-off-by: Alfred Wingate <parona <AT> protonmail.com>
Closes: https://github.com/gentoo/gentoo/pull/32267
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-db/mycli/Manifest            |  1 +
 dev-db/mycli/mycli-1.27.0.ebuild | 82 ++++++++++++++++++++++++++++++++++++++++
 2 files changed, 83 insertions(+)

diff --git a/dev-db/mycli/Manifest b/dev-db/mycli/Manifest
index cc2468208fc5..8e70becbdf75 100644
--- a/dev-db/mycli/Manifest
+++ b/dev-db/mycli/Manifest
@@ -1 +1,2 @@
 DIST mycli-1.26.1.gh.tar.gz 279221 BLAKE2B 2bb178110b5aba3e381541a7892cc1d8bed8e41c499d1dc36fa39435805a118536de44bf21b2ca2652afefcd15f8bc86ed77de876f703740e796444ff8cea6b0 SHA512 bce9def37718444f2445ed3a7ad91c54df4cc3dc5d207a4a2e0fc72eb27b75fca687958241fc40f5494efcdf9e4bae251f3cf94c13b967dd922d5ff653348c77
+DIST mycli-1.27.0.gh.tar.gz 285739 BLAKE2B 9b3ba8b98289721774d7bf06465402440d70772ee4f456f1a14a02a0f0cf90e6c4e6fe2abe36436ea051042bed208868dc469e9ef7c4499a9fdacd519b119199 SHA512 ae6fa9ed9151a39988ea64c5d551a68c92014cbaae4ec6695a727cd008882298d3373d1992768eff0781e881738f72f00dfe4756196c0ba82009758b1ea16b51

diff --git a/dev-db/mycli/mycli-1.27.0.ebuild b/dev-db/mycli/mycli-1.27.0.ebuild
new file mode 100644
index 000000000000..2baddf8fd9a6
--- /dev/null
+++ b/dev-db/mycli/mycli-1.27.0.ebuild
@@ -0,0 +1,82 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_SINGLE_IMPL=yes
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..11} )
+
+inherit distutils-r1
+
+DESCRIPTION="CLI for MySQL Database with auto-completion and syntax highlighting"
+HOMEPAGE="
+	https://www.mycli.net/
+	https://github.com/dbcli/mycli/
+	https://pypi.org/project/mycli/
+"
+SRC_URI="
+	https://github.com/dbcli/mycli/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="BSD MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="ssh"
+
+RDEPEND="
+	$(python_gen_cond_dep '
+		>=dev-python/cli_helpers-2.2.1[${PYTHON_USEDEP}]
+		>=dev-python/click-7.0[${PYTHON_USEDEP}]
+		>=dev-python/configobj-5.0.5[${PYTHON_USEDEP}]
+		>=dev-python/cryptography-1.0.0[${PYTHON_USEDEP}]
+		>=dev-python/prompt-toolkit-3.0.6[${PYTHON_USEDEP}]
+		<dev-python/prompt-toolkit-4.0.0[${PYTHON_USEDEP}]
+		>=dev-python/pyaes-1.6.1[${PYTHON_USEDEP}]
+		>=dev-python/pygments-1.6[${PYTHON_USEDEP}]
+		>=dev-python/pymysql-0.9.2[${PYTHON_USEDEP}]
+		>=dev-python/pyperclip-1.8.1[${PYTHON_USEDEP}]
+		>=dev-python/sqlglot-5.1.3[${PYTHON_USEDEP}]
+		>=dev-python/sqlparse-0.3.0[${PYTHON_USEDEP}]
+		<dev-python/sqlparse-0.5.0[${PYTHON_USEDEP}]
+		ssh? ( dev-python/paramiko[${PYTHON_USEDEP}] )'
+	)
+"
+BDEPEND="
+	test? (
+		$(python_gen_cond_dep '
+			dev-python/paramiko[${PYTHON_USEDEP}]
+		')
+	)
+"
+
+EPYTEST_DESELECT=(
+	# Fails after a seemingly benign change in sqlparse 0.4.3
+	# https://github.com/dbcli/mycli/issues/1103
+	"test/test_smart_completion_public_schema_only.py::test_auto_escaped_col_names"
+	# Requires a running mysql daemon
+	"test/test_main.py::test_batch"
+	"test/test_main.py::test_execute"
+	"test/test_main.py::test_init"
+	"test/test_special_iocommands.py::test_favorite_query"
+	"test/test_special_iocommands.py::test_watch"
+	"test/test_tabular_output.py::test_sql_output"
+)
+
+EPYTEST_IGNORE=(
+	# Requires a running mysql daemon
+	"test/test_sqlexecute.py"
+)
+
+distutils_enable_tests pytest
+
+PATCHES=( "${FILESDIR}/mycli-1.21.1-fix-test-install.patch" )
+
+src_prepare() {
+	default
+
+	# Remove unnecessary pin, we have paramiko 3.2.0.
+	# https://github.com/dbcli/mycli/commit/eaddc5ca3e208d66fd4f400b90eb76089dd35e4c
+	sed -i -e 's:==:>=:' setup.py || die
+}