From mboxrd@z Thu Jan 1 00:00:00 1970
Return-Path: <gentoo-commits+bounces-1542642-garchives=archives.gentoo.org@lists.gentoo.org>
Received: from lists.gentoo.org (pigeon.gentoo.org [208.92.234.80])
(using TLSv1.3 with cipher TLS_AES_256_GCM_SHA384 (256/256 bits)
key-exchange X25519 server-signature RSA-PSS (2048 bits))
(No client certificate requested)
by finch.gentoo.org (Postfix) with ESMTPS id 2FE0D15800A
for <garchives@archives.gentoo.org>; Wed, 2 Aug 2023 06:05:44 +0000 (UTC)
Received: from pigeon.gentoo.org (localhost [127.0.0.1])
by pigeon.gentoo.org (Postfix) with SMTP id 7868BE0C5E;
Wed, 2 Aug 2023 06:05:43 +0000 (UTC)
Received: from smtp.gentoo.org (woodpecker.gentoo.org [140.211.166.183])
(using TLSv1.3 with cipher TLS_AES_256_GCM_SHA384 (256/256 bits)
key-exchange X25519 server-signature RSA-PSS (4096 bits))
(No client certificate requested)
by pigeon.gentoo.org (Postfix) with ESMTPS id 542D4E0BB3
for <gentoo-commits@lists.gentoo.org>; Wed, 2 Aug 2023 06:05:43 +0000 (UTC)
Received: from oystercatcher.gentoo.org (oystercatcher.gentoo.org [148.251.78.52])
(using TLSv1.3 with cipher TLS_AES_256_GCM_SHA384 (256/256 bits)
key-exchange X25519 server-signature RSA-PSS (4096 bits) server-digest SHA256)
(No client certificate requested)
by smtp.gentoo.org (Postfix) with ESMTPS id 66A89335C9F
for <gentoo-commits@lists.gentoo.org>; Wed, 2 Aug 2023 06:05:42 +0000 (UTC)
Received: from localhost.localdomain (localhost [IPv6:::1])
by oystercatcher.gentoo.org (Postfix) with ESMTP id C8920A84
for <gentoo-commits@lists.gentoo.org>; Wed, 2 Aug 2023 06:05:40 +0000 (UTC)
From: "Michał Górny" <mgorny@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Content-Transfer-Encoding: 8bit
Content-type: text/plain; charset=UTF-8
Reply-To: gentoo-dev@lists.gentoo.org, "Michał Górny" <mgorny@gentoo.org>
Message-ID: <1690956328.8b2ab7c93df26a2ede5f31e663e1c797009e64be.mgorny@gentoo>
Subject: [gentoo-commits] repo/gentoo:master commit in: dev-python/sphinx/
X-VCS-Repository: repo/gentoo
X-VCS-Files: dev-python/sphinx/Manifest dev-python/sphinx/sphinx-7.1.2.ebuild
X-VCS-Directories: dev-python/sphinx/
X-VCS-Committer: mgorny
X-VCS-Committer-Name: Michał Górny
X-VCS-Revision: 8b2ab7c93df26a2ede5f31e663e1c797009e64be
X-VCS-Branch: master
Date: Wed, 2 Aug 2023 06:05:40 +0000 (UTC)
Precedence: bulk
List-Post: <mailto:gentoo-commits@lists.gentoo.org>
List-Help: <mailto:gentoo-commits+help@lists.gentoo.org>
List-Unsubscribe: <mailto:gentoo-commits+unsubscribe@lists.gentoo.org>
List-Subscribe: <mailto:gentoo-commits+subscribe@lists.gentoo.org>
List-Id: Gentoo Linux mail <gentoo-commits.gentoo.org>
X-BeenThere: gentoo-commits@lists.gentoo.org
X-Auto-Response-Suppress: DR, RN, NRN, OOF, AutoReply
X-Archives-Salt: a5c42032-685e-407f-a6ff-830abcbd645b
X-Archives-Hash: 21c310e3bb33b0c4b386240ad1e31ad5
commit: 8b2ab7c93df26a2ede5f31e663e1c797009e64be
Author: Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Wed Aug 2 05:25:00 2023 +0000
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Wed Aug 2 06:05:28 2023 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=8b2ab7c9
dev-python/sphinx: Bump to 7.1.2
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>
dev-python/sphinx/Manifest | 1 +
dev-python/sphinx/sphinx-7.1.2.ebuild | 132 ++++++++++++++++++++++++++++++++++
2 files changed, 133 insertions(+)
diff --git a/dev-python/sphinx/Manifest b/dev-python/sphinx/Manifest
index 940bac03d3f1..93860cf2e010 100644
--- a/dev-python/sphinx/Manifest
+++ b/dev-python/sphinx/Manifest
@@ -3,3 +3,4 @@ DIST sphinx-6.2.1.gh.tar.gz 6729925 BLAKE2B 621ead516dc17cc632e9e752b56b5432547b
DIST sphinx-7.0.1.gh.tar.gz 6712916 BLAKE2B 7e30804eb5c24559c8ca30e5d8943ad78b426f94c3008ec74de6a541a71a7835d4e83dd69d84df04778f6246840209847ce103863b4dd4109e01bc3a5a50fd84 SHA512 6489778c4953b2c2d9972fa3f07fdb3b361b441e2c9f47282ec9c47f70446e3df66e434690ba816cc6f98838056001d2518f9bd1235e8b07ddba3c1d03a57b76
DIST sphinx-7.1.0.gh.tar.gz 6882321 BLAKE2B dfa644b33e0dc97acb04470da452f184cdc377e0c07a58e2e504b425becbc114eac503559ceb7dc81b54d31e89587a8f8f3ecb11df073a949f08d0281ca21a3c SHA512 707a9f36e7c8f0dd0f0f6c3d81dff67e3c996fb8b9daac0eec240200828347ddfde3d374ca45286cd41bdc6a88d89012b606b217304f41b71661ee0d4acc9bbe
DIST sphinx-7.1.1.gh.tar.gz 6881907 BLAKE2B 4c73fbcd14c962ead0b15de5f36f6101ce1958aae26dffe055e7d9546eea4f998e53b97f3d27f55521d689e13b8524a03443858151968f33fcab1704cbb1319c SHA512 43fb78dbd51b25d50ce2f22b40c6e784200a0195e5a00b793b577bf2b2e8db28dd73f031dd6991e835a997de22781541e8239c73ddd36a6b5b8c1c367dcac3d1
+DIST sphinx-7.1.2.gh.tar.gz 6882028 BLAKE2B 3ceabcb688824d929a5258978433b46a31666f423941dbed7641c7017745c4beb8b215714e1aa9c8a8b251bc4be1f5a7e80680a498ed808ed07178219dc31b65 SHA512 26827a6fa955665bc3b26ab882933eadcadf9a055bad9e8c98ca80a79a062ea8102950bbd4974b168c2bda62ae437976cf787401816c0804aa533f65a91efc24
diff --git a/dev-python/sphinx/sphinx-7.1.2.ebuild b/dev-python/sphinx/sphinx-7.1.2.ebuild
new file mode 100644
index 000000000000..d5c5702da98e
--- /dev/null
+++ b/dev-python/sphinx/sphinx-7.1.2.ebuild
@@ -0,0 +1,132 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=flit
+PYTHON_COMPAT=( python3_{10..12} pypy3 )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1
+
+DESCRIPTION="Python documentation generator"
+HOMEPAGE="
+ https://www.sphinx-doc.org/
+ https://github.com/sphinx-doc/sphinx/
+ https://pypi.org/project/Sphinx/
+"
+SRC_URI="
+ https://github.com/sphinx-doc/sphinx/archive/v${PV}.tar.gz
+ -> ${P}.gh.tar.gz
+"
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x64-solaris"
+IUSE="doc latex"
+
+RDEPEND="
+ <dev-python/alabaster-0.8[${PYTHON_USEDEP}]
+ >=dev-python/Babel-2.9[${PYTHON_USEDEP}]
+ <dev-python/docutils-0.21[${PYTHON_USEDEP}]
+ >=dev-python/docutils-0.18.1[${PYTHON_USEDEP}]
+ >=dev-python/imagesize-1.3[${PYTHON_USEDEP}]
+ >=dev-python/jinja-3.0[${PYTHON_USEDEP}]
+ >=dev-python/pygments-2.13[${PYTHON_USEDEP}]
+ >=dev-python/requests-2.25.0[${PYTHON_USEDEP}]
+ >=dev-python/snowballstemmer-2.0[${PYTHON_USEDEP}]
+ dev-python/sphinxcontrib-applehelp[${PYTHON_USEDEP}]
+ dev-python/sphinxcontrib-devhelp[${PYTHON_USEDEP}]
+ dev-python/sphinxcontrib-jsmath[${PYTHON_USEDEP}]
+ >=dev-python/sphinxcontrib-htmlhelp-2.0.0[${PYTHON_USEDEP}]
+ >=dev-python/sphinxcontrib-serializinghtml-1.1.5[${PYTHON_USEDEP}]
+ dev-python/sphinxcontrib-qthelp[${PYTHON_USEDEP}]
+ >=dev-python/packaging-21.0[${PYTHON_USEDEP}]
+ latex? (
+ dev-texlive/texlive-latexextra
+ dev-texlive/texlive-luatex
+ app-text/dvipng
+ )
+ !dev-python/namespace-sphinxcontrib
+"
+BDEPEND="
+ doc? (
+ dev-python/sphinxcontrib-websupport[${PYTHON_USEDEP}]
+ media-gfx/graphviz
+ )
+ test? (
+ app-text/dvipng
+ dev-python/cython[${PYTHON_USEDEP}]
+ dev-python/filelock[${PYTHON_USEDEP}]
+ dev-python/html5lib[${PYTHON_USEDEP}]
+ dev-texlive/texlive-fontsextra
+ dev-texlive/texlive-latexextra
+ dev-texlive/texlive-luatex
+ virtual/imagemagick-tools[jpeg,png,svg]
+ )
+"
+
+PATCHES=(
+ "${FILESDIR}/sphinx-3.2.1-doc-link.patch"
+ "${FILESDIR}/sphinx-4.3.2-doc-link.patch"
+)
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+ # disable internet access
+ sed -i -e 's:^intersphinx_mapping:disabled_&:' \
+ doc/conf.py || die
+
+ distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+ # we can't use distutils_enable_sphinx because it would
+ # introduce a dep on itself
+ use doc && build_sphinx doc
+}
+
+python_test() {
+ mkdir -p "${BUILD_DIR}/sphinx_tempdir" || die
+ local -x SPHINX_TEST_TEMPDIR="${BUILD_DIR}/sphinx_tempdir"
+
+ local EPYTEST_DESELECT=(
+ # these tests require Internet access
+ tests/test_build_latex.py::test_latex_images
+ tests/test_build_linkcheck.py::test_defaults
+ tests/test_build_linkcheck.py::test_defaults_json
+ tests/test_build_linkcheck.py::test_anchors_ignored
+ tests/test_build_linkcheck.py::test_check_link_response_only
+ tests/test_build_linkcheck.py::test_linkcheck_exclude_documents
+ # TODO
+ tests/test_ext_autodoc.py::test_cython
+ tests/test_ext_autodoc_autoclass.py::test_classes
+ tests/test_ext_autodoc_autofunction.py::test_classes
+ tests/test_ext_math.py::test_imgmath_numfig_html
+ tests/test_ext_math.py::test_imgmath_png
+ tests/test_ext_inheritance_diagram.py::test_import_classes
+ # looks like a bug in lualatex
+ "tests/test_build_latex.py::test_build_latex_doc[lualatex-howto-None]"
+ "tests/test_build_latex.py::test_build_latex_doc[lualatex-manual-None]"
+ )
+ [[ ${EPYTHON} == pypy3 ]] && EPYTEST_DESELECT+=(
+ tests/test_ext_autodoc.py::test_autodoc_inherited_members_None
+ tests/test_ext_autodoc.py::test_automethod_for_builtin
+ tests/test_ext_autodoc.py::test_cython
+ tests/test_ext_autodoc.py::test_partialfunction
+ tests/test_ext_autodoc_autoclass.py::test_autodoc_process_bases
+ tests/test_ext_autodoc_autoclass.py::test_show_inheritance_for_decendants_of_generic_type
+ tests/test_ext_autodoc_autoclass.py::test_show_inheritance_for_subclass_of_generic_type
+ tests/test_ext_autodoc_autofunction.py::test_builtin_function
+ tests/test_ext_autodoc_autofunction.py::test_methoddescriptor
+ tests/test_ext_autodoc_automodule.py::test_automodule_inherited_members
+ tests/test_ext_autosummary.py::test_autosummary_generate_content_for_module
+ tests/test_ext_autosummary.py::test_autosummary_generate_content_for_module_skipped
+ tests/test_util_inspect.py::test_isattributedescriptor
+ tests/test_util_typing.py::test_stringify_type_hints_pep_585
+ )
+
+ # note: pytest-xdist causes random test failures
+ epytest
+}