[gentoo-commits] repo/gentoo:master commit in: net-misc/rdesktop/

["Andreas Sturmlechner" <asturm@gentoo.org>]

commit:     0f2e0c611b08cb86a45d8076ab38966fb8816eba
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Sat Jun 10 22:03:19 2023 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Sat Jun 10 22:56:11 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=0f2e0c61

net-misc/rdesktop: update EAPI 7 -> 8, switch to media-libs/libpulse

Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 net-misc/rdesktop/rdesktop-1.9.0-r4.ebuild | 78 ++++++++++++++++++++++++++++++
 1 file changed, 78 insertions(+)

diff --git a/net-misc/rdesktop/rdesktop-1.9.0-r4.ebuild b/net-misc/rdesktop/rdesktop-1.9.0-r4.ebuild
new file mode 100644
index 000000000000..7d9cffc8104a
--- /dev/null
+++ b/net-misc/rdesktop/rdesktop-1.9.0-r4.ebuild
@@ -0,0 +1,78 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools
+
+DESCRIPTION="A Remote Desktop Protocol Client"
+HOMEPAGE="http://www.rdesktop.org/"
+SRC_URI="https://github.com/${PN}/${PN}/releases/download/v${PV}/${P}.tar.gz"
+S=${WORKDIR}/${PN}-${PV/_/-}
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux ~x64-solaris"
+IUSE="alsa ao ipv6 kerberos oss pcsc-lite pulseaudio xrandr"
+
+RDEPEND="
+	dev-libs/nettle:0=
+	>=net-libs/gnutls-3.2.0:0=
+	x11-libs/libX11
+	x11-libs/libXcursor
+	x11-libs/libXext
+	x11-libs/libXau
+	x11-libs/libXdmcp
+	alsa? (
+		media-libs/alsa-lib
+		media-libs/libsamplerate
+	)
+	ao? (
+		>=media-libs/libao-0.8.6
+		media-libs/libsamplerate
+	)
+	kerberos? ( virtual/krb5 )
+	pcsc-lite? ( >=sys-apps/pcsc-lite-1.6.6 )
+	oss? ( media-libs/libsamplerate )
+	pulseaudio? (
+		media-libs/libpulse
+		media-libs/libsamplerate
+	)
+	xrandr? ( x11-libs/libXrandr )"
+DEPEND="${RDEPEND}
+	x11-libs/libXt"
+BDEPEND="virtual/pkgconfig"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-1.8.3-no_strip.patch
+	"${FILESDIR}"/${PN}-1.8.3-xrandr_configure.patch
+	"${FILESDIR}"/${P}-rdssl_rkey_get_exp_mod.patch
+	"${FILESDIR}"/${P}-gssapi-check.patch
+	"${FILESDIR}"/${P}-configure-clang16.patch
+)
+
+DOCS=( doc/ChangeLog doc/HACKING doc/TODO doc/keymapping.txt )
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	if use pulseaudio; then
+		sound_conf="--with-sound=pulse"
+	elif use ao; then
+		sound_conf="--with-sound=libao"
+	elif use alsa; then
+		sound_conf="--with-sound=alsa"
+	else
+		sound_conf=$(use_with oss sound oss)
+	fi
+
+	econf \
+		$(use_with ipv6) \
+		$(use_with xrandr) \
+		$(use_enable kerberos credssp) \
+		$(use_enable pcsc-lite smartcard) \
+		${sound_conf}
+}