[gentoo-commits] repo/gentoo:master commit in: media-radio/tlf/

["Thomas Beierlein" <tomjbe@gentoo.org>]

commit:     a87879f8046d39c966b04d3a1fa6054d4a1ce216
Author:     Thomas Beierlein <tomjbe <AT> gentoo <DOT> org>
AuthorDate: Tue Mar  7 18:06:48 2023 +0000
Commit:     Thomas Beierlein <tomjbe <AT> gentoo <DOT> org>
CommitDate: Tue Mar  7 18:13:33 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=a87879f8

media-radio/tlf: Skip check for implicit function declaration in config logs

ax_with_curses.m4 ifrom autoconf-archive checks potential available
ncursesw header file locations. If header file is not found the check
results in an implicit function declaration.

Closes: https://bugs.gentoo.org/898488
Signed-off-by: Thomas Beierlein <tomjbe <AT> gentoo.org>

 media-radio/tlf/tlf-1.4.1-r2.ebuild | 56 +++++++++++++++++++++++++++++++++++++
 1 file changed, 56 insertions(+)

diff --git a/media-radio/tlf/tlf-1.4.1-r2.ebuild b/media-radio/tlf/tlf-1.4.1-r2.ebuild
new file mode 100644
index 000000000000..9e10989920d6
--- /dev/null
+++ b/media-radio/tlf/tlf-1.4.1-r2.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="7"
+
+inherit autotools flag-o-matic
+
+DESCRIPTION="Console-mode amateur radio contest logger"
+HOMEPAGE="http://home.iae.nl/users/reinc/TLF-0.2.html"
+SRC_URI="mirror://nongnu/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="test"
+
+RESTRICT="!test? ( test )"
+
+RDEPEND="sys-libs/ncurses:=
+	dev-libs/glib:2
+	media-libs/hamlib:=
+	media-sound/sox
+	dev-libs/xmlrpc-c[curl]
+	elibc_musl? ( sys-libs/argp-standalone )"
+DEPEND="
+	${RDEPEND}
+	test? ( dev-util/cmocka )"
+
+PATCHES=( "${FILESDIR}/${P}-zone_nr.patch"
+	  "${FILESDIR}/${P}-musl.patch"
+	  "${FILESDIR}/${P}-missing-include.patch"
+	)
+
+# suppress warning wrt 'implicit function declaration' in config logs
+# bug #899842
+QA_CONFIG_IMPL_DECL_SKIP=(
+	wget_wch	# designed to check availability of various ncursesw
+				# header files
+	)
+
+src_prepare() {
+	if has_version '>=media-libs/hamlib-4.2' ; then
+		sed -i -e "s/FILPATHLEN/HAMLIB_FILPATHLEN/g" "${S}"/src/sendqrg.c || die
+	fi
+
+	eapply ${PATCHES[@]}
+	eapply_user
+	eautoreconf
+}
+
+src_configure() {
+	use elibc_musl && append-libs argp
+	append-ldflags -L/usr/$(get_libdir)/hamlib
+	filter-lto		# bug # 876418
+	econf --enable-fldigi-xmlrpc
+}