[gentoo-commits] repo/gentoo:master commit in: sys-fs/lxcfs/

["Joonas Niilola" <juippis@gentoo.org>]

commit:     47df59fcd374c3b6d183264f5f3eeeeb3e56928a
Author:     Joonas Niilola <juippis <AT> gentoo <DOT> org>
AuthorDate: Wed Jul 26 05:07:01 2023 +0000
Commit:     Joonas Niilola <juippis <AT> gentoo <DOT> org>
CommitDate: Wed Jul 26 05:15:57 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=47df59fc

sys-fs/lxcfs: add 5.0.4

Signed-off-by: Joonas Niilola <juippis <AT> gentoo.org>

 sys-fs/lxcfs/Manifest           |  2 ++
 sys-fs/lxcfs/lxcfs-5.0.4.ebuild | 80 +++++++++++++++++++++++++++++++++++++++++
 2 files changed, 82 insertions(+)

diff --git a/sys-fs/lxcfs/Manifest b/sys-fs/lxcfs/Manifest
index 490192a63102..a733525b98af 100644
--- a/sys-fs/lxcfs/Manifest
+++ b/sys-fs/lxcfs/Manifest
@@ -1,2 +1,4 @@
 DIST lxcfs-5.0.3.tar.gz 103697 BLAKE2B bdea820f1a5b799309b3d5c8ea439477e6eeda2d9600a348a92b203f2f8a6e0e686d0bf56d8f6b5bbfeb4837dd5737626d7d0610157211f0f189711e9e45a048 SHA512 967e60bd7ea545f1fcdd805adc0083e39684013c18f42a51753b5be8cdabfb86a652d02471a1f71c7b4fa756da09b72d324b724d68091d539edd10ea63add1fd
 DIST lxcfs-5.0.3.tar.gz.asc 833 BLAKE2B 2dc139639431d9430149369b0a28b6debef0de9f5f69854070d8f2e47718bcc130a869683dfa2b0002c6a54978b0550303adbd5a7fa5ef565eb6bc6bbfcde9e0 SHA512 0207c110553b9d62cf88ec70ed4472b9696d74b277af1e53df6d1145228b76d06695fd28bf20c8428bee5b6ff617c617fbf063c1c8ff0bcc44be2e3439c76a64
+DIST lxcfs-5.0.4.tar.gz 104249 BLAKE2B 83a7b861136c34da8a24dd525fd0767193f2bbd92b40e3b9fd5e42d7645465411792e65e95797ab13b33330299d12b19bdd5786352875ed88ac0097b72b711a9 SHA512 b404045dbabe23e1d1f1d74c1648d2596bb70aaa9f9e46f9f5635b0a02d0c451f68b2559920bbefc5b889e908cf1da0a33c148b26bdce3e45c3d0cbdff710604
+DIST lxcfs-5.0.4.tar.gz.asc 833 BLAKE2B aff883d24b374b296ea3678670e5e82c723fd0e35cfd7fed555aabbd811a104becc0b741331b4aa4a5129c9fff4dc88c6a86e7d64a89fe86aea81718f5d432dd SHA512 56b639597dbaf3008fe030147ea37192bd465c467a79e11ce139bcaa6bca1625b4bb9c4eda6ea1877446769f0fad9b4c5a3513d4f4415b841db96d5da8325ddc

diff --git a/sys-fs/lxcfs/lxcfs-5.0.4.ebuild b/sys-fs/lxcfs/lxcfs-5.0.4.ebuild
new file mode 100644
index 000000000000..ef62a49d82c3
--- /dev/null
+++ b/sys-fs/lxcfs/lxcfs-5.0.4.ebuild
@@ -0,0 +1,80 @@
+# Copyright 2022-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{9..12} )
+
+inherit cmake meson python-any-r1 systemd verify-sig
+
+DESCRIPTION="FUSE filesystem for LXC"
+HOMEPAGE="https://linuxcontainers.org/lxcfs/introduction/ https://github.com/lxc/lxcfs/"
+SRC_URI="https://linuxcontainers.org/downloads/lxcfs/${P}.tar.gz
+	verify-sig? ( https://linuxcontainers.org/downloads/lxcfs/${P}.tar.gz.asc )"
+
+LICENSE="Apache-2.0 LGPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~riscv ~x86"
+IUSE="doc test"
+
+DEPEND="sys-fs/fuse:3"
+RDEPEND="${DEPEND}"
+BDEPEND="${PYTHON_DEPS}
+	virtual/pkgconfig
+	$(python_gen_any_dep '
+		dev-python/jinja[${PYTHON_USEDEP}]
+	')
+	doc? ( sys-apps/help2man )
+	verify-sig? ( sec-keys/openpgp-keys-linuxcontainers )"
+
+# Needs some black magic to work inside container/chroot.
+RESTRICT="test"
+
+VERIFY_SIG_OPENPGP_KEY_PATH=${BROOT}/usr/share/openpgp-keys/linuxcontainers.asc
+
+python_check_deps() {
+	python_has_version -b "dev-python/jinja[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+	python-any-r1_pkg_setup
+}
+
+src_prepare() {
+	default
+
+	# Fix python shebangs for python-exec[-native-symlinks], #851480
+	local shebangs=($(grep -rl "#!/usr/bin/env python3" || die))
+	python_fix_shebang -q ${shebangs[*]}
+}
+
+src_configure() {
+	local emesonargs=(
+		--localstatedir "${EPREFIX}/var"
+
+		$(meson_use doc docs)
+		$(meson_use test tests)
+
+		-Dfuse-version=3
+		-Dinit-script=""
+		-Dwith-init-script=""
+	)
+
+	meson_src_configure
+}
+
+src_test() {
+	cd "${BUILD_DIR}"/tests || die "failed to change into tests/ directory."
+	./main.sh || die
+}
+
+src_install() {
+	meson_src_install
+
+	newconfd "${FILESDIR}"/lxcfs-5.0.2.confd lxcfs
+	newinitd "${FILESDIR}"/lxcfs-5.0.2.initd lxcfs
+
+	# Provide our own service file (copy of upstream) due to paths being different from upstream,
+	# #728470
+	systemd_newunit "${FILESDIR}"/lxcfs-5.0.2.service lxcfs.service
+}