[gentoo-commits] repo/gentoo:master commit in: gnome-extra/gnome-software/

["Matt Turner" <mattst88@gentoo.org>]

commit:     23c64ccdfc8bc09043071f18aefc03eef0d4c6b8
Author:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
AuthorDate: Tue Aug  8 15:24:06 2023 +0000
Commit:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Tue Aug  8 15:24:06 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=23c64ccd

gnome-extra/gnome-software: Version bump to 44.4

Signed-off-by: Matt Turner <mattst88 <AT> gentoo.org>

 gnome-extra/gnome-software/Manifest                |   1 +
 .../gnome-software/gnome-software-44.4.ebuild      | 106 +++++++++++++++++++++
 2 files changed, 107 insertions(+)

diff --git a/gnome-extra/gnome-software/Manifest b/gnome-extra/gnome-software/Manifest
index 4c5973285425..71ae903b70b2 100644
--- a/gnome-extra/gnome-software/Manifest
+++ b/gnome-extra/gnome-software/Manifest
@@ -1,4 +1,5 @@
 DIST gnome-software-44.2.tar.xz 2423844 BLAKE2B 6dfbefb71a4d8c83bdc2ef293fa11379523fc966a58bef80f72fc1106b332594c06c6749702e07547c5dd4e3412ac57c309fd7d45bdabe94be5139474d6a76f6 SHA512 0f053d1d92285239d7edd62a5dcc5c8ce9e991103e3987808ef82406e2dc665a13e0cd14b043d66dfd420459a6aa7c83e7db2fd6a16a8f3b41a6e93498820251
 DIST gnome-software-44.3.tar.xz 2426180 BLAKE2B 1c88803cd86d383990c5e79f1721a454a9168d0872f257922d2a14ef3e345757477e8222eb891121ddaca883c3da8ad7c0afe815157eb578ba50775411470176 SHA512 33d2429597ab48fe27d772e88669569fba11c81a8cba33d17a0e00d8027079d178d97172a088fcd2167f895380ae1b4ad56244da9ca0a15b1acc096e3f048e3f
+DIST gnome-software-44.4.tar.xz 2426404 BLAKE2B 6f60ffd115ad0e11b619118ae5e665fb35c70621adefe4c532481ab3742c8e2c6a5a0790dae29b2fcf0311f89fda93c323e5bc24b185bbbe95e62a687f71930d SHA512 97eaa33b4dd91a6865ee7eeee28e5acf3cf5fbd6a72a60cf5a7c528f79f6f0684014d1169318314b8efce23c1c29e7d24a71193998ced930584a50494137cf8b
 DIST gnome-software-45.alpha.tar.xz 2440740 BLAKE2B 20a6c467072af7c75fffc5e79d10d87178b4c561215718561d69f018aa8cda92a0dedaca8a6631d12a91d38d8599316ff4151bb043d937cfa77866ffa5708966 SHA512 1a2c5e6eec249fdeb726b6cdd58c47ccbdefd6c9bc7278c6d30f1350cc62d3e1231e12b5b2cd9acee8deff269346171d427fd389194f04ca641825bd32ddaa2a
 DIST gnome-software-45.beta.tar.xz 2450776 BLAKE2B b14af00c87682a56a54b3cba394be57e0994a56671ccbb2016aecd492401f54e068973f7bd6278c1b55f02f0d8e1ef9de9d3408dbe2ff30634c9f78e80be044b SHA512 d4218b56478c9e7e83adf4fb8daec8d0730f5ce16cca0a0c59962894a0abb2d21c356a55f232d266aaaa4f15b21c21bc5904cc1f7b6db4d94db8889019fea092

diff --git a/gnome-extra/gnome-software/gnome-software-44.4.ebuild b/gnome-extra/gnome-software/gnome-software-44.4.ebuild
new file mode 100644
index 000000000000..4f2a883a0040
--- /dev/null
+++ b/gnome-extra/gnome-software/gnome-software-44.4.ebuild
@@ -0,0 +1,106 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit gnome.org gnome2-utils meson virtualx xdg
+
+DESCRIPTION="Gnome install & update software"
+HOMEPAGE="https://wiki.gnome.org/Apps/Software https://gitlab.gnome.org/GNOME/gnome-software"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="flatpak +firmware gnome gtk-doc sysprof udev test"
+
+RDEPEND="
+	>=dev-libs/appstream-0.14.0:0=
+	>=x11-libs/gdk-pixbuf-2.32.0:2
+	>=dev-libs/libxmlb-0.1.7:=
+	>=gui-libs/gtk-4.9.2:4
+	>=dev-libs/glib-2.70.0:2
+	>=dev-libs/json-glib-1.6.0
+	>=net-libs/libsoup-3.0:3.0
+	>=gui-libs/libadwaita-1.3_rc:1
+	sysprof? ( >=dev-util/sysprof-capture-3.40.1:4 )
+	gnome? ( >=gnome-base/gsettings-desktop-schemas-3.18.0 )
+	sys-auth/polkit
+	firmware? ( >=sys-apps/fwupd-1.5.6 )
+	flatpak? (
+		>=sys-apps/flatpak-1.14.0-r1
+		dev-util/ostree
+	)
+	udev? ( dev-libs/libgudev )
+	>=gnome-base/gsettings-desktop-schemas-3.11.5
+"
+DEPEND="${RDEPEND}
+	test? ( dev-libs/libglib-testing )
+"
+BDEPEND="
+	dev-libs/libxml2:2
+	dev-util/gdbus-codegen
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+	gtk-doc? (
+		dev-util/gtk-doc
+		app-text/docbook-xml-dtd:4.3
+	)
+"
+
+src_prepare() {
+	default
+	xdg_environment_reset
+
+	sed -i -e '/install_data.*README\.md.*share\/doc\/gnome-software/d' meson.build || die
+	# We don't need language packs download support, and it fails tests in 3.34.2 for us (if they are enabled)
+	sed -i -e '/subdir.*fedora-langpacks/d' plugins/meson.build || die
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use test tests)
+		$(meson_feature gnome gsettings_desktop_schemas) # Honoring of GNOME date format settings.
+		-Dman=true
+		-Dpackagekit=false
+		# -Dpackagekit_autoremove
+		-Dpolkit=true
+		-Deos_updater=false # Endless OS updater
+		$(meson_use firmware fwupd)
+		$(meson_use flatpak)
+		-Dmalcontent=false
+		-Drpm_ostree=false
+		-Dwebapps=true
+		-Dhardcoded_foss_webapps=true
+		-Dhardcoded_proprietary_webapps=true
+		$(meson_use udev gudev)
+		-Dapt=false
+		-Dsnap=false
+		-Dexternal_appstream=false
+		$(meson_use gtk-doc gtk_doc)
+		-Dhardcoded_curated=true
+		# TODO: Will this be beneficial to us with flatpak at least? If
+		# enabled, it shows some apps under installed (probably merely due to
+		# /usr/share/app-info presence), but launching and removal of them is
+		# broken
+		-Ddefault_featured_apps=false
+		-Dmogwai=false #TODO?
+		$(meson_feature sysprof)
+		-Dprofile=''
+		-Dsoup2=false
+	)
+	meson_src_configure
+}
+
+src_test() {
+	virtx dbus-run-session meson test -C "${BUILD_DIR}" || die
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}