[gentoo-commits] repo/gentoo:master commit in: net-p2p/transmission/

["Mike Gilbert" <floppym@gentoo.org>]

commit:     87cafe04fb8ae01d45e96de56ca14125064b44d0
Author:     Mike Gilbert <floppym <AT> gentoo <DOT> org>
AuthorDate: Sat May  6 17:49:40 2023 +0000
Commit:     Mike Gilbert <floppym <AT> gentoo <DOT> org>
CommitDate: Sat May  6 17:49:40 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=87cafe04

net-p2p/transmission: drop 4.0.2

Signed-off-by: Mike Gilbert <floppym <AT> gentoo.org>

 net-p2p/transmission/Manifest                  |   1 -
 net-p2p/transmission/transmission-4.0.2.ebuild | 153 -------------------------
 2 files changed, 154 deletions(-)

diff --git a/net-p2p/transmission/Manifest b/net-p2p/transmission/Manifest
index 761067bb06a4..e32f0a53fc43 100644
--- a/net-p2p/transmission/Manifest
+++ b/net-p2p/transmission/Manifest
@@ -1,3 +1,2 @@
 DIST transmission-3.00.tar.xz 3995080 BLAKE2B fb1be44aa630e6a1cf15511ab4ab40156edb16f9410b83058c53548f466fb9502c23157756a29e921e4468db1ebac7832b755cfcf98451c663c64401559f5498 SHA512 c8fb96086ba4b18f04d6181a29f6e2af85864840c533f3470a202dfa686e9431caeccd25f12c975a9a8f9b7802ca0bd73c4edc1ca06bdbada682326cad188a76
-DIST transmission-4.0.2.tar.xz 10055708 BLAKE2B bab21145013ade7eb457bc6f847c7670a6f71780e50abfe190639826d02b4cc57876f31e0911655279c44d231a95a9068697d8390e0c1a9418151d266b7024cd SHA512 84784e0c06d4595674710dbc3caac545e0bcf69bef44f2d681ed80ed6722dbb24fc4b8cba39dd957e0e3a276b6b664f8a938087d930f633ebfe9af16e7afcbf4
 DIST transmission-4.0.3.tar.xz 10062044 BLAKE2B 3d58f002d57458869e143e4a3617c8992e51a01f15f0e17031bc2913f404a455cde3397bde404f84a2234d12411e99b2902e4213ca6811b95288bb68f9b98553 SHA512 246d4af2f9b399cb5a6e43ca0852d2ab5ff48d2a5c89d0f450c968fcad042ef2e45fef3c9be8ffbf37e7c61dc509929869b6bf59914333818ddf6950582d669c

