[gentoo-commits] repo/gentoo:master commit in: sci-libs/coinor-utils/

[gentoo-commits] repo/gentoo:master commit in: sci-libs/coinor-utils/

[David Seifert]

commit:     b02869496f18098d468416b3ab5d6b645f37516e
Author:     David Seifert <soap <AT> gentoo <DOT> org>
AuthorDate: Mon Mar  7 08:15:27 2016 +0000
Commit:     David Seifert <soap <AT> gentoo <DOT> org>
CommitDate: Mon Mar  7 08:15:27 2016 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=b0286949

sci-libs/coinor-utils: Add missing subslot dependency

Package-Manager: portage-2.2.27

 sci-libs/coinor-utils/coinor-utils-2.9.11.ebuild | 4 ++--
 1 file changed, 2 insertions(+), 2 deletions(-)

diff --git a/sci-libs/coinor-utils/coinor-utils-2.9.11.ebuild b/sci-libs/coinor-utils/coinor-utils-2.9.11.ebuild
index bd65cc4..ca9275c 100644
--- a/sci-libs/coinor-utils/coinor-utils-2.9.11.ebuild
+++ b/sci-libs/coinor-utils/coinor-utils-2.9.11.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2014 Gentoo Foundation
+# Copyright 1999-2016 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
 # $Id$
 
@@ -18,7 +18,7 @@ KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
 IUSE="bzip2 doc glpk blas lapack static-libs test zlib"
 
 RDEPEND="
-	sys-libs/readline
+	sys-libs/readline:0=
 	bzip2? ( app-arch/bzip2 )
 	blas? ( virtual/blas )
 	glpk? ( sci-mathematics/glpk:= )

[gentoo-commits] repo/gentoo:master commit in: sci-libs/coinor-utils/

[Michael Orlitzky]

commit:     676f9dfeca33ccff9dffc0331ea0ac8a34bb02f4
Author:     Michael Orlitzky <mjo <AT> gentoo <DOT> org>
AuthorDate: Wed May  6 22:09:13 2020 +0000
Commit:     Michael Orlitzky <mjo <AT> gentoo <DOT> org>
CommitDate: Fri May  8 12:20:32 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=676f9dfe

sci-libs/coinor-utils: new EAPI=7 version 2.11.4.

Mostly a straightforward version bump. The package has a new homepage,
and now econf/emake are used in place of their autotools-utils
counterparts. I added some comments about the weirdness you'll find in
the coinor-* packages.

Closes: https://bugs.gentoo.org/601648
Package-Manager: Portage-2.3.89, Repoman-2.3.20
Signed-off-by: Michael Orlitzky <mjo <AT> gentoo.org>

 sci-libs/coinor-utils/Manifest                   |   2 +-
 sci-libs/coinor-utils/coinor-utils-2.11.4.ebuild | 101 +++++++++++++++++++++++
 sci-libs/coinor-utils/coinor-utils-2.9.11.ebuild |  84 -------------------
 3 files changed, 102 insertions(+), 85 deletions(-)

diff --git a/sci-libs/coinor-utils/Manifest b/sci-libs/coinor-utils/Manifest
index 7b1465862ee..1f3f6c21314 100644
--- a/sci-libs/coinor-utils/Manifest
+++ b/sci-libs/coinor-utils/Manifest
@@ -1 +1 @@
-DIST CoinUtils-2.9.11.tgz 1740411 BLAKE2B 7adce4e17d31f8187c7959140f7cb5c537d6454b2e82c9cede7625bcff2b490e50dea190838f598b5fcc55a42ec2beea3982b14dc7bc8432e86ab82475462bc1 SHA512 3cbbce47cda4d5f63338644853601bf0a3dd9b9388e71a7aea7fedd51dfc007134359e5f12f24d8f6135d86b77a88a95bcb88249b1ba880eb3cd9cf41d039424
+DIST coinor-utils-2.11.4.tar.gz 1225148 BLAKE2B d55f9b3efbb3ce1c04fb9193ec70f62d8f130cd2f7ddf033c0df35f37006c542bd39e345662c271b4466b00c4bb1ec3cc14965bfe35f5b89370071d675113f4d SHA512 a7ac337b0f0bb11d578c44fd12d292ba8e77568362eaaaecbed8f4bc22ed85aaee911e2dd3153a2197b0165df082821969336d73fe1c5f0374a4636755d9a4ad

