[gentoo-commits] repo/gentoo:master commit in: x11-terms/kitty/

["Ionen Wolkens" <ionen@gentoo.org>]

commit:     d79e18e341df44aecc8d581f99fcc4fc48968d4e
Author:     Ionen Wolkens <ionen <AT> gentoo <DOT> org>
AuthorDate: Mon Apr 24 03:08:28 2023 +0000
Commit:     Ionen Wolkens <ionen <AT> gentoo <DOT> org>
CommitDate: Mon Apr 24 03:22:20 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=d79e18e3

x11-terms/kitty: drop 0.26.5-r1, 0.28.0

Signed-off-by: Ionen Wolkens <ionen <AT> gentoo.org>

 x11-terms/kitty/Manifest               |   5 -
 x11-terms/kitty/kitty-0.26.5-r1.ebuild | 127 ------------------------
 x11-terms/kitty/kitty-0.28.0.ebuild    | 170 ---------------------------------
 3 files changed, 302 deletions(-)

diff --git a/x11-terms/kitty/Manifest b/x11-terms/kitty/Manifest
index fee52b68f543..096fec6c58fe 100644
--- a/x11-terms/kitty/Manifest
+++ b/x11-terms/kitty/Manifest
@@ -1,11 +1,6 @@
-DIST kitty-0.26.5.tar.xz 4749988 BLAKE2B 488969b4d7c6aed489a540a8e3bee183345fcfb7e05ae5604f4af40f0720ed931cff82cf389e2fa4015eed74762c0630481a99eeb9302c22c89c4f3e247170d4 SHA512 086ae03d0e382afbe3001e357ef51388c7a8e81fa5b4bf9ce8b123a7fc8bfff3bd68d074e926f540a1f2b83062baa831e44d29c017cabfe8221bebe49b64e808
-DIST kitty-0.26.5.tar.xz.sig 566 BLAKE2B 377202d46e66854e0cf1998506e0fafca54b33d85264e47c13aa4b98d272c786809375f1e277ec169291e06809f11b5b061ec1243a708711fa2350243ad1eca2 SHA512 0c691d8becff2b0f24e09b941d7315efaac831beacfed6f66b9186bde9c502f2ae86289f4b0d8fa6a34624dce7a1e958ba2d0502fd87003ba08b07fa07c6ae17
 DIST kitty-0.27.1-vendor.tar.xz 695432 BLAKE2B 86c9a316351432e0ff14bf139158816ddabe7e16d91768694a8560a500765b518ba42db26ad24349c05caece5771c5db4fdf7077f06631d1e81ea9ddb52e0391 SHA512 f96366b7896a34202110c98a9f2177482a01102fb822bd33c46eeb6ffe096fce927213950bab658a6649e1874e936c479ea7884d3518a0d054e2f598d6402bdf
 DIST kitty-0.27.1.tar.xz 5045588 BLAKE2B 2381b3e9af26bb8a4c4358318289e9ef49ba1e38678ef192fd815ced962644671433a80f124579fb593257351cd8e0a61f845975d61d0d33f42b9d470ef130f0 SHA512 484d451b418defc7256319730d623224e3744d6200989d92839c40c951fdb213fe2ef472ddf968f695e499aa6c35d994ad76bb0eb28bca80ec8644b2ead40d56
 DIST kitty-0.27.1.tar.xz.sig 566 BLAKE2B 49cb96d99c48cfe74a50191687fac269cdc33146b5879acbb298c3c9bc7760eda1b2b08839f531d6fe4cf46287d671a1f6a6a24ffe6d6408939d113ba40545db SHA512 b4d24f24ea49c342756d0e458c22e856c4117f07f197ee5294b07ac0a8b5e9d992446b86effb5a7aa1683582cf9ee59bcf651ae4f3952df7783f0a4438042799
