From mboxrd@z Thu Jan 1 00:00:00 1970
Return-Path: <gentoo-commits+bounces-1498069-garchives=archives.gentoo.org@lists.gentoo.org>
Received: from lists.gentoo.org (pigeon.gentoo.org [208.92.234.80])
(using TLSv1.3 with cipher TLS_AES_256_GCM_SHA384 (256/256 bits)
key-exchange X25519 server-signature RSA-PSS (2048 bits))
(No client certificate requested)
by finch.gentoo.org (Postfix) with ESMTPS id 4AD1C15A7DA
for <garchives@archives.gentoo.org>; Fri, 17 Mar 2023 21:54:10 +0000 (UTC)
Received: from pigeon.gentoo.org (localhost [127.0.0.1])
by pigeon.gentoo.org (Postfix) with SMTP id 4A1E8E0CCC;
Fri, 17 Mar 2023 21:54:09 +0000 (UTC)
Received: from smtp.gentoo.org (dev.gentoo.org [IPv6:2001:470:ea4a:1:5054:ff:fec7:86e4])
(using TLSv1.3 with cipher TLS_AES_256_GCM_SHA384 (256/256 bits)
key-exchange X25519 server-signature RSA-PSS (4096 bits))
(No client certificate requested)
by pigeon.gentoo.org (Postfix) with ESMTPS id 1C7A4E0CCA
for <gentoo-commits@lists.gentoo.org>; Fri, 17 Mar 2023 21:54:09 +0000 (UTC)
Received: from oystercatcher.gentoo.org (oystercatcher.gentoo.org [148.251.78.52])
(using TLSv1.3 with cipher TLS_AES_256_GCM_SHA384 (256/256 bits)
key-exchange X25519 server-signature RSA-PSS (4096 bits))
(No client certificate requested)
by smtp.gentoo.org (Postfix) with ESMTPS id 08D0C341326
for <gentoo-commits@lists.gentoo.org>; Fri, 17 Mar 2023 21:54:08 +0000 (UTC)
Received: from localhost.localdomain (localhost [IPv6:::1])
by oystercatcher.gentoo.org (Postfix) with ESMTP id B56308D7
for <gentoo-commits@lists.gentoo.org>; Fri, 17 Mar 2023 21:54:05 +0000 (UTC)
From: "Sam James" <sam@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Content-Transfer-Encoding: 8bit
Content-type: text/plain; charset=UTF-8
Reply-To: gentoo-dev@lists.gentoo.org, "Sam James" <sam@gentoo.org>
Message-ID: <1679089924.4bffb8b541223d4ebaf3a659a42675d57d8419e4.sam@gentoo>
Subject: [gentoo-commits] repo/gentoo:master commit in: app-crypt/gpgme/
X-VCS-Repository: repo/gentoo
X-VCS-Files: app-crypt/gpgme/Manifest app-crypt/gpgme/gpgme-1.19.0.ebuild
X-VCS-Directories: app-crypt/gpgme/
X-VCS-Committer: sam
X-VCS-Committer-Name: Sam James
X-VCS-Revision: 4bffb8b541223d4ebaf3a659a42675d57d8419e4
X-VCS-Branch: master
Date: Fri, 17 Mar 2023 21:54:05 +0000 (UTC)
Precedence: bulk
List-Post: <mailto:gentoo-commits@lists.gentoo.org>
List-Help: <mailto:gentoo-commits+help@lists.gentoo.org>
List-Unsubscribe: <mailto:gentoo-commits+unsubscribe@lists.gentoo.org>
List-Subscribe: <mailto:gentoo-commits+subscribe@lists.gentoo.org>
List-Id: Gentoo Linux mail <gentoo-commits.gentoo.org>
X-BeenThere: gentoo-commits@lists.gentoo.org
X-Auto-Response-Suppress: DR, RN, NRN, OOF, AutoReply
X-Archives-Salt: dba4fd46-ca72-45d7-8684-b02cf1af4780
X-Archives-Hash: 5c32ec93364010025d278cb91c13dfc3
commit: 4bffb8b541223d4ebaf3a659a42675d57d8419e4
Author: Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Fri Mar 17 20:56:33 2023 +0000
Commit: Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Fri Mar 17 21:52:04 2023 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=4bffb8b5
app-crypt/gpgme: add 1.19.0
Signed-off-by: Sam James <sam <AT> gentoo.org>
app-crypt/gpgme/Manifest | 2 +
app-crypt/gpgme/gpgme-1.19.0.ebuild | 162 ++++++++++++++++++++++++++++++++++++
2 files changed, 164 insertions(+)
diff --git a/app-crypt/gpgme/Manifest b/app-crypt/gpgme/Manifest
index fb1c045a3555..50144ff866d9 100644
--- a/app-crypt/gpgme/Manifest
+++ b/app-crypt/gpgme/Manifest
@@ -2,3 +2,5 @@ DIST gpgme-1.17.1.tar.bz2 1747692 BLAKE2B 44cf9309cbad038f23aa7c5c77fd85be23faf3
DIST gpgme-1.17.1.tar.bz2.sig 119 BLAKE2B 31832424c0e029dc520d3302a71b086d9fcb044c74344cc0fb4b6c6a02d0dd840e62e7eb60acfaf004e6f3650d58436b58e645ef2a50b948ecaf3ca162bf577a SHA512 e1a4213d0d39f2efd0d5c007a0449c76bd650e76e002a9acb673eef0579912db06d844df11a4f7cb821e1d8468d2d6c1303f1c5d915a5c3c9cb5abacfbd004fc
DIST gpgme-1.18.0.tar.bz2 1762323 BLAKE2B a071b839eb75455378514f003920cd387320e9fae416e71151cf6ac1b4a058b58ed054450b79e3eeaf820ff5324ea14efa003612867477b7379a776942d62be6 SHA512 c0cb0b337d017793a15dd477a7f5eaef24587fcda3d67676bf746bb342398d04792c51abe3c26ae496e799c769ce667d4196d91d86e8a690d02c6718c8f6b4ac
DIST gpgme-1.18.0.tar.bz2.sig 119 BLAKE2B 968f8b24ec71b4157214dd026aed83c96894ef353a9cb171f268d640a62fe464ba43540f318abf95dcfc19dffab177a0c3ad8a6e9937dc80e4ececbc8ceb3203 SHA512 02958d86cc037fffc787c6611ace8676d4e04cc1f65fd117eb911d3bfd665dddb7849bcd838af598465be78960f54883eac09c29c42f891f2e4b9713095aed7d
+DIST gpgme-1.19.0.tar.bz2 1821913 BLAKE2B e0359d50cdeff14a20f0e4f463f78b1e1df62e6e3cd50c5f59d90754e7ffe1c74d0c155507bc9d16c61a45a47fdda7e82a86d7db8cbf3999615d854fc1bb5207 SHA512 c6f01ad9432abe33f407e81083dd2f299375ad13b0517429ea1c55fb8cffa05e470dd26f5910a78b8d0f4c8c1e620788a9f369d983c191a3dac681714054fe84
+DIST gpgme-1.19.0.tar.bz2.sig 119 BLAKE2B 699c2db9746c48b133ff71fbf621e3f8b9dc3e11517cb6abea48e7b0b11d6ece1f9e5aa72cfcd74b0cf24f4a51316e055baed0d93c3146e0c13865b0fdf3e9f3 SHA512 cc8bdd83063155e4aa893b4fe79208d4ff524fcaa4e21b6de0dd879501bdb21ebd7074e841625aa5b4c206273297232d3c005f44abd05214b5d9d711eb980c07
diff --git a/app-crypt/gpgme/gpgme-1.19.0.ebuild b/app-crypt/gpgme/gpgme-1.19.0.ebuild
new file mode 100644
index 000000000000..93eccd707136
--- /dev/null
+++ b/app-crypt/gpgme/gpgme-1.19.0.ebuild
@@ -0,0 +1,162 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+# Maintainers should:
+# 1. Join the "Gentoo" project at https://dev.gnupg.org/project/view/27/
+# 2. Subscribe to release tasks like https://dev.gnupg.org/T6159
+# (find the one for the current release then subscribe to it +
+# any subsequent ones linked within so you're covered for a while.)
+
+DISTUTILS_OPTIONAL=1
+PYTHON_COMPAT=( python3_{9..11} )
+VERIFY_SIG_OPENPGP_KEY_PATH="${BROOT}"/usr/share/openpgp-keys/gnupg.asc
+
+inherit distutils-r1 libtool flag-o-matic qmake-utils toolchain-funcs verify-sig
+
+DESCRIPTION="GnuPG Made Easy is a library for making GnuPG easier to use"
+HOMEPAGE="https://www.gnupg.org/related_software/gpgme"
+SRC_URI="
+ mirror://gnupg/gpgme/${P}.tar.bz2
+ verify-sig? ( mirror://gnupg/gpgme/${P}.tar.bz2.sig )
+"
+
+LICENSE="GPL-2 LGPL-2.1"
+# Please check ABI on each bump, even if SONAMEs didn't change: bug #833355
+# Use e.g. app-portage/iwdevtools integration with dev-libs/libabigail's abidiff.
+# Subslot: SONAME of each: <libgpgme.libgpgmepp.libqgpgme.FUDGE>
+# Bump FUDGE if a release is made which breaks ABI without changing SONAME.
+# (Reset to 0 if FUDGE != 0 if libgpgme/libgpgmepp/libqpggme change.)
+SLOT="1/11.6.15.2"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-cygwin ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="common-lisp static-libs +cxx python qt5 test"
+RESTRICT="!test? ( test )"
+REQUIRED_USE="qt5? ( cxx ) python? ( ${PYTHON_REQUIRED_USE} )"
+
+# - On each bump, update dep bounds on each version from configure.ac!
+RDEPEND="
+ >=app-crypt/gnupg-2
+ >=dev-libs/libassuan-2.5.3:=
+ >=dev-libs/libgpg-error-1.36:=
+ >=dev-libs/libgpg-error-1.46-r1
+ python? ( ${PYTHON_DEPS} )
+ qt5? ( dev-qt/qtcore:5 )
+"
+DEPEND="
+ ${RDEPEND}
+ test? (
+ qt5? ( dev-qt/qttest:5 )
+ )
+"
+#doc? ( app-doc/doxygen[dot] )
+BDEPEND="
+ python? ( dev-lang/swig )
+ verify-sig? ( sec-keys/openpgp-keys-gnupg )
+"
+
+PATCHES=(
+ "${FILESDIR}"/${PN}-1.18.0-tests-start-stop-agent-use-command-v.patch
+)
+
+src_prepare() {
+ default
+
+ elibtoolize
+
+ # bug #697456
+ addpredict /run/user/$(id -u)/gnupg
+
+ local MAX_WORKDIR=66
+ if use test && [[ "${#WORKDIR}" -gt "${MAX_WORKDIR}" ]]; then
+ eerror "Unable to run tests as WORKDIR='${WORKDIR}' is longer than ${MAX_WORKDIR} which causes failure!"
+ die "Could not run tests as requested with too-long WORKDIR."
+ fi
+
+ # Make best effort to allow longer PORTAGE_TMPDIR
+ # as usock limitation fails build/tests
+ ln -s "${P}" "${WORKDIR}/b" || die
+ S="${WORKDIR}/b"
+}
+
+src_configure() {
+ local languages=()
+
+ # bug #847955
+ append-lfs-flags
+
+ if use common-lisp ; then
+ languages+=( "cl" )
+ fi
+
+ if use cxx ; then
+ languages+=( "cpp" )
+ fi
+
+ # TODO: qt6? but qt5 and qt5 are mutually exclusive :(
+ if use qt5; then
+ languages+=( "qt5" )
+
+ #use doc ||
+ export DOXYGEN=true
+ export MOC="$(qt5_get_bindir)/moc"
+ fi
+
+ local myeconfargs=(
+ $(use test || echo "--disable-gpgconf-test --disable-gpg-test --disable-gpgsm-test --disable-g13-test")
+ --enable-languages="${languages[*]}"
+ $(use_enable static-libs static)
+ )
+
+ econf "${myeconfargs[@]}"
+
+ if use python ; then
+ emake -C lang/python prepare
+
+ pushd lang/python > /dev/null || die
+ top_builddir="../.." srcdir="." CPP="$(tc-getCPP)" distutils-r1_src_configure
+ popd > /dev/null || die
+ fi
+}
+
+src_compile() {
+ default
+
+ if use python ; then
+ pushd lang/python > /dev/null || die
+ top_builddir="../.." srcdir="." CPP="$(tc-getCPP)" distutils-r1_src_compile
+ popd > /dev/null || die
+ fi
+}
+
+src_test() {
+ default
+
+ if use python ; then
+ distutils-r1_src_test
+ fi
+}
+
+python_test() {
+ emake -C lang/python/tests check \
+ PYTHON=${EPYTHON} \
+ PYTHONS=${EPYTHON} \
+ TESTFLAGS="--python-libdir=${BUILD_DIR}/lib"
+}
+
+src_install() {
+ default
+
+ if use python ; then
+ pushd lang/python > /dev/null || die
+ top_builddir="../.." srcdir="." CPP="$(tc-getCPP)" distutils-r1_src_install
+ popd > /dev/null || die
+ fi
+
+ find "${ED}" -type f -name '*.la' -delete || die
+
+ # Backward compatibility for gentoo
+ # (in the past, we had slots)
+ dodir /usr/include/gpgme
+ dosym ../gpgme.h /usr/include/gpgme/gpgme.h
+}