[gentoo-commits] repo/gentoo:master commit in: dev-python/testtools/

["Michał Górny" <mgorny@gentoo.org>]

commit:     79193c01dc68ba0390f044afdeff0c1cffa84e68
Author:     Petr Vaněk <arkamar <AT> atlas <DOT> cz>
AuthorDate: Tue May 30 19:23:14 2023 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Wed May 31 10:49:54 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=79193c01

dev-python/testtools: enable py3.12

New revbump because of changed deps:

- dev-python/python-mimemparse was removed in 2.5.0
- dev-python/pyrsistent was removed in 2.1.0
- dev-python/testresources is used in tests

Signed-off-by: Petr Vaněk <arkamar <AT> atlas.cz>
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/testtools/testtools-2.6.0-r1.ebuild | 52 ++++++++++++++++++++++++++
 1 file changed, 52 insertions(+)

diff --git a/dev-python/testtools/testtools-2.6.0-r1.ebuild b/dev-python/testtools/testtools-2.6.0-r1.ebuild
new file mode 100644
index 000000000000..6af5a459caa1
--- /dev/null
+++ b/dev-python/testtools/testtools-2.6.0-r1.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..12} pypy3 )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Extensions to the Python standard library unit testing framework"
+HOMEPAGE="
+	https://github.com/testing-cabal/testtools/
+	https://pypi.org/project/testtools/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~x64-macos"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-python/pbr-0.11[${PYTHON_USEDEP}]
+	>=dev-python/six-1.4.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		>=dev-python/fixtures-2.0.0[${PYTHON_USEDEP}]
+		dev-python/testscenarios[${PYTHON_USEDEP}]
+		dev-python/testresources[${PYTHON_USEDEP}]
+	)
+"
+PDEPEND="
+	>=dev-python/fixtures-2.0.0[${PYTHON_USEDEP}]
+"
+
+distutils_enable_sphinx doc
+
+src_prepare() {
+	# very fragile to formatting changes (broken on py3.10 & pypy3)
+	sed -i -e 's:test_syntax_error(:_&:' \
+		testtools/tests/test_testresult.py || die
+
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	"${PYTHON}" -m testtools.run testtools.tests.test_suite ||
+		die "tests failed under ${EPYTHON}"
+}