From mboxrd@z Thu Jan 1 00:00:00 1970
Return-Path: <gentoo-commits+bounces-1467498-garchives=archives.gentoo.org@lists.gentoo.org>
Received: from lists.gentoo.org (pigeon.gentoo.org [208.92.234.80])
(using TLSv1.3 with cipher TLS_AES_256_GCM_SHA384 (256/256 bits)
key-exchange X25519 server-signature RSA-PSS (2048 bits) server-digest SHA256)
(No client certificate requested)
by finch.gentoo.org (Postfix) with ESMTPS id 71258158020
for <garchives@archives.gentoo.org>; Fri, 16 Dec 2022 04:40:19 +0000 (UTC)
Received: from pigeon.gentoo.org (localhost [127.0.0.1])
by pigeon.gentoo.org (Postfix) with SMTP id B8828E0824;
Fri, 16 Dec 2022 04:40:18 +0000 (UTC)
Received: from smtp.gentoo.org (woodpecker.gentoo.org [140.211.166.183])
(using TLSv1.3 with cipher TLS_AES_256_GCM_SHA384 (256/256 bits)
key-exchange X25519 server-signature RSA-PSS (4096 bits) server-digest SHA256)
(No client certificate requested)
by pigeon.gentoo.org (Postfix) with ESMTPS id 996BCE0824
for <gentoo-commits@lists.gentoo.org>; Fri, 16 Dec 2022 04:40:18 +0000 (UTC)
Received: from oystercatcher.gentoo.org (oystercatcher.gentoo.org [148.251.78.52])
(using TLSv1.3 with cipher TLS_AES_256_GCM_SHA384 (256/256 bits)
key-exchange X25519 server-signature RSA-PSS (4096 bits) server-digest SHA256)
(No client certificate requested)
by smtp.gentoo.org (Postfix) with ESMTPS id AD1BA340DF8
for <gentoo-commits@lists.gentoo.org>; Fri, 16 Dec 2022 04:40:17 +0000 (UTC)
Received: from localhost.localdomain (localhost [IPv6:::1])
by oystercatcher.gentoo.org (Postfix) with ESMTP id 130BD21
for <gentoo-commits@lists.gentoo.org>; Fri, 16 Dec 2022 04:40:16 +0000 (UTC)
From: "Sam James" <sam@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Content-Transfer-Encoding: 8bit
Content-type: text/plain; charset=UTF-8
Reply-To: gentoo-dev@lists.gentoo.org, "Sam James" <sam@gentoo.org>
Message-ID: <1671165302.9939f85601cbca6f6cd1ee7f39f4f8c170358595.sam@gentoo>
Subject: [gentoo-commits] repo/gentoo:master commit in: media-libs/libsdl/
X-VCS-Repository: repo/gentoo
X-VCS-Files: media-libs/libsdl/Manifest media-libs/libsdl/libsdl-1.2.15_p20221201.ebuild
X-VCS-Directories: media-libs/libsdl/
X-VCS-Committer: sam
X-VCS-Committer-Name: Sam James
X-VCS-Revision: 9939f85601cbca6f6cd1ee7f39f4f8c170358595
X-VCS-Branch: master
Date: Fri, 16 Dec 2022 04:40:16 +0000 (UTC)
Precedence: bulk
List-Post: <mailto:gentoo-commits@lists.gentoo.org>
List-Help: <mailto:gentoo-commits+help@lists.gentoo.org>
List-Unsubscribe: <mailto:gentoo-commits+unsubscribe@lists.gentoo.org>
List-Subscribe: <mailto:gentoo-commits+subscribe@lists.gentoo.org>
List-Id: Gentoo Linux mail <gentoo-commits.gentoo.org>
X-BeenThere: gentoo-commits@lists.gentoo.org
X-Auto-Response-Suppress: DR, RN, NRN, OOF, AutoReply
X-Archives-Salt: dfd285f1-9551-47e9-9024-65b8595e7925
X-Archives-Hash: f67189376e595fc59b1b11ae687747a9
commit: 9939f85601cbca6f6cd1ee7f39f4f8c170358595
Author: Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Fri Dec 16 04:35:02 2022 +0000
Commit: Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Fri Dec 16 04:35:02 2022 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=9939f856
media-libs/libsdl: add 1.2.15_p20221201
Fixes CVE-2021-33657.
Bug: https://bugs.gentoo.org/836665
Signed-off-by: Sam James <sam <AT> gentoo.org>
media-libs/libsdl/Manifest | 1 +
media-libs/libsdl/libsdl-1.2.15_p20221201.ebuild | 166 +++++++++++++++++++++++
2 files changed, 167 insertions(+)
diff --git a/media-libs/libsdl/Manifest b/media-libs/libsdl/Manifest
index c47438c7c26c..0bf126fb820c 100644
--- a/media-libs/libsdl/Manifest
+++ b/media-libs/libsdl/Manifest
@@ -1,2 +1,3 @@
DIST SDL-1.2.15_p20210224.tar.gz 3991106 BLAKE2B be0906950c80cddf15bc458f7734a3ebfa767b11e2f54bf9f771155f4420947900b95bbbebf01341d9dba4c1c7cfe9d54e43150e5f7781622b99668b3362adeb SHA512 3521fe996cf8a8ebb9beaa4802ac05cf5f3a2e7ed1c9b362a818d965b26ec8b3bbebfaac7c827feae44becf5bdd764378cb4282d129285f23a982b5c7474e006
DIST SDL-1.2.15_p20221103.tar.gz 4002891 BLAKE2B 2329cec3579a2eb226ee7c8566f7f995b21b4f7fac3a0b40f237cf2d13576347a001dac96caf35d7da0fa95b4ee1684fbb9972a82e2691e4c83c1c0984b46029 SHA512 bd2cf4119dd9be99094d3379b15067817d4d40490d894e2338da9c365378d79edcfe2d7df03f57ac948f5fd1f949e5acb5b2233be484084a828c98af350f1830
+DIST SDL-1.2.15_p20221201.tar.gz 4002787 BLAKE2B 87b729cb16cfb36efa2b66166ef21d4c5c8bc99f8c8b4683885f04699122945a60512c5875d0c8425ddfe33b2eb901d11f27afbd9e3656cde3f30de5a5f1537c SHA512 5e70977cf5beaffebb28ae84f778e08d3cf56b2badda125ec1f08ac26c6b4e60a148d9ca9b2d7efee8a5fbc0b1a343d1d27a05be1c08e5d9251da67aea209659
diff --git a/media-libs/libsdl/libsdl-1.2.15_p20221201.ebuild b/media-libs/libsdl/libsdl-1.2.15_p20221201.ebuild
new file mode 100644
index 000000000000..3a3700ce6d5b
--- /dev/null
+++ b/media-libs/libsdl/libsdl-1.2.15_p20221201.ebuild
@@ -0,0 +1,166 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools flag-o-matic multilib-minimal toolchain-funcs
+
+MY_COMMIT="ca3acd25348edc9b6e984fc1712fd4d365931dc1"
+DESCRIPTION="Simple Direct Media Layer"
+HOMEPAGE="https://libsdl.org/"
+SRC_URI="https://github.com/libsdl-org/SDL-1.2/archive/${MY_COMMIT}.tar.gz -> SDL-${PV}.tar.gz"
+S="${WORKDIR}"/SDL-1.2-${MY_COMMIT}
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+# WARNING:
+# If you turn on the custom-cflags use flag in USE and something breaks,
+# you pick up the pieces. Be prepared for bug reports to be marked INVALID.
+IUSE="aalib alsa custom-cflags dga fbcon +joystick libcaca nas opengl oss pulseaudio +sound static-libs tslib +video X xinerama xv"
+
+RDEPEND="
+ aalib? ( >=media-libs/aalib-1.4_rc5-r6[${MULTILIB_USEDEP}] )
+ alsa? ( >=media-libs/alsa-lib-1.0.27.2[${MULTILIB_USEDEP}] )
+ libcaca? ( >=media-libs/libcaca-0.99_beta18-r1[${MULTILIB_USEDEP}] )
+ nas? (
+ >=media-libs/nas-1.9.4[${MULTILIB_USEDEP}]
+ >=x11-libs/libX11-1.6.2[${MULTILIB_USEDEP}]
+ >=x11-libs/libXext-1.3.2[${MULTILIB_USEDEP}]
+ >=x11-libs/libXt-1.1.4[${MULTILIB_USEDEP}]
+ )
+ opengl? (
+ >=virtual/glu-9.0-r1[${MULTILIB_USEDEP}]
+ >=virtual/opengl-7.0-r1[${MULTILIB_USEDEP}]
+ )
+ tslib? ( >=x11-libs/tslib-1.0-r3[${MULTILIB_USEDEP}] )
+ pulseaudio? ( >=media-sound/pulseaudio-2.1-r1[${MULTILIB_USEDEP}] )
+ sound? ( >=media-libs/audiofile-0.3.5[${MULTILIB_USEDEP}] )
+ X? (
+ >=x11-libs/libX11-1.6.2[${MULTILIB_USEDEP}]
+ >=x11-libs/libXext-1.3.2[${MULTILIB_USEDEP}]
+ >=x11-libs/libXrandr-1.4.2[${MULTILIB_USEDEP}]
+ )
+"
+DEPEND="
+ ${RDEPEND}
+ nas? ( x11-base/xorg-proto )
+ X? ( x11-base/xorg-proto )
+"
+BDEPEND="
+ pulseaudio? ( virtual/pkgconfig )
+ x86? (
+ || (
+ >=dev-lang/yasm-0.6.0
+ >=dev-lang/nasm-0.98.39-r3
+ )
+ )"
+
+pkg_setup() {
+ if use custom-cflags ; then
+ ewarn "Since you've chosen to use possibly unsafe CFLAGS,"
+ ewarn "don't bother filing libsdl-related bugs until trying to remerge"
+ ewarn "libsdl without the custom-cflags use flag in USE."
+ fi
+}
+
+PATCHES=(
+ "${FILESDIR}"/${PN}-$(ver_cut 1-3)-sdl-config.patch
+ "${FILESDIR}"/${PN}-$(ver_cut 1-3)-gamma.patch
+)
+
+DOCS=( BUGS CREDITS README-SDL.txt TODO WhatsNew )
+
+HTML_DOCS=( {docs,VisualC}.html docs/{html,images,index.html} )
+
+src_prepare() {
+ default
+
+ if $(tc-is-gcc) && [[ ${CHOST} == *-darwin* ]] ; then
+ # GCC at least has no idea what -fpascal-strings is
+ sed -i -e '/EXTRA_CFLAGS="$EXTRA_CFLAGS -fpascal-strings"/d' configure.ac || die
+ # We have trouble building against Frameworks with GCC for now (no Blocks support, etc)
+ # error: unknown type name ‘CGImageSourceAnimationBlock’
+ sed -i \
+ -e '/EXTRA_CFLAGS="$EXTRA_CFLAGS -DTARGET_API_MAC_CARBON"/d' \
+ -e '/EXTRA_CFLAGS="$EXTRA_CFLAGS -DTARGET_API_MAC_OSX"/d' \
+ configure.ac || die
+ fi
+
+ AT_M4DIR="${EPREFIX}/usr/share/aclocal acinclude" eautoreconf
+}
+
+multilib_src_configure() {
+ local myconf=
+
+ if $(tc-is-gcc) && [[ ${CHOST} == *-darwin* ]] ; then
+ # We can't build against Cocoa because we lack Blocks + Objective C++ support in
+ # GCC (for now)
+ use video && myconf="${myconf} --disable-video-cocoa"
+ # CD support drags in audio
+ myconf="${myconf} --disable-cdrom"
+ else
+ myconf="${myconf} --enable-cdrom"
+ fi
+
+ if use !x86 && use !x86-linux ; then
+ myconf="${myconf} --disable-nasm"
+ else
+ myconf="${myconf} --enable-nasm"
+ fi
+ use custom-cflags || strip-flags
+ use sound || myconf="${myconf} --disable-audio"
+ use video \
+ && myconf="${myconf} --enable-video-dummy" \
+ || myconf="${myconf} --disable-video"
+ use joystick || myconf="${myconf} --disable-joystick"
+
+ ECONF_SOURCE="${S}" econf \
+ $(use_enable prefix rpath) \
+ --disable-arts \
+ --disable-esd \
+ --enable-events \
+ --enable-threads \
+ --enable-timers \
+ --enable-file \
+ --enable-cpuinfo \
+ --disable-alsa-shared \
+ --disable-esd-shared \
+ --disable-sndio \
+ --disable-pulseaudio-shared \
+ --disable-arts-shared \
+ --disable-nas-shared \
+ --disable-osmesa-shared \
+ $(use_enable oss) \
+ $(use_enable alsa) \
+ $(use_enable pulseaudio) \
+ $(use_enable nas) \
+ $(use_enable X video-x11) \
+ $(use_enable dga) \
+ $(use_enable xv video-x11-xv) \
+ $(use_enable xinerama video-x11-xinerama) \
+ $(use_enable X video-x11-xrandr) \
+ $(use_enable dga video-dga) \
+ $(use_enable fbcon video-fbcon) \
+ --disable-video-ggi \
+ --disable-video-svga \
+ $(use_enable aalib video-aalib) \
+ $(use_enable libcaca video-caca) \
+ $(use_enable opengl video-opengl) \
+ --disable-video-ps3 \
+ $(use_enable tslib input-tslib) \
+ $(use_with X x) \
+ $(use_enable static-libs static) \
+ --disable-video-x11-xme \
+ --disable-video-directfb \
+ ${myconf}
+}
+
+multilib_src_install() {
+ emake DESTDIR="${D}" install
+}
+
+multilib_src_install_all() {
+ use static-libs || find "${ED}" -type f -name "*.la" -delete || die
+ einstalldocs
+}