diff --git a/sci-libs/coinor-utils/coinor-utils-2.11.4.ebuild b/sci-libs/coinor-utils/coinor-utils-2.11.4.ebuild
new file mode 100644
index 00000000000..d969f9d022e
--- /dev/null
+++ b/sci-libs/coinor-utils/coinor-utils-2.11.4.ebuild
@@ -0,0 +1,101 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit toolchain-funcs
+
+MY_PN=CoinUtils
+
+DESCRIPTION="COIN-OR Matrix, Vector and other utility classes"
+HOMEPAGE="https://github.com/coin-or/CoinUtils/"
+SRC_URI="https://github.com/coin-or/${MY_PN}/archive/releases/${PV}.tar.gz
+	-> ${P}.tar.gz"
+LICENSE="EPL-1.0"
+
+# major soname component
+SLOT="0/3"
+
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="bzip2 doc glpk blas lapack static-libs test zlib"
+RESTRICT="!test? ( test )"
+
+# Fortran is NOT needed, but the ./configure scripts for all of the CoinOR
+# packages contain a check for it. Gentoo bug 601648 and upstream issue,
+#
+#   https://github.com/coin-or/CoinUtils/issues/132
+#
+BDEPEND="virtual/fortran
+	virtual/pkgconfig
+	doc? ( app-doc/doxygen[dot] )
+	test? ( sci-libs/coinor-sample )"
+DEPEND="sys-libs/readline:0=
+	blas? ( virtual/blas )
+	bzip2? ( app-arch/bzip2 )
+	glpk? ( sci-mathematics/glpk:= )
+	lapack? ( virtual/lapack )
+	zlib? ( sys-libs/zlib )"
+RDEPEND="${DEPEND}"
+
+S="${WORKDIR}/${MY_PN}-releases-${PV}/${MY_PN}"
+
+src_prepare() {
+	# Needed to make the --with-coin-instdir in src_configure happy.
+	dodir /usr
+
+	# They don't need to guess at this, but they do, and get it wrong...
+	sed -e "s:lib/pkgconfig:$(get_libdir)/pkgconfig:g" \
+		-i configure \
+		|| die "failed to fix the pkgconfig path in ${S}/configure"
+
+	default
+}
+
+src_configure() {
+	local myeconfargs=(
+		--enable-dependency-linking
+		--with-coin-instdir="${ED}/usr"
+		$(use_enable zlib)
+		$(use_enable bzip2 bzlib)
+		$(use_with doc dot)
+	)
+	if use blas; then
+		myeconfargs+=( --with-blas-lib="$($(tc-getPKG_CONFIG) --libs blas)" )
+	else
+		myeconfargs+=( --without-blas )
+	fi
+	if use glpk; then
+		myeconfargs+=(
+			--with-glpk-incdir="${EPREFIX}"/usr/include
+			--with-glpk-lib=-lglpk
+		)
+	else
+		myeconfargs+=( --without-glpk )
+	fi
+	if use lapack; then
+		myeconfargs+=( --with-lapack="$($(tc-getPKG_CONFIG) --libs lapack)" )
+	else
+		myeconfargs+=( --without-lapack )
+	fi
+
+	econf "${myeconfargs[@]}"
+}
+
+src_compile() {
+	emake all $(usex doc doxydoc "")
+}
+
+src_test() {
+	# NOT redundant! The build system has a "make check" target that does
+	# nothing, so if you don't specify "test" here, you'll get a no-op.
+	emake test
+}
+
+src_install() {
+	use doc && HTML_DOC=("${BUILD_DIR}/doxydocs/html/")
+
+	emake DESTDIR="${D}" install
+
+	# Duplicate junk, and in the wrong location.
+	rm -r "${ED}/usr/share/coin/doc/${MY_PN}" || die
+}

diff --git a/sci-libs/coinor-utils/coinor-utils-2.9.11.ebuild b/sci-libs/coinor-utils/coinor-utils-2.9.11.ebuild
deleted file mode 100644
index 29e79cb5bf8..00000000000
--- a/sci-libs/coinor-utils/coinor-utils-2.9.11.ebuild
+++ /dev/null
@@ -1,84 +0,0 @@
-# Copyright 1999-2019 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=5
-
-inherit autotools-utils multilib toolchain-funcs
-
-MYPN=CoinUtils
-
-DESCRIPTION="COIN-OR Matrix, Vector and other utility classes"
-HOMEPAGE="https://projects.coin-or.org/CoinUtils/"
-SRC_URI="http://www.coin-or.org/download/source/${MYPN}/${MYPN}-${PV}.tgz"
-
-LICENSE="EPL-1.0"
-SLOT="0/3"
-KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
-IUSE="bzip2 doc glpk blas lapack static-libs test zlib"
-RESTRICT="!test? ( test )"
-
-RDEPEND="
-	sys-libs/readline:0=
-	bzip2? ( app-arch/bzip2 )
-	blas? ( virtual/blas )
-	glpk? ( sci-mathematics/glpk:= )
-	lapack? ( virtual/lapack )
-	zlib? ( sys-libs/zlib )"
-DEPEND="${RDEPEND}
-	virtual/pkgconfig
-	doc? ( app-doc/doxygen[dot] )
-	test? ( sci-libs/coinor-sample )"
-
-S="${WORKDIR}/${MYPN}-${PV}/${MYPN}"
-
-src_prepare() {
-	dodir /usr
-	sed \
-		-e "s:lib/pkgconfig:$(get_libdir)/pkgconfig:g" \
-		-i configure || die
-	autotools-utils_src_prepare
-}
-
-src_configure() {
-	local myeconfargs=(
-		--enable-dependency-linking
-		--with-coin-instdir="${ED}"/usr
-		$(use_enable zlib)
-		$(use_enable bzip2 bzlib)
-		$(use_with doc dot)
-	)
-	if use blas; then
-		myeconfargs+=( --with-blas-lib="$($(tc-getPKG_CONFIG) --libs blas)" )
-	else
-		myeconfargs+=( --without-blas )
-	fi
-	if use glpk; then
-		myeconfargs+=(
-			--with-glpk-incdir="${EPREFIX}"/usr/include
-			--with-glpk-lib=-lglpk
-		)
-	else
-		myeconfargs+=( --without-glpk )
-	fi
-	if use lapack; then
-		myeconfargs+=( --with-lapack="$($(tc-getPKG_CONFIG) --libs lapack)" )
-	else
-		myeconfargs+=( --without-lapack )
-	fi
-	autotools-utils_src_configure
-}
-
-src_compile() {
-	autotools-utils_src_compile all $(usex doc doxydoc "")
-}
-
-psrc_test() {
-	autotools-utils_src_test test
-}
-
-src_install() {
-	use doc && HTML_DOC=("${BUILD_DIR}/doxydocs/html/")
-	autotools-utils_src_install
-	# already installed
-	rm "${ED}"/usr/share/coin/doc/${MYPN}/{README,AUTHORS,LICENSE} || die
-}

