[gentoo-commits] repo/gentoo:master commit in: www-plugins/lightspark/

["Michał Górny" <mgorny@gentoo.org>]

commit:     f9d2d7c6ce85916967a26fc68ee0daac7fd42701
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Mon May 29 06:12:53 2023 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Mon May 29 06:23:15 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=f9d2d7c6

www-plugins/lightspark: Bump to 0.8.7

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 www-plugins/lightspark/Manifest                |   1 +
 www-plugins/lightspark/lightspark-0.8.7.ebuild | 100 +++++++++++++++++++++++++
 2 files changed, 101 insertions(+)

diff --git a/www-plugins/lightspark/Manifest b/www-plugins/lightspark/Manifest
index 6be67ba1eca0..4fd489882718 100644
--- a/www-plugins/lightspark/Manifest
+++ b/www-plugins/lightspark/Manifest
@@ -1 +1,2 @@
 DIST lightspark-0.8.6.1.tar.gz 5419194 BLAKE2B dfe56f604c6dd9f9848c1cedffce5bc2a20f51a8b42405f5a38ddbc5c5a1db87e69cba99f5045cd7f60957e46992da8442d95d7ef929bcb806ed5ab0a17f084e SHA512 ea54b3d66acfcb12aac271669d550f6aa1709db59d4bcc005479b7be394a4ca30473a993a780c632228eeaad2977d97cdbcadff5cf8abbbf07503f9d56192f31
+DIST lightspark-0.8.7.tar.gz 5440706 BLAKE2B 53486183672c35a8b8040177ebc738e588c3ea39a316d2dd10fc4868393b0befea5ac9f411cdb87aad608f02df2f04e07b4a7f8a0635c0f6e0dee465469709f4 SHA512 a0207629238054d669710fcb4d6b1904624d4ed8fb19cf822447e55107d6c3596f6e9fb425c14968365a1c8224b7c3a899008428fd69c9714a03a74230e64f2f

diff --git a/www-plugins/lightspark/lightspark-0.8.7.ebuild b/www-plugins/lightspark/lightspark-0.8.7.ebuild
new file mode 100644
index 000000000000..29b4fcc7e999
--- /dev/null
+++ b/www-plugins/lightspark/lightspark-0.8.7.ebuild
@@ -0,0 +1,100 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake xdg-utils
+
+DESCRIPTION="High performance flash player"
+HOMEPAGE="https://lightspark.github.io/"
+SRC_URI="
+	https://github.com/lightspark/lightspark/archive/${PV}.tar.gz
+		-> ${P}.tar.gz
+"
+S=${WORKDIR}/${P/_rc*/}
+
+LICENSE="LGPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="cpu_flags_x86_sse2 curl ffmpeg gles2-only nsplugin ppapi profile rtmp"
+
+# Note: no LLVM since it's broken upstream
+RDEPEND="
+	app-arch/xz-utils:=
+	dev-libs/glib
+	dev-libs/libpcre:=[cxx]
+	media-fonts/liberation-fonts
+	media-libs/freetype:=
+	media-libs/libjpeg-turbo:=
+	media-libs/libpng:=
+	media-libs/libsdl2
+	sys-libs/zlib:=
+	x11-libs/cairo
+	x11-libs/libX11
+	x11-libs/pango
+	curl? ( net-misc/curl:= )
+	ffmpeg? ( media-video/ffmpeg:= )
+	gles2-only? ( media-libs/mesa:=[gles2] )
+	!gles2-only? (
+		>=media-libs/glew-1.5.3:=
+		virtual/opengl:0=
+	)
+	rtmp? ( media-video/rtmpdump:= )
+"
+DEPEND="
+	${RDEPEND}
+"
+BDEPEND="
+	amd64? ( dev-lang/nasm )
+	x86? ( dev-lang/nasm )
+	virtual/pkgconfig
+"
+
+src_configure() {
+	local mycmakeargs=(
+		-DENABLE_CURL=$(usex curl)
+		-DENABLE_GLES2=$(usex gles2-only)
+		-DENABLE_LIBAVCODEC=$(usex ffmpeg)
+		-DENABLE_RTMP=$(usex rtmp)
+
+		-DENABLE_MEMORY_USAGE_PROFILING=$(usex profile)
+		-DENABLE_PROFILING=$(usex profile)
+		-DENABLE_SSE2=$(usex cpu_flags_x86_sse2)
+
+		-DCOMPILE_NPAPI_PLUGIN=$(usex nsplugin)
+		-DPLUGIN_DIRECTORY="${EPREFIX}"/usr/$(get_libdir)/${PN}/plugins
+		# TODO: install /etc/chromium file? block adobe-flash?
+		-DCOMPILE_PPAPI_PLUGIN=$(usex ppapi)
+		-DPPAPI_PLUGIN_DIRECTORY="${EPREFIX}"/usr/$(get_libdir)/chromium-browser/${PN}
+	)
+
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+
+	if use nsplugin; then
+		# copied from nsplugins.eclass, that's broken in EAPI 7
+		dodir /usr/$(get_libdir)/nsbrowser/plugins
+		dosym ../../lightspark/plugins/liblightsparkplugin.so \
+			/usr/$(get_libdir)/nsbrowser/plugins/liblightsparkplugin.so
+	fi
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+	xdg_desktop_database_update
+
+	if use nsplugin && has_version "www-plugins/gnash[nsplugin]"; then
+		elog "Having two plugins installed for the same MIME type may confuse"
+		elog "Mozilla based browsers. It is recommended to disable the nsplugin"
+		elog "USE flag for either gnash or lightspark. For details, see"
+		elog "https://bugzilla.mozilla.org/show_bug.cgi?id=581848"
+	fi
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+	xdg_desktop_database_update
+}