-DIST kitty-0.28.0-vendor.tar.xz 1324380 BLAKE2B 0e10660fd5ff95827746ba2f669a8941a1855958e91ca623090c184d972e39ba9b8b8c773321de812429345f75f3b6d75af9f5e70a3aff1e638afa718801133a SHA512 7c871feb7dda605b9b7af42b9136b6047b6442a06e7e7e0a1ff9dd74d845100d70359f88c07e1dc86dc6e39e8e2a850c1a7619a5cbb696b6000957b50783d545
-DIST kitty-0.28.0.tar.xz 7900352 BLAKE2B fea1944e818354522a386d9d6bfa778e70bef3404c3b3f3c87667cee16edc54206540d0ef022f1383e22ed1caf929cc839b226da21c86f9d9b1cda8f8a9a847f SHA512 d133dab019c67367e90cc2e2dce7e614a65400b079cdcfa854f2e1cb7399af7b1ba0f3ef4d30867ae588c9919a772c03ee12457b6dc5922f58c034a6da927127
-DIST kitty-0.28.0.tar.xz.sig 566 BLAKE2B cd52127069a443f7b94de173d7b7497be88420032907a555cea40ad922dfa4a67701e62fbb93dceae280bd21e28a352a02a84e48a3678f63e5312d3121d713e6 SHA512 2d9d147eca26496bdba17551eca64a07437c5ea183c0a748a76418374963742c5cfe20b68c0102b5afe2f9f1b36be58736f014d54c028d33f55d940a32213ac6
 DIST kitty-0.28.1-vendor.tar.xz 1344988 BLAKE2B 768a2859f18b743a23007be60323035f54375496cb08d45dabab12ca09b3227451f7c1e78dda72bc79712835e1e0541549b1c1f7b5f68f8b1164062c77ba7520 SHA512 bc111e7428660d79e116a88f0c62c4dc54c79c423c364156219c5a6251f0725fc43e34e8b518352b00433c2443371619b4f6ab5c41d32ddf129c42f98ced0694
 DIST kitty-0.28.1.tar.xz 7850232 BLAKE2B 18567e54bbd2ac183120122847951744bb8494829911d4c66b5db23488fcc257c895b8d788c1b386ffec832aceb4f691a8a10339be07d43e54957c9c98365a01 SHA512 a8863c8bf5a3c385671d98bd50481ffcd3984e45ee051173eb38de9aac79643e69a312e08b8f655759f3ecdfab4efe38dca39167f5590e482748b5e85dea5537
 DIST kitty-0.28.1.tar.xz.sig 566 BLAKE2B 5ad5fa8fa0143dcd5760dbd885c718582e5001d2eeb5b6b559abffd556407e1061ebe9c84757f49c57803233f38ebe6f7d813f9f50a55b7ce8532c0f589cd8ae SHA512 cf13e09978187c19d53903aea0032ef2088950eb050e0d183283919e96d9a2ae14dd2a40f63ee0fc5180be3e5a9066ade86943f1bcac042d6da890fa2ed13720