diff --git a/net-p2p/transmission/transmission-4.0.2.ebuild b/net-p2p/transmission/transmission-4.0.2.ebuild
deleted file mode 100644
index c75d92d0e1a1..000000000000
--- a/net-p2p/transmission/transmission-4.0.2.ebuild
+++ /dev/null
@@ -1,153 +0,0 @@
-# Copyright 2006-2023 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-inherit cmake flag-o-matic tmpfiles systemd xdg-utils
-
-if [[ ${PV} == 9999 ]]; then
-	inherit git-r3
-	EGIT_REPO_URI="https://github.com/transmission/transmission"
-else
-	MY_PV="${PV/_beta/-beta.}"
-	MY_P="${PN}-${MY_PV}"
-	S="${WORKDIR}/${MY_P}"
-	SRC_URI="https://github.com/transmission/transmission/releases/download/${MY_PV}/${MY_P}.tar.xz"
-	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~x86"
-fi
-
-DESCRIPTION="A fast, easy, and free BitTorrent client"
-HOMEPAGE="https://transmissionbt.com/"
-
-# web/LICENSE is always GPL-2 whereas COPYING allows either GPL-2 or GPL-3 for the rest
-# transmission in licenses/ is for mentioning OpenSSL linking exception
-# MIT is in several libtransmission/ headers
-LICENSE="|| ( GPL-2 GPL-3 Transmission-OpenSSL-exception ) GPL-2 MIT"
-SLOT="0"
-IUSE="appindicator cli debug gtk nls mbedtls qt5 qt6 systemd test"
-REQUIRED_USE="?? ( qt5 qt6 )"
-RESTRICT="!test? ( test )"
-
-ACCT_DEPEND="
-	acct-group/transmission
-	acct-user/transmission
-"
-BDEPEND="
-	virtual/pkgconfig
-	nls? (
-		gtk? ( sys-devel/gettext )
-	)
-	qt5? ( dev-qt/linguist-tools:5 )
-	qt6? ( dev-qt/qttools:6[linguist] )
-"
-COMMON_DEPEND="
-	>=dev-libs/libevent-2.1.0:=[threads(+)]
-	!mbedtls? ( dev-libs/openssl:0= )
-	mbedtls? ( net-libs/mbedtls:0= )
-	net-libs/libnatpmp
-	>=net-libs/libpsl-0.21.1
-	>=net-libs/miniupnpc-1.7:=
-	>=net-misc/curl-7.28.0[ssl]
-	sys-libs/zlib:=
-	nls? ( virtual/libintl )
-	gtk? (
-		>=dev-cpp/gtkmm-3.24.0:3.0
-		>=dev-cpp/glibmm-2.60.0:2
-		appindicator? ( dev-libs/libayatana-appindicator )
-	)
-	qt5? (
-		dev-qt/qtcore:5
-		dev-qt/qtdbus:5
-		dev-qt/qtgui:5
-		dev-qt/qtnetwork:5
-		dev-qt/qtsvg:5
-		dev-qt/qtwidgets:5
-	)
-	qt6? (
-		dev-qt/qtbase:6[dbus,gui,network,widgets]
-		dev-qt/qtsvg:6
-	)
-	systemd? ( >=sys-apps/systemd-209:= )
-"
-DEPEND="${COMMON_DEPEND}
-	nls? ( virtual/libintl )
-"
-RDEPEND="${COMMON_DEPEND}
-	${ACCT_DEPEND}
-"
-
-src_configure() {
-	local mycmakeargs=(
-		-DCMAKE_INSTALL_DOCDIR=share/doc/${PF}
-
-		-DENABLE_GTK=$(usex gtk ON OFF)
-		-DENABLE_MAC=OFF
-		-DREBUILD_WEB=OFF
-		-DENABLE_CLI=$(usex cli ON OFF)
-		-DENABLE_TESTS=$(usex test ON OFF)
-		-DENABLE_NLS=$(usex nls ON OFF)
-
-		-DRUN_CLANG_TIDY=OFF
-
-		-DUSE_GTK_VERSION=3
-		-DUSE_SYSTEM_EVENT2=ON
-		-DUSE_SYSTEM_DEFLATE=OFF
-		-DUSE_SYSTEM_DHT=OFF
-		-DUSE_SYSTEM_MINIUPNPC=ON
-		-DUSE_SYSTEM_NATPMP=ON
-		-DUSE_SYSTEM_UTP=OFF
-		-DUSE_SYSTEM_B64=OFF
-		-DUSE_SYSTEM_PSL=ON
-
-		-DWITH_CRYPTO=$(usex mbedtls mbedtls openssl)
-		-DWITH_INOTIFY=ON
-		-DWITH_APPINDICATOR=$(usex appindicator ON OFF)
-		-DWITH_SYSTEMD=$(usex systemd ON OFF)
-	)
-
-	if use qt6; then
-		mycmakeargs+=( -DENABLE_QT=ON -DUSE_QT_VERSION=6 )
-	elif use qt5; then
-		mycmakeargs+=( -DENABLE_QT=ON -DUSE_QT_VERSION=5 )
-	else
-		mycmakeargs+=( -DENABLE_QT=OFF )
-	fi
-
-	# Disable assertions by default, bug 893870.
-	use debug || append-cppflags -DNDEBUG
-
-	cmake_src_configure
-}
-
-src_install() {
-	cmake_src_install
-
-	newinitd "${FILESDIR}"/transmission-daemon.initd.10 transmission-daemon
-	newconfd "${FILESDIR}"/transmission-daemon.confd.4 transmission-daemon
-
-	if use systemd; then
-		# Service sets Type=notify
-		systemd_dounit daemon/transmission-daemon.service
-		systemd_install_serviced "${FILESDIR}"/transmission-daemon.service.conf
-	fi
-
-	insinto /usr/lib/sysctl.d
-	doins "${FILESDIR}"/60-transmission.conf
-
-	newtmpfiles "${FILESDIR}"/transmission-daemon.tmpfiles transmission-daemon.conf
-}
-
-pkg_postrm() {
-	if use gtk || use qt5 || use qt6; then
-		xdg_desktop_database_update
-		xdg_icon_cache_update
-	fi
-}
-
-pkg_postinst() {
-	if use gtk || use qt5 || use qt6; then
-		xdg_desktop_database_update
-		xdg_icon_cache_update
-	fi
-	tmpfiles_process transmission-daemon.conf
-}