[gentoo-commits] repo/gentoo:master commit in: media-libs/gexiv2/

["Matt Turner" <mattst88@gentoo.org>]

commit:     801424a28f4c5493a17d034d4753fccf64915331
Author:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
AuthorDate: Mon Jul 24 21:20:22 2023 +0000
Commit:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Mon Jul 24 21:20:48 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=801424a2

media-libs/gexiv2: Version bump to 0.14.2

Signed-off-by: Matt Turner <mattst88 <AT> gentoo.org>

 media-libs/gexiv2/gexiv2-0.14.2.ebuild | 78 ++++++++++++++++++++++++++++++++++
 1 file changed, 78 insertions(+)

diff --git a/media-libs/gexiv2/gexiv2-0.14.2.ebuild b/media-libs/gexiv2/gexiv2-0.14.2.ebuild
new file mode 100644
index 000000000000..1c1402775504
--- /dev/null
+++ b/media-libs/gexiv2/gexiv2-0.14.2.ebuild
@@ -0,0 +1,78 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..12} )
+
+inherit gnome.org meson python-r1 vala
+
+DESCRIPTION="GObject-based wrapper around the Exiv2 library"
+HOMEPAGE="https://wiki.gnome.org/Projects/gexiv2"
+
+if [[ ${PV} == 9999 ]]; then
+	EGIT_REPO_URI="https://gitlab.gnome.org/GNOME/gexiv2.git"
+	inherit git-r3
+else
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~ppc ~ppc64 ~riscv ~sparc ~x86"
+fi
+
+LICENSE="LGPL-2.1+ GPL-2"
+SLOT="0"
+IUSE="gtk-doc +introspection python test +vala"
+REQUIRED_USE="
+	python? ( introspection ${PYTHON_REQUIRED_USE} )
+	test? ( python introspection )
+	vala? ( introspection )
+"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=media-gfx/exiv2-0.26:=
+	>=dev-libs/glib-2.46.0:2
+	introspection? ( >=dev-libs/gobject-introspection-1.54:= )
+	python? (
+		${PYTHON_DEPS}
+		dev-python/pygobject:3[${PYTHON_USEDEP}]
+	)
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	dev-util/glib-utils
+	gtk-doc? (
+		dev-util/gtk-doc
+		app-text/docbook-xml-dtd:4.3
+	)
+	test? ( media-gfx/exiv2[xmp] )
+	virtual/pkgconfig
+	vala? ( $(vala_depend) )
+"
+
+src_prepare() {
+	default
+	use vala && vala_setup
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use test tests)
+		$(meson_use gtk-doc gtk_doc)
+		$(meson_use introspection)
+		$(meson_use vala vapi)
+		-Dtools=false # requires vala, freshly promoted tool that some other distros don't ship yet either
+		# Prevents installation of python modules (uses install_data from meson
+		# which does not optimize the modules)
+		-Dpython3=false
+	)
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+
+	if use python ; then
+		python_moduleinto gi/overrides/
+		python_foreach_impl python_domodule GExiv2.py
+		python_foreach_impl python_optimize
+	fi
+}