From: "Sam James" <sam@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Subject: [gentoo-commits] repo/gentoo:master commit in: media-sound/beets/
Date: Wed, 22 Feb 2023 16:00:55 +0000 (UTC) [thread overview]
Message-ID: <1677081555.c3170a5d7b7b045a01046c63b8b749d0a7f26041.sam@gentoo> (raw)
commit: c3170a5d7b7b045a01046c63b8b749d0a7f26041
Author: Petr Vaněk <arkamar <AT> atlas <DOT> cz>
AuthorDate: Wed Feb 22 15:23:50 2023 +0000
Commit: Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Wed Feb 22 15:59:15 2023 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=c3170a5d
media-sound/beets: update EAPI 7 -> 8, enable py3.11
Signed-off-by: Petr Vaněk <arkamar <AT> atlas.cz>
Closes: https://github.com/gentoo/gentoo/pull/29723
Signed-off-by: Sam James <sam <AT> gentoo.org>
media-sound/beets/beets-1.6.0-r1.ebuild | 129 ++++++++++++++++++++++++++++++++
1 file changed, 129 insertions(+)
diff --git a/media-sound/beets/beets-1.6.0-r1.ebuild b/media-sound/beets/beets-1.6.0-r1.ebuild
new file mode 100644
index 000000000000..dbc429fae351
--- /dev/null
+++ b/media-sound/beets/beets-1.6.0-r1.ebuild
@@ -0,0 +1,129 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_SINGLE_IMPL=1
+PYTHON_COMPAT=( python3_{9..11} )
+PYTHON_REQ_USE="sqlite"
+
+inherit distutils-r1 bash-completion-r1 optfeature
+
+if [[ ${PV} == "9999" ]]; then
+ EGIT_REPO_URI="https://github.com/beetbox/beets.git"
+ inherit git-r3
+else
+ MY_PV=${PV/_beta/-beta.}
+ MY_P=${PN}-${MY_PV}
+ SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+ KEYWORDS="~amd64 ~x86"
+ S="${WORKDIR}/${MY_P}"
+fi
+
+DESCRIPTION="Media library management system for obsessive-compulsive music geeks"
+HOMEPAGE="https://beets.io/ https://pypi.org/project/beets/"
+
+LICENSE="MIT"
+SLOT="0"
+IUSE="doc test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+ $(python_gen_cond_dep '
+ >=dev-python/jellyfish-0.7.1[${PYTHON_USEDEP}]
+ dev-python/munkres[${PYTHON_USEDEP}]
+ >=media-libs/mutagen-1.33[${PYTHON_USEDEP}]
+ >=dev-python/python-musicbrainzngs-0.4[${PYTHON_USEDEP}]
+ dev-python/pyyaml[${PYTHON_USEDEP}]
+ dev-python/requests-oauthlib[${PYTHON_USEDEP}]
+ dev-python/requests[${PYTHON_USEDEP}]
+ dev-python/unidecode[${PYTHON_USEDEP}]
+ dev-python/reflink[${PYTHON_USEDEP}]
+ dev-python/confuse[${PYTHON_USEDEP}]
+ dev-python/mediafile[${PYTHON_USEDEP}]
+ ')"
+DEPEND="
+ ${RDEPEND}
+"
+BDEPEND="
+ doc? (
+ dev-python/sphinx
+ )
+ $(python_gen_cond_dep '
+ test? (
+ dev-db/sqlite[icu]
+ dev-python/beautifulsoup4[${PYTHON_USEDEP}]
+ dev-python/bluelet[${PYTHON_USEDEP}]
+ dev-python/discogs-client[${PYTHON_USEDEP}]
+ dev-python/flask[${PYTHON_USEDEP}]
+ dev-python/mock[${PYTHON_USEDEP}]
+ dev-python/pyacoustid[${PYTHON_USEDEP}]
+ dev-python/pylast[${PYTHON_USEDEP}]
+ dev-python/pygobject:3[${PYTHON_USEDEP}]
+ dev-python/python-mpd[${PYTHON_USEDEP}]
+ dev-python/pyxdg[${PYTHON_USEDEP}]
+ dev-python/reflink[${PYTHON_USEDEP}]
+ || (
+ dev-python/pillow[${PYTHON_USEDEP}]
+ media-gfx/imagemagick
+ )
+ dev-python/rarfile[${PYTHON_USEDEP}]
+ dev-python/responses[${PYTHON_USEDEP}]
+ dev-python/wheel[${PYTHON_USEDEP}]
+ media-libs/chromaprint[tools]
+ media-libs/flac
+ media-libs/gst-plugins-bad:1.0
+ media-libs/gst-plugins-good:1.0
+ media-sound/mp3val
+ media-sound/mp3gain
+ media-plugins/gst-plugins-libav:1.0
+ media-video/ffmpeg:0[encode]
+ app-shells/bash-completion
+ )
+ ')"
+
+PATCHES=(
+ "${FILESDIR}/${PV}-0001-Remove-test_completion.patch"
+ "${FILESDIR}/${PV}-sphinx-6.patch"
+ "${FILESDIR}/${PV}-mediafile-test.patch"
+ "${FILESDIR}/${PV}-unicode-test.patch"
+)
+
+DOCS=( README.rst docs/changelog.rst )
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+ distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+ use doc && esetup.py build_sphinx -b html --build-dir=docs/build
+}
+
+python_install_all() {
+ distutils-r1_python_install_all
+
+ doman man/*
+ use doc && local HTML_DOCS=( docs/build/html/. )
+ einstalldocs
+
+ ${PYTHON} "${ED}/usr/bin/beet" completion > "${T}/beet.bash" || die
+ newbashcomp "${T}/beet.bash" beet
+ insinto /usr/share/zsh/site-functions
+ newins "${WORKDIR}/${P}/extra/_beet" _beet
+
+ optfeature "badfiles support" "media-libs/flac media-sound/mp3val"
+ optfeature "chromaprint support" "dev-python/pyacoustid media-libs/chromaprint[tools]"
+ optfeature "discogs support" dev-python/discogs-client
+ optfeature "ffmpeg support" media-video/ffmpeg[encode]
+ optfeature "gstreamer support" "media-libs/gst-plugins-bad media-libs/gst-plugins-good"
+ optfeature "icu support" dev-db/sqlite[icu]
+ optfeature "lastfm support" dev-python/pylast
+ optfeature "mpd support" "dev-python/bluelet dev-python/python-mpd"
+ optfeature "replaygain with gstreamer support" "dev-python/pygobject media-plugins/gst-plugins-libav"
+ optfeature "replaygain without gstreamer support" media-sound/mp3gain
+ optfeature "thumbnail support" dev-python/pyxdg "dev-python/pillow media-gfx/imagemagick"
+ optfeature "webserver support" dev-python/flask
+ optfeature "webserver cors support" dev-python/flask-cors
+}
next reply other threads:[~2023-02-22 16:00 UTC|newest]
Thread overview: 57+ messages / expand[flat|nested] mbox.gz Atom feed top
2023-02-22 16:00 Sam James [this message]
-- strict thread matches above, loose matches on Subject: below --
2025-03-11 9:04 [gentoo-commits] repo/gentoo:master commit in: media-sound/beets/ Ionen Wolkens
2024-12-19 7:54 Arsen Arsenović
2024-12-19 7:54 Arsen Arsenović
2024-06-13 9:26 Matt Jolly
2024-06-03 5:06 Matt Jolly
2024-06-03 5:06 Matt Jolly
2024-05-28 22:01 Sam James
2024-05-23 7:51 Matt Jolly
2024-05-22 13:19 Matt Jolly
2024-05-08 21:33 Sam James
2023-07-14 12:09 Sam James
2023-05-20 6:22 Michał Górny
2023-05-01 0:34 Sam James
2023-05-01 0:19 Sam James
2023-02-22 16:02 Sam James
2023-02-22 16:02 Sam James
2023-02-22 16:00 Sam James
2022-06-22 13:22 Agostino Sarubbo
2022-06-21 6:40 Sam James
2022-06-21 5:35 Sam James
2022-06-07 21:09 Sam James
2022-02-13 22:59 Jakov Smolić
2021-10-31 18:29 Sam James
2021-10-31 8:46 Sam James
2021-10-31 2:58 Sam James
2021-06-01 0:28 Sam James
2021-05-14 11:21 Sam James
2021-01-26 11:37 Joonas Niilola
2021-01-26 11:37 Joonas Niilola
2021-01-26 11:37 Joonas Niilola
2021-01-24 8:09 Joonas Niilola
2021-01-24 8:09 Joonas Niilola
2021-01-18 12:27 Joonas Niilola
2021-01-18 12:27 Joonas Niilola
2021-01-18 12:27 Joonas Niilola
2020-06-01 13:10 Joonas Niilola
2020-06-01 13:07 Joonas Niilola
2020-06-01 13:07 Joonas Niilola
2020-06-01 12:28 Joonas Niilola
2020-06-01 12:28 Joonas Niilola
2020-06-01 12:28 Joonas Niilola
2020-06-01 12:28 Joonas Niilola
2020-03-16 18:55 Michał Górny
2019-08-30 11:46 Joonas Niilola
2019-08-30 11:46 Joonas Niilola
2019-06-01 14:26 Andreas Sturmlechner
2019-05-19 17:54 Andreas Sturmlechner
2018-09-05 21:08 Andreas Sturmlechner
2018-09-05 21:08 Andreas Sturmlechner
2018-09-05 21:08 Andreas Sturmlechner
2018-09-05 21:08 Andreas Sturmlechner
2018-03-18 12:42 Pacho Ramos
2018-03-18 12:42 Pacho Ramos
2017-02-20 0:36 Robin H. Johnson
2016-08-10 20:18 Michael Palimaka
2016-08-10 20:18 Michael Palimaka
Reply instructions:
You may reply publicly to this message via plain-text email
using any one of the following methods:
* Save the following mbox file, import it into your mail client,
and reply-to-all from there: mbox
Avoid top-posting and favor interleaved quoting:
https://en.wikipedia.org/wiki/Posting_style#Interleaved_style
* Reply using the --to, --cc, and --in-reply-to
switches of git-send-email(1):
git send-email \
--in-reply-to=1677081555.c3170a5d7b7b045a01046c63b8b749d0a7f26041.sam@gentoo \
--to=sam@gentoo.org \
--cc=gentoo-commits@lists.gentoo.org \
--cc=gentoo-dev@lists.gentoo.org \
/path/to/YOUR_REPLY
https://kernel.org/pub/software/scm/git/docs/git-send-email.html
* If your mail client supports setting the In-Reply-To header
via mailto: links, try the mailto: link
Be sure your reply has a Subject: header at the top and a blank line
before the message body.
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox