[gentoo-commits] repo/proj/guru:master commit in: app-text/komikku/

["Florian Schmaus" <flow@gentoo.org>]

commit:     6f8cd89657e3206044bc93e35b1c860c8adb7d48
Author:     Anna (cybertailor) Vyalkova <cyber+gentoo <AT> sysrq <DOT> in>
AuthorDate: Tue Mar  7 14:58:04 2023 +0000
Commit:     Florian Schmaus <flow <AT> gentoo <DOT> org>
CommitDate: Tue Mar  7 15:33:01 2023 +0000
URL:        https://gitweb.gentoo.org/repo/proj/guru.git/commit/?id=6f8cd896

app-text/komikku: add 1.13.0

Signed-off-by: Anna (cybertailor) Vyalkova <cyber+gentoo <AT> sysrq.in>

 app-text/komikku/Manifest              |  1 +
 app-text/komikku/komikku-1.13.0.ebuild | 92 ++++++++++++++++++++++++++++++++++
 2 files changed, 93 insertions(+)

diff --git a/app-text/komikku/Manifest b/app-text/komikku/Manifest
index 43e5c8359..f0edfe154 100644
--- a/app-text/komikku/Manifest
+++ b/app-text/komikku/Manifest
@@ -1 +1,2 @@
 DIST Komikku-v1.12.1.tar.bz2 5048587 BLAKE2B 4055edebe237a665da9ed231b44c4a906246c154d6dc4608116baf4107663d8032a3b0faa2a6c0dca00b5df27af975a4f7e6f4b96976dd9d472d7775a7222cff SHA512 d9c83ca821f5e5d377288ff7d7cb09c1a56a06fb80c2a9a96ca0d7a998acf12dfbec884ea96e142cf860d7a598716e482b7f4d1d5805292cc986e00155118a60
+DIST Komikku-v1.13.0.tar.bz2 5052567 BLAKE2B e8d23e6de55f0df1762fb248fa4f881e855feb63de068cf2ed3c9c71dfdbb31051f8cb36910328f2ac5e76af54dbcffcb0b49c3810e13adc04fc1f701bf0ca64 SHA512 2e1eecca064a222430c6e5023a12da92c1c299a2e221e84a0b570bf3e2824b0c7309cfd6726e334812092d612de5fd47729305567ba4aa9458998cfe36e32562

diff --git a/app-text/komikku/komikku-1.13.0.ebuild b/app-text/komikku/komikku-1.13.0.ebuild
new file mode 100644
index 000000000..6057f03bd
--- /dev/null
+++ b/app-text/komikku/komikku-1.13.0.ebuild
@@ -0,0 +1,92 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{9..11} )
+PYTHON_REQ_USE="sqlite(+),ssl(+)"
+DISTUTILS_USE_PEP517=no
+DISTUTILS_SINGLE_IMPL=1
+inherit distutils-r1 meson gnome2-utils virtualx xdg
+
+MY_PN="${PN^}"
+MY_P="${MY_PN}-v${PV}"
+DESCRIPTION="An online/offline manga reader for GNOME"
+HOMEPAGE="https://gitlab.com/valos/Komikku"
+SRC_URI="https://gitlab.com/valos/${MY_PN}/-/archive/v${PV}/${MY_P}.tar.bz2"
+S="${WORKDIR}/${MY_P}"
+
+KEYWORDS="~amd64"
+LICENSE="GPL-3+"
+SLOT="0"
+IUSE="test"
+
+RESTRICT="test"
+PROPERTIES="test_network"
+
+DEPEND="
+	dev-libs/glib:2
+	dev-libs/gobject-introspection
+	>=gui-libs/gtk-4.8.2:4
+	>=gui-libs/libadwaita-1.2.0[introspection]
+	net-libs/webkit-gtk:5[introspection]
+"
+RDEPEND="
+	${DEPEND}
+	$(python_gen_cond_dep '
+		app-arch/brotli[python,${PYTHON_USEDEP}]
+		dev-python/aiohttp[${PYTHON_USEDEP}]
+		dev-python/beautifulsoup4[${PYTHON_USEDEP}]
+		dev-python/cffi[${PYTHON_USEDEP}]
+		dev-python/cloudscraper[${PYTHON_USEDEP}]
+		dev-python/cryptography[${PYTHON_USEDEP}]
+		dev-python/dateparser[${PYTHON_USEDEP}]
+		dev-python/emoji[${PYTHON_USEDEP}]
+		dev-python/keyring[${PYTHON_USEDEP}]
+		dev-python/lxml[${PYTHON_USEDEP}]
+		dev-python/natsort[${PYTHON_USEDEP}]
+		dev-python/pillow[${PYTHON_USEDEP}]
+		dev-python/pure-protobuf[${PYTHON_USEDEP}]
+		dev-python/pygobject[${PYTHON_USEDEP}]
+		dev-python/python-magic[${PYTHON_USEDEP}]
+		dev-python/rarfile[compressed,${PYTHON_USEDEP}]
+		dev-python/requests[${PYTHON_USEDEP}]
+		dev-python/unidecode[${PYTHON_USEDEP}]
+	')
+"
+BDEPEND="
+	sys-devel/gettext
+	test? (
+		$(python_gen_cond_dep '
+			dev-python/pytest-steps[${PYTHON_USEDEP}]
+		')
+	)
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	default
+
+	# fix broken shebang
+	sed "s|py_installation.full_path()|'${PYTHON}'|" -i bin/meson.build || die
+}
+
+src_test() {
+	virtx epytest
+}
+
+src_install() {
+	meson_src_install
+	python_optimize
+}
+
+pkg_postinst() {
+	gnome2_schemas_update
+	xdg_pkg_postinst
+}
+
+pkg_postrm() {
+	gnome2_schemas_update
+	xdg_pkg_postrm
+}