[gentoo-commits] repo/gentoo:master commit in: gnome-extra/gnome-software/

["Matt Turner" <mattst88@gentoo.org>]

commit:     3c64ab124b839e7c7f46f560514df1433ccb5a0d
Author:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
AuthorDate: Fri Dec  2 14:32:25 2022 +0000
Commit:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Fri Dec  2 14:35:33 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=3c64ab12

gnome-extra/gnome-software: Version bump to 43.2

Signed-off-by: Matt Turner <mattst88 <AT> gentoo.org>

 gnome-extra/gnome-software/Manifest                |   1 +
 .../gnome-software/gnome-software-43.2.ebuild      | 102 +++++++++++++++++++++
 2 files changed, 103 insertions(+)

diff --git a/gnome-extra/gnome-software/Manifest b/gnome-extra/gnome-software/Manifest
index 14190ddfb56c..48784d706f4e 100644
--- a/gnome-extra/gnome-software/Manifest
+++ b/gnome-extra/gnome-software/Manifest
@@ -1,3 +1,4 @@
 DIST gnome-software-42.4.tar.xz 2278412 BLAKE2B beb63ba7f874b72edd3c592f0a7553a4a5ba3631ede55da4c70989604cd0433dd40dd7c75b4bafdf106f1c02285e8502a610d8e2c9edf8cc4d34ea14f75fab62 SHA512 00c70886c6e3302a59ae533034d8d75cfe05873ea40d0d05a03e15ae34101bb8a64722a7c6a6d43bb54b61033bc14af1542bb832a70ee7b1a2dab6dacb8ffd8f
 DIST gnome-software-43.0.tar.xz 2352976 BLAKE2B 8dc8b03c198aad01e73026ccb4b3e99888f39e9bbd99d9809863a2fe405865022a33458194f3769a3a5e9ff7a888beb463aca2805d90405342f9aae4485b352a SHA512 bcf64e4d3d847c660fd1c1a2356235569560bc315fb6b0d2e459dfb1bbee7bf97d9a14f7c8ef1129e01241385cd1540d1499f9cc9ad99a996965feb48e698d6a
 DIST gnome-software-43.1.tar.xz 2351032 BLAKE2B e8718817ee9a6ac458f57d5f06271136d590ba2e6a951a05f143f5f85e124b0a64e1866fd50a1ff8e28e24682ffcb6ffb72dfd2ee8fcb9f6e8dd2fa3797513a5 SHA512 5494622e1c52bcf660df8ab83cd73720ccab3c767f8870b6a23bd83c396972c508beb365e6df143055e3a7d9e77b42f01ea73a49d8dcdcf97aaeada0fe9f03e5
+DIST gnome-software-43.2.tar.xz 2356928 BLAKE2B 07cc787cc3320f84bc29164c40da8d600f011e1a1d8645be6089375f13658772562061e100f6347fa2019cc21cf27b71bd4c050fcc2850a2bb56d1160e849141 SHA512 d011418536706d2c5693581bd322008b5eb0fdf766ec96f1775135efb0fecec42dbc126ea2a66465b2169afb38b48fed1246516197e3bbf9d75b96e339d6ba33

diff --git a/gnome-extra/gnome-software/gnome-software-43.2.ebuild b/gnome-extra/gnome-software/gnome-software-43.2.ebuild
new file mode 100644
index 000000000000..19f8b6526551
--- /dev/null
+++ b/gnome-extra/gnome-software/gnome-software-43.2.ebuild
@@ -0,0 +1,102 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit gnome.org gnome2-utils meson virtualx xdg
+
+DESCRIPTION="Gnome install & update software"
+HOMEPAGE="https://wiki.gnome.org/Apps/Software https://gitlab.gnome.org/GNOME/gnome-software"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="flatpak +firmware gnome gtk-doc sysprof udev test"
+
+RDEPEND="
+	>=dev-libs/appstream-0.14.0:0=
+	>=x11-libs/gdk-pixbuf-2.32.0:2
+	>=dev-libs/libxmlb-0.1.7:=
+	>=gui-libs/gtk-4.6:4
+	>=dev-libs/glib-2.70.0:2
+	>=dev-libs/json-glib-1.6.0
+	>=net-libs/libsoup-3.0:3.0
+	>=gui-libs/libadwaita-1.0.1:1
+	sysprof? ( >=dev-util/sysprof-capture-3.40.1:4 )
+	gnome? ( >=gnome-base/gsettings-desktop-schemas-3.18.0 )
+	sys-auth/polkit
+	firmware? ( >=sys-apps/fwupd-1.5.6 )
+	flatpak? (
+		>=sys-apps/flatpak-1.9.1
+		dev-util/ostree
+	)
+	udev? ( dev-libs/libgudev )
+	>=gnome-base/gsettings-desktop-schemas-3.11.5
+"
+DEPEND="${RDEPEND}
+	test? ( dev-libs/libglib-testing )
+"
+BDEPEND="
+	dev-libs/libxml2:2
+	dev-util/gdbus-codegen
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+	gtk-doc? (
+		dev-util/gtk-doc
+		app-text/docbook-xml-dtd:4.3
+	)
+"
+
+src_prepare() {
+	default
+	xdg_environment_reset
+
+	sed -i -e '/install_data.*README\.md.*share\/doc\/gnome-software/d' meson.build || die
+	# We don't need language packs download support, and it fails tests in 3.34.2 for us (if they are enabled)
+	sed -i -e '/subdir.*fedora-langpacks/d' plugins/meson.build || die
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use test tests)
+		$(meson_feature gnome gsettings_desktop_schemas) # Honoring of GNOME date format settings.
+		-Dman=true
+		-Dpackagekit=false
+		# -Dpackagekit_autoremove
+		-Dpolkit=true
+		-Deos_updater=false # Endless OS updater
+		$(meson_use firmware fwupd)
+		$(meson_use flatpak)
+		-Dmalcontent=false
+		-Drpm_ostree=false
+		-Dwebapps=true
+		-Dhardcoded_foss_webapps=true
+		-Dhardcoded_proprietary_webapps=true
+		$(meson_use udev gudev)
+		-Dapt=false
+		-Dsnap=false
+		-Dexternal_appstream=false
+		$(meson_use gtk-doc gtk_doc)
+		-Dhardcoded_curated=true
+		-Ddefault_featured_apps=false # TODO: Will this be beneficial to us with flatpak at least? If enabled, it shows some apps under installed (probably merely due to /usr/share/app-info presence), but launching and removal of them is broken
+		-Dmogwai=false #TODO?
+		$(meson_feature sysprof)
+		-Dprofile=''
+		-Dsoup2=false
+	)
+	meson_src_configure
+}
+
+src_test() {
+	virtx dbus-run-session meson test -C "${BUILD_DIR}" || die
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}