[gentoo-commits] repo/gentoo:master commit in: media-libs/intel-mediasdk/

["Andrew Ammerlaan" <andrewammerlaan@gentoo.org>]

commit:     e81a54269b0407d5e6cb2a4c63593c40acae5345
Author:     Andrew Ammerlaan <andrewammerlaan <AT> gentoo <DOT> org>
AuthorDate: Wed May 31 06:49:00 2023 +0000
Commit:     Andrew Ammerlaan <andrewammerlaan <AT> gentoo <DOT> org>
CommitDate: Wed May 31 06:49:00 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=e81a5426

media-libs/intel-mediasdk: add 23.2.2

Signed-off-by: Andrew Ammerlaan <andrewammerlaan <AT> gentoo.org>

 media-libs/intel-mediasdk/Manifest                 |  1 +
 .../intel-mediasdk/intel-mediasdk-23.2.2.ebuild    | 91 ++++++++++++++++++++++
 2 files changed, 92 insertions(+)

diff --git a/media-libs/intel-mediasdk/Manifest b/media-libs/intel-mediasdk/Manifest
index 39d5078748f0..c3a404846dd0 100644
--- a/media-libs/intel-mediasdk/Manifest
+++ b/media-libs/intel-mediasdk/Manifest
@@ -1,3 +1,4 @@
 DIST intel-mediasdk-22.6.5.tar.gz 11657890 BLAKE2B 53b38f7b3757895f65badb7e43e5d1f1112f744dd4a43ea9313f7bfbdf889088310b2093ccd45794426f0ac5e38ca8d901790d4963945648a3b99922476d02e0 SHA512 af9a59a9a7e9477672a875f454988cc49d8b782b32701ba681efa6dda445239e133b00f9366fc58ddadf79beef0ee74f1165990f0b8194124a841b36d5dca6bc
 DIST intel-mediasdk-23.2.0.tar.gz 22528541 BLAKE2B 12b613ea4e60c99383edb7703892931d5b787d78610972e1cc64c679333ca421c947075cbaec660db1ab4a5f0ac1f816bfa0f0e037e3800612cbfbd2b5038389 SHA512 43faa24cd2b8270dd74845063e2a61635e9d0adf5cf335f5eb805d686cc9feb22e69f1e14fd5cc75c0a4fc665898dde121c469a70a681caace3e18efad57ead5
 DIST intel-mediasdk-23.2.1.tar.gz 22528440 BLAKE2B ee1da0ab86dfce2bb69df3b03fd6773550cbd974ff7461a1ff46a69913194bb7b71a184985f54d82532f6cdd3d5970439bfd9423260849a7cd09541feda59154 SHA512 f37bfb2b2358dbbe68075f03a0ab9b387b063639ad31c247b5d61fb009bc5cc51642109af6dbdeeb07988a3fdd08a5d2f280b2460dfa6c7fc77047c4336e2499
+DIST intel-mediasdk-23.2.2.tar.gz 22527304 BLAKE2B aa0e7b0fabc1bd376511a1022da5e40ea282c4f016384e8bc20fb4e28693e3bb06816ad790da1a708f623ac3a6e6b2f704f785dd4e6cd5c9db320f63c8bded78 SHA512 d4cfebee4f689b93c0171775ff2bab449f801c55822c5b800fe3217653d197216cf2a95dea115cf51f308e158adea7a271f03081b011e024c16bf7915fdcd586

diff --git a/media-libs/intel-mediasdk/intel-mediasdk-23.2.2.ebuild b/media-libs/intel-mediasdk/intel-mediasdk-23.2.2.ebuild
new file mode 100644
index 000000000000..a0674e307b13
--- /dev/null
+++ b/media-libs/intel-mediasdk/intel-mediasdk-23.2.2.ebuild
@@ -0,0 +1,91 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake-multilib optfeature
+
+if [[ ${PV} == *9999 ]] ; then
+	: ${EGIT_REPO_URI:="https://github.com/Intel-Media-SDK/MediaSDK"}
+	if [[ ${PV%9999} != "" ]] ; then
+		: ${EGIT_BRANCH:="release/${PV%.9999}"}
+	fi
+	inherit git-r3
+fi
+
+DESCRIPTION="Intel Media SDK"
+HOMEPAGE="https://github.com/Intel-Media-SDK/MediaSDK"
+if [[ ${PV} == *9999 ]] ; then
+	SRC_URI=""
+else
+	SRC_URI="https://github.com/Intel-Media-SDK/MediaSDK/archive/intel-mediasdk-${PV}.tar.gz"
+	S="${WORKDIR}/MediaSDK-intel-mediasdk-${PV}"
+	KEYWORDS="~amd64"
+fi
+
+LICENSE="MIT"
+SLOT="0"
+
+IUSE="dri test tools wayland X"
+# Test not working at the moment
+#RESTRICT="!test? ( test )"
+RESTRICT="test"
+REQUIRED_USE="
+	dri? ( X )
+"
+
+# x11-libs/libdrm[video_cards_intel] for intel_bufmgr.h in samples
+# bug #805224
+RDEPEND="
+	x11-libs/libpciaccess[${MULTILIB_USEDEP}]
+	>=media-libs/libva-intel-media-driver-${PV}[${MULTILIB_USEDEP}]
+	media-libs/libva[X?,wayland?,${MULTILIB_USEDEP}]
+	x11-libs/libdrm[video_cards_intel,${MULTILIB_USEDEP}]
+	wayland? (
+		dev-libs/wayland[${MULTILIB_USEDEP}]
+	)
+	X? (
+		x11-libs/libX11[${MULTILIB_USEDEP}]
+		x11-libs/libxcb[${MULTILIB_USEDEP}]
+	)
+"
+DEPEND="${RDEPEND}
+	wayland? (
+		dev-libs/wayland-protocols
+	)
+"
+BDEPEND="
+	wayland? (
+		dev-util/wayland-scanner
+	)
+"
+
+PATCHES=(
+	# https://github.com/Intel-Media-SDK/MediaSDK/pull/2998
+	"${FILESDIR}/${PN}-23.2.0-gcc13.patch"
+)
+
+multilib_src_configure() {
+	local mycmakeargs=(
+		# OpenCL only has an effect if we build kernels
+		-DENABLE_OPENCL=OFF
+		-DBUILD_TUTORIALS=OFF
+		# Need to package the cm-compiler to build kernels, use pre-built instead
+		-DBUILD_KERNELS=OFF
+		-DBUILD_RUNTIME=ON
+		-DBUILD_DISPATCHER=ON
+		-DBUILD_TOOLS="$(usex tools)"
+		# Cannot build tools without samples
+		-DBUILD_SAMPLES="$(usex tools)"
+		-DBUILD_TESTS="$(usex test)"
+		-DENABLE_X11="$(usex X)"
+		-DENABLE_X11_DRI3="$(usex dri)"
+		-DENABLE_WAYLAND="$(usex wayland)"
+	)
+
+	cmake_src_configure
+}
+
+pkg_postinst() {
+	optfeature "Intel GPUs newer then, and including, Intel Xe" media-libs/oneVPL-intel-gpu
+}