[gentoo-commits] repo/gentoo:master commit in: dev-python/APScheduler/

["Michał Górny" <mgorny@gentoo.org>]

commit:     7a8500a85ff802b8203af58e05dc8e6f656b7553
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Wed Feb  1 04:18:04 2023 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Wed Feb  1 04:57:02 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=7a8500a8

dev-python/APScheduler: Bump to 3.10.0

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/APScheduler/APScheduler-3.10.0.ebuild | 58 ++++++++++++++++++++++++
 dev-python/APScheduler/Manifest                  |  1 +
 2 files changed, 59 insertions(+)

diff --git a/dev-python/APScheduler/APScheduler-3.10.0.ebuild b/dev-python/APScheduler/APScheduler-3.10.0.ebuild
new file mode 100644
index 000000000000..496012d99a0f
--- /dev/null
+++ b/dev-python/APScheduler/APScheduler-3.10.0.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{9..11} )
+
+inherit distutils-r1
+
+DESCRIPTION="In-process task scheduler with Cron-like capabilities"
+HOMEPAGE="
+	https://github.com/agronholm/apscheduler/
+	https://pypi.org/project/APScheduler/
+"
+SRC_URI="mirror://pypi/${PN::1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+# imports pkg_resources
+RDEPEND="
+	dev-python/pytz[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	>=dev-python/six-1.4.0[${PYTHON_USEDEP}]
+	>=dev-python/tzlocal-4[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/setuptools_scm[${PYTHON_USEDEP}]
+	test? (
+		>=dev-python/sqlalchemy-1.4[${PYTHON_USEDEP}]
+		dev-python/tornado[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+PATCHES=(
+	# disable test fixtures using external servers (mongodb, redis...)
+	# these fixtures are using markers in git master, so the patch
+	# should be no longer necessary with next major bump
+	"${FILESDIR}"/APScheduler-3.8.1-external-server-tests.patch
+)
+
+EPYTEST_DESELECT=(
+	tests/test_jobstores.py::test_repr_mongodbjobstore
+	tests/test_jobstores.py::test_repr_redisjobstore
+	tests/test_jobstores.py::test_repr_zookeeperjobstore
+)
+
+python_prepare_all() {
+	# suppress setuptools warning #797751
+	sed -e 's|^upload-dir|upload_dir|' -i setup.cfg || die
+	sed -e '/addopts/d' -i setup.cfg || die
+
+	distutils-r1_python_prepare_all
+}

diff --git a/dev-python/APScheduler/Manifest b/dev-python/APScheduler/Manifest
index f7cc8a75c5a7..b1ece2737e82 100644
--- a/dev-python/APScheduler/Manifest
+++ b/dev-python/APScheduler/Manifest
@@ -1 +1,2 @@
+DIST APScheduler-3.10.0.tar.gz 100353 BLAKE2B 0d5c25641410161b15bd337661c15443b1034c85d5fa770b4603352c86f517d0ebb9713ac514a2efe1ec5d77f086fbecfb2c39bbf6e41ec6666cfcbb619dd3cb SHA512 ba44be82b10bac899b631b32d78ecc9303955241d2e2b7597282bd914726af3cf406bd3c6e0285f2a9b1737288453075107f317118ae1240de9e15f36290c979
 DIST APScheduler-3.9.1.tar.gz 100567 BLAKE2B a31e2591c47d451e95a982b4d85a70ee9a33bf2370a70e0e1ba2a8e31ae718d5853aad6242cbd8f90dc5bc6912af3ea96270e9f514c3903d041af450c1d8ead5 SHA512 901e04140dc9af3b67887cd3200131cc4121cad71b7ca4afe7cc0adf1a58cebb02eee5abed1f97fc95fe9fef843d00cd6611ab3fbff8ace9247894d6f0720dff