[gentoo-commits] repo/gentoo:master commit in: dev-python/pytest-django/

["Michał Górny" <mgorny@gentoo.org>]

commit:     653dbd52b6deaf02ab83718b8ab4670c0997dc26
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Sun Jul 23 14:36:32 2023 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Sun Jul 23 14:38:45 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=653dbd52

dev-python/pytest-django: Use PEP517 build

Closes: https://bugs.gentoo.org/909949
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 .../pytest-django/pytest-django-4.5.2-r1.ebuild    | 60 ++++++++++++++++++++++
 1 file changed, 60 insertions(+)

diff --git a/dev-python/pytest-django/pytest-django-4.5.2-r1.ebuild b/dev-python/pytest-django/pytest-django-4.5.2-r1.ebuild
new file mode 100644
index 000000000000..2a30c4eb24db
--- /dev/null
+++ b/dev-python/pytest-django/pytest-django-4.5.2-r1.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..11} )
+
+inherit distutils-r1
+
+DESCRIPTION="A Django plugin for py.test"
+HOMEPAGE="
+	https://pypi.org/project/pytest-django/
+	https://pytest-django.readthedocs.io/
+	https://github.com/pytest-dev/pytest-django/
+"
+SRC_URI="
+	https://github.com/pytest-dev/pytest-django/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="BSD"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86"
+SLOT="0"
+
+RDEPEND="
+	dev-python/django[${PYTHON_USEDEP}]
+	>=dev-python/pytest-5.4[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	>=dev-python/setuptools-scm-1.11.1[${PYTHON_USEDEP}]
+	test? (
+		dev-python/django-configurations[${PYTHON_USEDEP}]
+		dev-python/pytest-xdist[${PYTHON_USEDEP}]
+	)
+"
+
+PATCHES=(
+	"${FILESDIR}"/${P}-pytest-7.patch
+)
+
+export SETUPTOOLS_SCM_PRETEND_VERSION=${PV}
+
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# something else may be loading it
+		tests/test_django_settings_module.py::test_django_not_loaded_without_settings
+	)
+
+	local -x DJANGO_SETTINGS_MODULE
+	local -x PYTHONPATH=${PWD}
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	local -x PYTEST_PLUGINS=pytest_django.plugin,xdist.plugin
+	for DJANGO_SETTINGS_MODULE in pytest_django_test.settings_sqlite{,_file}; do
+		einfo "Testing ${DJANGO_SETTINGS_MODULE}"
+		epytest tests
+	done
+}