From mboxrd@z Thu Jan  1 00:00:00 1970
Return-Path: <gentoo-commits+bounces-1498371-garchives=archives.gentoo.org@lists.gentoo.org>
Received: from lists.gentoo.org (pigeon.gentoo.org [208.92.234.80])
	(using TLSv1.3 with cipher TLS_AES_256_GCM_SHA384 (256/256 bits)
	 key-exchange X25519 server-signature RSA-PSS (2048 bits))
	(No client certificate requested)
	by finch.gentoo.org (Postfix) with ESMTPS id 90BB015A7D9
	for <garchives@archives.gentoo.org>; Sat, 18 Mar 2023 23:22:46 +0000 (UTC)
Received: from pigeon.gentoo.org (localhost [127.0.0.1])
	by pigeon.gentoo.org (Postfix) with SMTP id D008BE08F1;
	Sat, 18 Mar 2023 23:22:45 +0000 (UTC)
Received: from smtp.gentoo.org (woodpecker.gentoo.org [IPv6:2001:470:ea4a:1:5054:ff:fec7:86e4])
	(using TLSv1.3 with cipher TLS_AES_256_GCM_SHA384 (256/256 bits)
	 key-exchange X25519 server-signature RSA-PSS (4096 bits))
	(No client certificate requested)
	by pigeon.gentoo.org (Postfix) with ESMTPS id AF4F4E08F1
	for <gentoo-commits@lists.gentoo.org>; Sat, 18 Mar 2023 23:22:45 +0000 (UTC)
Received: from oystercatcher.gentoo.org (oystercatcher.gentoo.org [148.251.78.52])
	(using TLSv1.3 with cipher TLS_AES_256_GCM_SHA384 (256/256 bits)
	 key-exchange X25519 server-signature RSA-PSS (4096 bits))
	(No client certificate requested)
	by smtp.gentoo.org (Postfix) with ESMTPS id E995134126C
	for <gentoo-commits@lists.gentoo.org>; Sat, 18 Mar 2023 23:22:44 +0000 (UTC)
Received: from localhost.localdomain (localhost [IPv6:::1])
	by oystercatcher.gentoo.org (Postfix) with ESMTP id 4300D8DE
	for <gentoo-commits@lists.gentoo.org>; Sat, 18 Mar 2023 23:22:43 +0000 (UTC)
From: "Ionen Wolkens" <ionen@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Content-Transfer-Encoding: 8bit
Content-type: text/plain; charset=UTF-8
Reply-To: gentoo-dev@lists.gentoo.org, "Ionen Wolkens" <ionen@gentoo.org>
Message-ID: <1679181732.3d8762f07bd8ae6779b5011f34b0f497c4947c58.ionen@gentoo>
Subject: [gentoo-commits] repo/gentoo:master commit in: www-client/qutebrowser/
X-VCS-Repository: repo/gentoo
X-VCS-Files: www-client/qutebrowser/qutebrowser-3.0.0_pre9999.ebuild
X-VCS-Directories: www-client/qutebrowser/
X-VCS-Committer: ionen
X-VCS-Committer-Name: Ionen Wolkens
X-VCS-Revision: 3d8762f07bd8ae6779b5011f34b0f497c4947c58
X-VCS-Branch: master
Date: Sat, 18 Mar 2023 23:22:43 +0000 (UTC)
Precedence: bulk
List-Post: <mailto:gentoo-commits@lists.gentoo.org>
List-Help: <mailto:gentoo-commits+help@lists.gentoo.org>
List-Unsubscribe: <mailto:gentoo-commits+unsubscribe@lists.gentoo.org>
List-Subscribe: <mailto:gentoo-commits+subscribe@lists.gentoo.org>
List-Id: Gentoo Linux mail <gentoo-commits.gentoo.org>
X-BeenThere: gentoo-commits@lists.gentoo.org
X-Auto-Response-Suppress: DR, RN, NRN, OOF, AutoReply
X-Archives-Salt: d8af75a9-d1be-456f-b3ac-d7a7ea7646ac
X-Archives-Hash: af732c4b8fc6d0823680b637ae5e663f

commit:     3d8762f07bd8ae6779b5011f34b0f497c4947c58
Author:     Ionen Wolkens <ionen <AT> gentoo <DOT> org>
AuthorDate: Thu Mar 16 22:10:33 2023 +0000
Commit:     Ionen Wolkens <ionen <AT> gentoo <DOT> org>
CommitDate: Sat Mar 18 23:22:12 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=3d8762f0

www-client/qutebrowser: drop 3.0.0_pre9999

The qt6-v2 branch was merged in the main branch making this
obsolete. Use normal 9999 if want USE=qt6 (or at least until
3.0.0 is released).

Signed-off-by: Ionen Wolkens <ionen <AT> gentoo.org>

 .../qutebrowser/qutebrowser-3.0.0_pre9999.ebuild   | 187 ---------------------
 1 file changed, 187 deletions(-)

