[gentoo-commits] repo/gentoo:master commit in: app-misc/gnote/

["Matt Turner" <mattst88@gentoo.org>]

commit:     bf0abc0263b14e13badf3125cbb460ffe49788ff
Author:     Guillermo Joandet <gjoandet <AT> gmail <DOT> com>
AuthorDate: Mon Feb  6 01:31:43 2023 +0000
Commit:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Mon Feb  6 02:40:42 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=bf0abc02

app-misc/gnote: Version bump to 43.1

Signed-off-by: Guillermo Joandet <gjoandet <AT> gmail.com>
Closes: https://github.com/gentoo/gentoo/pull/29442
Signed-off-by: Matt Turner <mattst88 <AT> gentoo.org>

 app-misc/gnote/Manifest          |  1 +
 app-misc/gnote/gnote-43.1.ebuild | 66 ++++++++++++++++++++++++++++++++++++++++
 2 files changed, 67 insertions(+)

diff --git a/app-misc/gnote/Manifest b/app-misc/gnote/Manifest
index 741f16798932..6b8d4b763029 100644
--- a/app-misc/gnote/Manifest
+++ b/app-misc/gnote/Manifest
@@ -1 +1,2 @@
 DIST gnote-43.0.tar.xz 3325232 BLAKE2B 9e56aa164262b710aab872be48fded2a6c70a062ddfe7c95ae633c38269390a6b3c3143c788f0ee43fb37d0229443a600d71e5edfbab1aa387a20e135210a0dc SHA512 34133ba1cef12c02a6518017f6b5b07b6781f05af787034ceb3dd8bc4d59fff2a7cdc17615511e7008c39bebf52e6b78a973840bdd5b6b1e5199226fdd12d91c
+DIST gnote-43.1.tar.xz 3329384 BLAKE2B 0e871797160a45d07ec17d9fbfeaaf159b755bdf373480ac47ac03b966b87510d0d721fdc581da76c0f7e3b1098964d926122f0aeb36c4a44597b137fe41ccf2 SHA512 7b007e325634371deee99e09230f4f2427a072e203d6086a91888ed3be69b54b22bfc9e49010a43a09c134f0d4de9d510fd1a370e2432f9542241d9f37e05921

diff --git a/app-misc/gnote/gnote-43.1.ebuild b/app-misc/gnote/gnote-43.1.ebuild
new file mode 100644
index 000000000000..5372712a5529
--- /dev/null
+++ b/app-misc/gnote/gnote-43.1.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit gnome2 meson readme.gentoo-r1
+
+DESCRIPTION="Desktop note-taking application"
+HOMEPAGE="https://wiki.gnome.org/Apps/Gnote"
+
+LICENSE="GPL-3+ FDL-1.1"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~riscv ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+DEPEND="
+	>=dev-libs/glib-2.62:2[dbus]
+	>=dev-cpp/glibmm-2.62.0:2
+	>=dev-cpp/gtkmm-3.22.20:3.0
+	>=app-crypt/libsecret-0.8
+	>=dev-libs/libxml2-2:2
+	dev-libs/libxslt
+	>=sys-apps/util-linux-2.16:=
+	>=app-text/gspell-1.6.0:=
+	test? ( dev-libs/unittest++ )
+"
+RDEPEND="${DEPEND}
+	gnome-base/gsettings-desktop-schemas
+"
+BDEPEND="
+	app-text/docbook-xml-dtd:4.1.2
+	>=dev-util/intltool-0.35.0
+	dev-util/itstool
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	default
+
+	# Build system requires UnitTest++ >=1.5.1, but the .pc file doesn't
+	# specify a version
+	sed -i -e "/UnitTest++/ s/version: [^,]*,//" meson.build || die
+	if ! use test; then
+		sed -i -e "/unit_test_pp/ s/ = .*/ = disabler()/" meson.build || die
+	fi
+
+	if has_version net-fs/wdfs; then
+		DOC_CONTENTS="You have net-fs/wdfs installed. app-misc/gnote will use it to
+		synchronize notes."
+	else
+		DOC_CONTENTS="Gnote can use net-fs/wdfs to synchronize notes.
+		If you want to use that functionality just emerge net-fs/wdfs.
+		Gnote will automatically detect that you did and let you use it."
+	fi
+}
+
+src_install() {
+	meson_src_install
+	readme.gentoo_create_doc
+}
+
+pkg_postinst() {
+	gnome2_pkg_postinst
+	readme.gentoo_print_elog
+}