diff --git a/x11-terms/kitty/kitty-0.26.5-r1.ebuild b/x11-terms/kitty/kitty-0.26.5-r1.ebuild
deleted file mode 100644
index f0c2d68f5c55..000000000000
--- a/x11-terms/kitty/kitty-0.26.5-r1.ebuild
+++ /dev/null
@@ -1,127 +0,0 @@
-# Copyright 1999-2023 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-PYTHON_COMPAT=( python3_{9..11} )
-inherit edo optfeature multiprocessing python-single-r1 toolchain-funcs xdg
-
-if [[ ${PV} == 9999 ]]; then
-	inherit git-r3
-	EGIT_REPO_URI="https://github.com/kovidgoyal/kitty.git"
-else
-	inherit verify-sig
-	SRC_URI="
-		https://github.com/kovidgoyal/kitty/releases/download/v${PV}/${P}.tar.xz
-		verify-sig? ( https://github.com/kovidgoyal/kitty/releases/download/v${PV}/${P}.tar.xz.sig )"
-	VERIFY_SIG_OPENPGP_KEY_PATH="${BROOT}/usr/share/openpgp-keys/kovidgoyal.gpg"
-	KEYWORDS="amd64 ~ppc64 ~riscv x86"
-fi
-
-DESCRIPTION="Fast, feature-rich, GPU-based terminal"
-HOMEPAGE="https://sw.kovidgoyal.net/kitty/"
-
-LICENSE="GPL-3"
-SLOT="0"
-IUSE="+X test wayland"
-REQUIRED_USE="
-	${PYTHON_REQUIRED_USE}
-	|| ( X wayland )
-	test? ( X wayland )"
-RESTRICT="!test? ( test )"
-
-# dlopen: fontconfig,libglvnd
-RDEPEND="
-	${PYTHON_DEPS}
-	dev-libs/openssl:=
-	media-libs/fontconfig
-	media-libs/harfbuzz:=
-	media-libs/lcms:2
-	media-libs/libglvnd[X?]
-	media-libs/libpng:=
-	net-libs/librsync:=
-	sys-apps/dbus
-	sys-libs/zlib:=
-	x11-libs/libxkbcommon[X?]
-	x11-misc/xkeyboard-config
-	~x11-terms/kitty-shell-integration-${PV}
-	~x11-terms/kitty-terminfo-${PV}
-	X? ( x11-libs/libX11 )
-	wayland? ( dev-libs/wayland )"
-DEPEND="
-	${RDEPEND}
-	X? (
-		x11-base/xorg-proto
-		x11-libs/libXcursor
-		x11-libs/libXi
-		x11-libs/libXinerama
-		x11-libs/libXrandr
-	)
-	wayland? ( dev-libs/wayland-protocols )"
-BDEPEND="
-	${PYTHON_DEPS}
-	sys-libs/ncurses
-	virtual/pkgconfig
-	test? ( $(python_gen_cond_dep 'dev-python/pillow[${PYTHON_USEDEP}]') )
-	wayland? ( dev-util/wayland-scanner )"
-[[ ${PV} == 9999 ]] || BDEPEND+=" verify-sig? ( sec-keys/openpgp-keys-kovidgoyal )"
-
-src_prepare() {
-	default
-
-	# seds unfortunately feel easier on maintainenance than patches here
-	sed -e "s/'x11 wayland'/'$(usev X x11) $(usev wayland)'/" \
-		-e "$(usev !X '/gl_libs =/s/=.*/= []/')" \
-		-e "/num_workers =/s/=.*/= $(makeopts_jobs)/" \
-		-e "s/cflags.append.*-O3.*/pass/" -e 's/-O3//' \
-		-i setup.py || die
-
-	# test relies on 'who' command which doesn't detect users with pid-sandbox
-	rm kitty_tests/utmp.py || die
-
-	# test may fail/hang depending on environment and shell initialization scripts
-	rm kitty_tests/{shell_integration,ssh}.py || die
-
-	# skip docs for live version
-	[[ ${PV} != 9999 ]] || sed -i '/exists.*_build/,/docs(ddir)/d' setup.py || die
-}
-
-src_compile() {
-	tc-export CC
-	export PKGCONFIG_EXE=$(tc-getPKG_CONFIG)
-
-	local conf=(
-		--disable-link-time-optimization
-		--ignore-compiler-warnings
-		--libdir-name=$(get_libdir)
-		--shell-integration="enabled no-rc"
-		--update-check-interval=0
-		--verbose
-	)
-
-	edo ${EPYTHON} setup.py linux-package "${conf[@]}"
-	use test && edo ${EPYTHON} setup.py build-launcher "${conf[@]}"
-
-	[[ ${PV} == 9999 ]] || mv linux-package/share/doc/{${PN},${PF}} || die
-	rm -r linux-package/share/terminfo || die
-}
-
-src_test() {
-	KITTY_CONFIG_DIRECTORY=${T} ./test.py || die # shebang is kitty
-}
-
-src_install() {
-	insinto /usr
-	doins -r linux-package/.
-
-	fperms +x /usr/bin/kitty \
-		/usr/$(get_libdir)/kitty/shell-integration/ssh/{askpass.py,kitty}
-}
-
-pkg_postinst() {
-	xdg_pkg_postinst
-
-	optfeature "in-terminal image display with kitty icat" media-gfx/imagemagick
-	optfeature "audio-based terminal bell support" media-libs/libcanberra
-	optfeature "opening links from the terminal" x11-misc/xdg-utils
-}

diff --git a/x11-terms/kitty/kitty-0.28.0.ebuild b/x11-terms/kitty/kitty-0.28.0.ebuild
deleted file mode 100644
index 4f133e2c0b61..000000000000
--- a/x11-terms/kitty/kitty-0.28.0.ebuild
+++ /dev/null
@@ -1,170 +0,0 @@
-# Copyright 1999-2023 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-PYTHON_COMPAT=( python3_{9..11} )
-inherit edo optfeature multiprocessing python-single-r1 toolchain-funcs xdg
-
-if [[ ${PV} == 9999 ]]; then
-	inherit git-r3
-	EGIT_REPO_URI="https://github.com/kovidgoyal/kitty.git"
-else
-	inherit verify-sig
-	SRC_URI="
-		https://github.com/kovidgoyal/kitty/releases/download/v${PV}/${P}.tar.xz
-		https://dev.gentoo.org/~ionen/distfiles/${P}-vendor.tar.xz
-		verify-sig? ( https://github.com/kovidgoyal/kitty/releases/download/v${PV}/${P}.tar.xz.sig )"
-	VERIFY_SIG_OPENPGP_KEY_PATH="${BROOT}/usr/share/openpgp-keys/kovidgoyal.gpg"
-	KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86"
-fi
-
-DESCRIPTION="Fast, feature-rich, GPU-based terminal"
-HOMEPAGE="https://sw.kovidgoyal.net/kitty/"
-
-LICENSE="GPL-3 ZLIB"
-LICENSE+=" Apache-2.0 BSD MIT" # go
-SLOT="0"
-IUSE="+X test wayland"
-REQUIRED_USE="
-	${PYTHON_REQUIRED_USE}
-	|| ( X wayland )
-	test? ( X wayland )"
-RESTRICT="!test? ( test )"
-
-# dlopen: fontconfig,libglvnd
-RDEPEND="
-	${PYTHON_DEPS}
-	dev-libs/openssl:=
-	media-libs/fontconfig
-	media-libs/harfbuzz:=
-	media-libs/lcms:2
-	media-libs/libglvnd[X?]
-	media-libs/libpng:=
-	net-libs/librsync:=
-	sys-apps/dbus
-	sys-libs/zlib:=
-	x11-libs/libxkbcommon[X?]
-	x11-misc/xkeyboard-config
-	~x11-terms/kitty-shell-integration-${PV}
-	~x11-terms/kitty-terminfo-${PV}
-	X? ( x11-libs/libX11 )
-	wayland? ( dev-libs/wayland )
-	!sci-mathematics/kissat"
-DEPEND="
-	${RDEPEND}
-	X? (
-		x11-base/xorg-proto
-		x11-libs/libXcursor
-		x11-libs/libXi
-		x11-libs/libXinerama
-		x11-libs/libXrandr
-	)
-	wayland? ( dev-libs/wayland-protocols )"
-BDEPEND="
-	${PYTHON_DEPS}
-	>=dev-lang/go-1.20
-	sys-libs/ncurses
-	virtual/pkgconfig
-	test? ( $(python_gen_cond_dep 'dev-python/pillow[${PYTHON_USEDEP}]') )
-	wayland? ( dev-util/wayland-scanner )"
-[[ ${PV} == 9999 ]] || BDEPEND+=" verify-sig? ( sec-keys/openpgp-keys-kovidgoyal )"
-
-# kitten: written in Go
-# *.so: unsure for their use but they have no objects, so CFLAGS play no part
-QA_FLAGS_IGNORED="
-	usr/bin/kitten
-	usr/lib.*/kitty/kittens/diff/diff_speedup.so
-	usr/lib.*/kitty/kittens/unicode_input/unicode_names.so"
-
-src_unpack() {
-	if [[ ${PV} == 9999 ]]; then
-		git-r3_src_unpack
-		cd "${S}" || die
-		edo go mod vendor
-	else
-		use verify-sig &&
-			verify-sig_verify_detached "${DISTDIR}"/${P}.tar.xz{,.sig}
-		default
-	fi
-}
-
-src_prepare() {
-	default
-
-	# sed unfortunately feels easier on maintenance than patches here
-	local sedargs=(
-		-e "/num_workers =/s/=.*/= $(makeopts_jobs)/"
-		-e "s/cflags.append.*-O3.*/pass/" -e 's/-O3//'
-		-e "s/ld_flags.append('-[sw]')/pass/"
-	)
-
-	# kitty is often popular on wayland-only setups, try to allow this
-	use !X && sedargs+=( -e '/gl_libs =/s/=.*/= []/' ) #857918
-	use !X || use !wayland &&
-		sedargs+=( -e "s/'x11 wayland'/'$(usex X x11 wayland)'/" )
-
-	# skip docs for live version, missing dependencies
-	[[ ${PV} == 9999 ]] && sedargs+=( -e '/exists.*_build/,/docs(ddir)/d' )
-
-	sed -i setup.py "${sedargs[@]}" || die
-
-	local skiptests=(
-		# relies on 'who' command which doesn't detect users with pid-sandbox
-		kitty_tests/utmp.py
-		# may fail/hang depending on environment and shell initialization
-		kitty_tests/{shell_integration,ssh}.py
-		# relies on /proc/self/fd and gets confused when ran from here
-		tools/utils/tpmfile_test.go
-	)
-	use !test || rm "${skiptests[@]}" || die
-}
-
-src_compile() {
-	tc-export CC
-	local -x GOFLAGS="-p=$(makeopts_jobs) -v -x"
-	use ppc64 && [[ $(tc-endian) == big ]] || GOFLAGS+=" -buildmode=pie"
-	local -x PKGCONFIG_EXE=$(tc-getPKG_CONFIG)
-
-	local conf=(
-		--disable-link-time-optimization
-		--ignore-compiler-warnings
-		--libdir-name=$(get_libdir)
-		--shell-integration="enabled no-rc"
-		--update-check-interval=0
-		--verbose
-	)
-
-	edo "${EPYTHON}" setup.py linux-package "${conf[@]}"
-	use test && edo "${EPYTHON}" setup.py build-launcher "${conf[@]}"
-
-	rm -r linux-package/share/terminfo || die # provided by kitty-terminfo
-
-	if [[ ${PV} == 9999 ]]; then
-		mkdir -p linux-package/share/doc/${PF} || die
-	else
-		mv linux-package/share/doc/{${PN},${PF}} || die
-	fi
-
-	# generate default config as reference, command taken from docs/conf.rst
-	if ! tc-is-cross-compiler; then
-		linux-package/bin/kitty +runpy \
-			'from kitty.config import *; print(commented_out_default_config())' \
-			> linux-package/share/doc/${PF}/kitty.conf || die
-	fi
-}
-
-src_test() {
-	KITTY_CONFIG_DIRECTORY=${T} ./test.py || die # shebang is kitty
-}
-
-src_install() {
-	edo mv linux-package "${ED}"/usr
-}
-
-pkg_postinst() {
-	xdg_pkg_postinst
-
-	optfeature "audio-based terminal bell support" media-libs/libcanberra
-	optfeature "opening links from the terminal" x11-misc/xdg-utils
-}