[gentoo-commits] repo/gentoo:master commit in: media-gfx/pngquant/

["Sam James" <sam@gentoo.org>]

commit:     cb413f272536fa7cff7c953d6ef1e71513e763da
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Mon Feb  6 05:15:18 2023 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Mon Feb  6 05:15:18 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=cb413f27

media-gfx/pngquant: add 2.18.0

Signed-off-by: Sam James <sam <AT> gentoo.org>

 media-gfx/pngquant/Manifest               |  1 +
 media-gfx/pngquant/pngquant-2.18.0.ebuild | 68 +++++++++++++++++++++++++++++++
 2 files changed, 69 insertions(+)

diff --git a/media-gfx/pngquant/Manifest b/media-gfx/pngquant/Manifest
index 3cf0ca86ad69..382c5cc28cf7 100644
--- a/media-gfx/pngquant/Manifest
+++ b/media-gfx/pngquant/Manifest
@@ -1,2 +1,3 @@
 DIST pngquant-2.12.6.tar.gz 69074 BLAKE2B 3573d54d94b0085de9ffd4dd34a8fd46c49a1e02d0a6419271c17bc7ac7ab6c05d811336a3a8a8ab21d4dea774c93ee1baae141b42c255838fb1eef9cdb1a871 SHA512 8ffff346df67edf1000c71b6d26371826bc4d236b3f57ef1ec73b3b61668cff9c3ca7d541417c39bc6c89e00176c91eb28867b7a91945ac84292ca0ac54984e9
 DIST pngquant-2.17.0.tar.gz 71209 BLAKE2B 0f625b6c27bc621fd5e1d9b4c5d3cbb7eda960a7afa8e6c6813c5d74e6f48055572dfacfcc93c694dc2d3fd8a107064c2a24c0845fc5339c0289b8527056d39a SHA512 7054cb6bdc547a6e00be1ab2363e2fa5367598593359ef23a91f3af8ff210b281e10f8721bc74d86f208f45336cd61292946c17dc5f26d292998eba95978dc0b
+DIST pngquant-2.18.0.tar.gz 71187 BLAKE2B 3b390908de8484748a136d68f1096d58b6e454138afe6b2f76692acff324830a8246cb7001ffc932b2acdd66732c42d72c898a5a355e4e4b9effc90cd6ed924a SHA512 d9531008c6909cbabd98eb17108baf3085903c22f79548012d9a6c5b1b973329f89739f11a45aa52e12041e8352315af6313ed04339b3db78f2be430a3ae2326

diff --git a/media-gfx/pngquant/pngquant-2.18.0.ebuild b/media-gfx/pngquant/pngquant-2.18.0.ebuild
new file mode 100644
index 000000000000..ae8a0c8e0e3b
--- /dev/null
+++ b/media-gfx/pngquant/pngquant-2.18.0.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit toolchain-funcs
+
+DESCRIPTION="Command-line utility and library for lossy compression of PNG images"
+HOMEPAGE="https://pngquant.org/ https://github.com/kornelski/pngquant"
+SRC_URI="https://github.com/kornelski/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3 HPND rwpng"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
+
+IUSE="cpu_flags_x86_sse2 debug lcms openmp test"
+REQUIRED_USE="test? ( lcms )"
+
+RDEPEND="
+	media-libs/libpng:=
+	media-gfx/libimagequant:=
+	sys-libs/zlib:=
+	lcms? ( media-libs/lcms:2 )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+RESTRICT="!test? ( test )"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-2.12.2-respect-CFLAGS.patch
+	"${FILESDIR}"/${PN}-2.17.0-fix-test-version.patch
+)
+
+pkg_pretend() {
+	[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
+}
+
+pkg_setup() {
+	[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
+}
+
+src_prepare() {
+	default
+
+	# avoid silent fallback to bundled lib
+	rm -rv lib || die
+}
+
+src_configure() {
+	tc-export AR CC
+	# Hand rolled configure script, so not all flags are supported.
+	./configure \
+		--prefix="${EPREFIX}/usr" \
+		--with-libimagequant \
+		$(use debug && echo --enable-debug) \
+		$(use_enable cpu_flags_x86_sse2 sse) \
+		$(use openmp && echo --with-openmp) \
+		$(use_with lcms lcms2) \
+		CFLAGS="${CFLAGS} ${CPPFLAGS}" \
+		LDFLAGS="${LDFLAGS}"
+}
+
+src_install() {
+	dobin ${PN}
+	doman ${PN}.1
+	dodoc CHANGELOG README.md
+}