diff --git a/www-client/qutebrowser/qutebrowser-3.0.0_pre9999.ebuild b/www-client/qutebrowser/qutebrowser-3.0.0_pre9999.ebuild
deleted file mode 100644
index 0de37e2649d8..000000000000
--- a/www-client/qutebrowser/qutebrowser-3.0.0_pre9999.ebuild
+++ /dev/null
@@ -1,187 +0,0 @@
-# Copyright 1999-2023 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-DISTUTILS_SINGLE_IMPL=1
-DISTUTILS_USE_PEP517=setuptools
-PYTHON_COMPAT=( python3_{9..11} )
-inherit distutils-r1 xdg
-
-if [[ ${PV} == *9999 ]]; then
-	inherit git-r3
-	EGIT_REPO_URI="https://github.com/qutebrowser/qutebrowser.git"
-	EGIT_BRANCH="qt6-v2"
-else
-	SRC_URI="https://github.com/qutebrowser/qutebrowser/releases/download/v${PV}/${P}.tar.gz"
-	KEYWORDS="~amd64 ~arm64 ~x86"
-fi
-
-DESCRIPTION="Keyboard-driven, vim-like browser based on Python and Qt"
-HOMEPAGE="https://www.qutebrowser.org/"
-
-LICENSE="GPL-3+"
-SLOT="0"
-IUSE="+adblock pdf +qt6 widevine"
-
-RDEPEND="
-	$(python_gen_cond_dep '
-		dev-python/colorama[${PYTHON_USEDEP}]
-		>=dev-python/jinja-3.1.2[${PYTHON_USEDEP}]
-		>=dev-python/markupsafe-2.1.1[${PYTHON_USEDEP}]
-		dev-python/pygments[${PYTHON_USEDEP}]
-		dev-python/pyyaml[${PYTHON_USEDEP}]
-		dev-python/zipp[${PYTHON_USEDEP}]
-		adblock? ( dev-python/adblock[${PYTHON_USEDEP}] )
-	')
-	qt6? (
-		dev-qt/qtbase:6[icu]
-		$(python_gen_cond_dep '
-			dev-python/PyQt6[${PYTHON_USEDEP},dbus,gui,network,opengl,printsupport,qml,sql,widgets]
-			dev-python/PyQt6-WebEngine[${PYTHON_USEDEP},widgets]
-		')
-		pdf? ( www-plugins/pdfjs )
-	)
-	!qt6? (
-		dev-qt/qtcore:5[icu]
-		dev-qt/qtgui:5[png]
-		$(python_gen_cond_dep '
-			dev-python/PyQt5[${PYTHON_USEDEP},dbus,declarative,gui,network,opengl,printsupport,sql,widgets]
-			dev-python/PyQtWebEngine[${PYTHON_USEDEP}]
-		')
-		pdf? ( <www-plugins/pdfjs-3 )
-	)
-	widevine? ( www-plugins/chrome-binary-plugins )"
-BDEPEND="
-	$(python_gen_cond_dep '
-		test? (
-			dev-python/beautifulsoup4[${PYTHON_USEDEP}]
-			dev-python/cheroot[${PYTHON_USEDEP}]
-			dev-python/flask[${PYTHON_USEDEP}]
-			dev-python/hypothesis[${PYTHON_USEDEP}]
-			dev-python/pytest-bdd[${PYTHON_USEDEP}]
-			dev-python/pytest-mock[${PYTHON_USEDEP}]
-			dev-python/pytest-qt[${PYTHON_USEDEP}]
-			dev-python/pytest-rerunfailures[${PYTHON_USEDEP}]
-			dev-python/pytest-xvfb[${PYTHON_USEDEP}]
-			dev-python/tldextract[${PYTHON_USEDEP}]
-			qt6? ( dev-python/PyQt6[testlib] )
-			!qt6? ( dev-python/PyQt5[testlib] )
-		)
-	')"
-[[ ${PV} == *9999 ]] && BDEPEND+=" app-text/asciidoc"
-
-distutils_enable_tests pytest
-
-src_prepare() {
-	distutils-r1_src_prepare
-
-	if use pdf; then
-		sed -e '/^content.pdfjs:/,+1s/false/true/' \
-			-i ${PN}/config/configdata.yml || die
-	fi
-
-	if use widevine && use prefix; then
-		# hack: QtWebEngine knows Gentoo's widevine, but not with ${EPREFIX}
-		local widevine=${EPREFIX}/usr/$(get_libdir)/chromium-browser/WidevineCdm/_platform_specific/linux_x64/libwidevinecdm.so
-		sed -e "/yield from _qtwebengine_settings_args/a\    yield '--widevine-path=${widevine}'" \
-			-i ${PN}/config/qtargs.py || die
-	fi
-
-	# ensure run the requested Qt backend
-	sed -e '/^_WRAPPERS = /,/^]/c\_WRAPPERS = [ "PyQt'$(usex qt6 6 5)'" ]' \
-		-i ${PN}/qt/machinery.py || die
-
-	# let eclass handle python
-	sed -i '/setup.py/d' misc/Makefile || die
-
-	if [[ ${PV} == *9999 ]]; then
-		# call asciidoc(1) rather than the single target python module
-		sed -e '/cmdline = /s/= .*/= ["asciidoc"]/' \
-			-i scripts/asciidoc2html.py || die
-
-		"${EPYTHON}" scripts/asciidoc2html.py || die
-	fi
-
-	# disable unnecessary tests/plugins that need extras
-	sed -e '/pytest-benchmark/d' -e 's/--benchmark[^ ]*//' \
-		-e '/pytest-instafail/d' -e 's/--instafail//' \
-		-i pytest.ini || die
-	if [[ ${PV} == *9999 ]]; then
-		rm tests/unit/scripts/test_run_vulture.py || die
-	else
-		rm tests/unit/scripts/test_problemmatchers.py || die
-	fi
-}
-
-python_test() {
-	local -x PYTEST_QT_API=pyqt$(usex qt6 6 5)
-
-	local EPYTEST_DESELECT=(
-		# end2end and other IPC tests are broken with "Name error" if
-		# socket path is over ~104 characters (=124 in /var/tmp/portage)
-		# https://github.com/qutebrowser/qutebrowser/issues/888 (not just OSX)
-		tests/end2end
-		tests/unit/misc/test_ipc.py
-		# calls eclass' python2 "failure" wrapper
-		tests/unit/misc/test_checkpyver.py::test_old_python
-		# not worth running dbus over
-		tests/unit/browser/test_notification.py::TestDBus
-		# bug 819393
-		tests/unit/commands/test_userscripts.py::test_custom_env[_POSIXUserscriptRunner]
-		# tests that don't know about our newer qtwebengine:5
-		tests/unit/browser/webengine/test_webenginedownloads.py::TestDataUrlWorkaround
-	)
-	# qtargs are mangled with widevine+prefix
-	use widevine && use prefix && EPYTEST_DESELECT+=( tests/unit/config/test_qtargs.py )
-
-	# skip benchmarks (incl. _tree), and warning tests broken by -Wdefault
-	epytest -p xvfb -n ${jobs} -k 'not _bench and not _matches_tree and not _warning'
-}
-
-python_install_all() {
-	emake -f misc/Makefile DESTDIR="${D}" PREFIX="${EPREFIX}"/usr install
-
-	rm "${ED}"/usr/share/${PN}/scripts/{mkvenv,utils}.py || die
-	fperms -x /usr/share/${PN}/{scripts/cycle-inputs.js,userscripts/README.md}
-	python_fix_shebang "${ED}"/usr/share/${PN}
-
-	einstalldocs
-}
-
-pkg_preinst() {
-	xdg_pkg_preinst
-
-	has_version "${CATEGORY}/${PN}[qt6]" && QUTEBROWSER_HAD_QT6=
-}
-
-pkg_postinst() {
-	xdg_pkg_postinst
-
-	if [[ ! ${REPLACING_VERSIONS} ]]; then
-		elog "Note that optional scripts in ${EROOT}/usr/share/${PN}/{user,}scripts"
-		elog "have additional dependencies not covered by this ebuild, for example"
-		elog "view_in_mpv needs media-video/mpv[lua] and net-misc/yt-dlp."
-	fi
-
-	if [[ ! -v QUTEBROWSER_HAD_QT6 ]] && use qt6; then
-		elog "USE=qt6 is enabled using the qt6-v2 branch, it is work-in-progress"
-		elog "and some issues may be expected. Can follow upstream progress at:"
-		elog "  https://github.com/qutebrowser/qutebrowser/issues/7202 [qt6 general]"
-		elog "  https://github.com/qutebrowser/qutebrowser/tree/qt6-v2 [used branch]"
-		if [[ ${REPLACING_VERSIONS} ]]; then
-			elog
-			elog "You may optionally want to backup your ~/.local/share/${PN} before"
-			elog "it is converted to use Qt6 WebEngine (one-way conversion). ${PN}"
-			elog "will also warn about this on launch for a last chance to abort."
-		fi
-	fi
-
-	# only show qt6 warning on arches where USE=qt6 is unmasked
-	if use amd64 && use !qt6; then
-		ewarn "USE=qt6 is disabled, be warned that Qt5's WebEngine uses an older"
-		ewarn "chromium version. While it is relatively maintained for security, it may"
-		ewarn "cause issues for sites/features designed with a newer version in mind."
-		ewarn "When Qt6 support is stable enough, ebuild's Qt5 support may get removed."
-	fi
-}