[gentoo-commits] repo/gentoo:master commit in: media-libs/ladspa-sdk/

["Sam James" <sam@gentoo.org>]

commit:     eff07f5a525f6e0e18ddfe72aba9790455e6067d
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Thu Jul 27 07:38:14 2023 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Thu Jul 27 08:19:32 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=eff07f5a

media-libs/ladspa-sdk: build with LFS

Closes: https://bugs.gentoo.org/911262
Thanks-to: Allen Webb <allenwebb <AT> google.com>
Signed-off-by: Sam James <sam <AT> gentoo.org>

 media-libs/ladspa-sdk/ladspa-sdk-1.17-r2.ebuild | 65 +++++++++++++++++++++++++
 1 file changed, 65 insertions(+)

diff --git a/media-libs/ladspa-sdk/ladspa-sdk-1.17-r2.ebuild b/media-libs/ladspa-sdk/ladspa-sdk-1.17-r2.ebuild
new file mode 100644
index 000000000000..d7af263402c3
--- /dev/null
+++ b/media-libs/ladspa-sdk/ladspa-sdk-1.17-r2.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit flag-o-matic toolchain-funcs portability multilib-minimal
+
+MY_PN=${PN/-/_}
+MY_P=${MY_PN}_${PV}
+
+DESCRIPTION="The Linux Audio Developer's Simple Plugin API"
+HOMEPAGE="https://www.ladspa.org/"
+SRC_URI="https://www.ladspa.org/download/${MY_P}.tgz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~ppc ~ppc64 ~riscv ~sparc ~x86"
+
+RDEPEND="media-libs/libsndfile[${MULTILIB_USEDEP}]"
+DEPEND="${RDEPEND}"
+
+S="${WORKDIR}/${MY_P}"
+
+PATCHES=(
+	"${FILESDIR}/${P}-properbuild.patch"
+)
+
+HTML_DOCS="doc/*.html"
+
+src_prepare() {
+	default
+
+	multilib_copy_sources
+}
+
+multilib_src_configure() {
+	# bug #911262
+	append-lfs-flags
+}
+
+multilib_src_compile() {
+	emake -C src CFLAGS="${CFLAGS}" CXXFLAGS="${CXXFLAGS}" \
+		DYNAMIC_LD_LIBS="$(dlopen_lib)" \
+		CC="$(tc-getCC)" CXX="$(tc-getCXX)" \
+		targets
+}
+
+multilib_src_test() {
+	emake -C src test
+}
+
+multilib_src_install() {
+	emake -C src INSTALL_PLUGINS_DIR="/usr/$(get_libdir)/ladspa" \
+		DESTDIR="${ED}" \
+		MKDIR_P="mkdir -p" \
+		install
+}
+
+multilib_src_install_all() {
+	einstalldocs
+
+	# Needed for apps like rezound
+	dodir /etc/env.d
+	echo "LADSPA_PATH=${EPREFIX}/usr/$(get_libdir)/ladspa" > "${ED}/etc/env.d/60ladspa"
+}