[gentoo-commits] repo/gentoo:master commit in: sci-libs/coinor-utils/

[Michael Orlitzky]

commit:     7014cc207d4d74e0bd4629ed669e8bdb7b0eb5b9
Author:     Michael Orlitzky <mjo <AT> gentoo <DOT> org>
AuthorDate: Wed May  6 21:33:49 2020 +0000
Commit:     Michael Orlitzky <mjo <AT> gentoo <DOT> org>
CommitDate: Fri May  8 12:20:32 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=7014cc20

sci-libs/coinor-utils: add "<upstream>" tag to metadata.xml.

Package-Manager: Portage-2.3.89, Repoman-2.3.20
Signed-off-by: Michael Orlitzky <mjo <AT> gentoo.org>

 sci-libs/coinor-utils/metadata.xml | 19 ++++++++++++-------
 1 file changed, 12 insertions(+), 7 deletions(-)

diff --git a/sci-libs/coinor-utils/metadata.xml b/sci-libs/coinor-utils/metadata.xml
index 871e40d0656..c4ba4a30fb7 100644
--- a/sci-libs/coinor-utils/metadata.xml
+++ b/sci-libs/coinor-utils/metadata.xml
@@ -6,13 +6,18 @@
     <name>Gentoo Science Project</name>
   </maintainer>
   <longdescription lang="en">
-  CoinUtils (Coin-or Utilities) is a collection of classes that are
-  generally useful to COmputational INfrastructure for Operations
-  Research (COIN-OR) projects. These include vector, matrix, mps file
-  reading classes.
-</longdescription>
+    CoinUtils (Coin-or Utilities) is a collection of classes that are
+    generally useful to COmputational INfrastructure for Operations
+    Research (COIN-OR) projects. These include vector, matrix, mps
+    file reading classes.
+  </longdescription>
   <use>
-    <flag name="glpk">Enable GNU Linear Programming Kit
-  <pkg>sci-mathematics/glpk</pkg> support</flag>
+    <flag name="glpk">
+      Enable GNU Linear Programming Kit
+      <pkg>sci-mathematics/glpk</pkg> support
+    </flag>
   </use>
+  <upstream>
+    <remote-id type="github">coin-or/CoinUtils</remote-id>
+  </upstream>
 </pkgmetadata>

[gentoo-commits] repo/gentoo:master commit in: sci-libs/coinor-utils/

[Yixun Lan]

commit:     c707159922e6b6cf64db1398a9581c4fee2944e3
Author:     Yixun Lan <dlan <AT> gentoo <DOT> org>
AuthorDate: Mon Mar  6 11:38:03 2023 +0000
Commit:     Yixun Lan <dlan <AT> gentoo <DOT> org>
CommitDate: Tue Mar  7 00:14:35 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=c7071599

sci-libs/coinor-utils: Keyword 2.11.4 riscv, #881389

Signed-off-by: Yixun Lan <dlan <AT> gentoo.org>

 sci-libs/coinor-utils/coinor-utils-2.11.4.ebuild | 4 ++--
 1 file changed, 2 insertions(+), 2 deletions(-)

diff --git a/sci-libs/coinor-utils/coinor-utils-2.11.4.ebuild b/sci-libs/coinor-utils/coinor-utils-2.11.4.ebuild
index 3053fcfbdc11..b5c346e982ed 100644
--- a/sci-libs/coinor-utils/coinor-utils-2.11.4.ebuild
+++ b/sci-libs/coinor-utils/coinor-utils-2.11.4.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2022 Gentoo Authors
+# Copyright 1999-2023 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=7
@@ -16,7 +16,7 @@ LICENSE="EPL-1.0"
 # major soname component
 SLOT="0/3"
 
-KEYWORDS="~amd64 ~loong ~x86 ~amd64-linux ~x86-linux"
+KEYWORDS="~amd64 ~loong ~riscv ~x86 ~amd64-linux ~x86-linux"
 IUSE="bzip2 doc glpk blas lapack static-libs test zlib"
 RESTRICT="!test? ( test )"