[gentoo-commits] repo/proj/guru:dev commit in: app-text/komikku/

["Anna Vyalkova" <cyber+gentoo@sysrq.in>]

commit:     667485dbc68a7d5368dcc5c383a99a6a9ca0dccd
Author:     Anna (cybertailor) Vyalkova <cyber+gentoo <AT> sysrq <DOT> in>
AuthorDate: Tue Nov 22 07:32:10 2022 +0000
Commit:     Anna Vyalkova <cyber+gentoo <AT> sysrq <DOT> in>
CommitDate: Tue Nov 22 07:32:10 2022 +0000
URL:        https://gitweb.gentoo.org/repo/proj/guru.git/commit/?id=667485db

app-text/komikku: new package, add 1.4.1

Signed-off-by: Anna (cybertailor) Vyalkova <cyber+gentoo <AT> sysrq.in>

 app-text/komikku/Manifest             |  1 +
 app-text/komikku/komikku-1.4.1.ebuild | 91 +++++++++++++++++++++++++++++++++++
 app-text/komikku/metadata.xml         | 11 +++++
 3 files changed, 103 insertions(+)

diff --git a/app-text/komikku/Manifest b/app-text/komikku/Manifest
new file mode 100644
index 000000000..117e700a1
--- /dev/null
+++ b/app-text/komikku/Manifest
@@ -0,0 +1 @@
+DIST Komikku-v1.4.1.tar.bz2 4306813 BLAKE2B f611b4596c86606f8b7d4840ea049d7547eebbe75ab594e2904dd639ad29006d648610c9e90993d065baa36f48de4f1c41cbc3b0a4462f6e342623007c946faf SHA512 a4cb417fb65517d1245f32a220b7d16f42130e4f96edfce8dc33ac00b9f3664f451937036e0c6849984e8864e1d1b10ea57a4614d9256d164e8d4c04cb199990

diff --git a/app-text/komikku/komikku-1.4.1.ebuild b/app-text/komikku/komikku-1.4.1.ebuild
new file mode 100644
index 000000000..0fa2a0727
--- /dev/null
+++ b/app-text/komikku/komikku-1.4.1.ebuild
@@ -0,0 +1,91 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..10} )
+PYTHON_REQ_USE="sqlite(+),ssl(+)"
+DISTUTILS_USE_PEP517=no
+DISTUTILS_SINGLE_IMPL=1
+inherit distutils-r1 meson gnome2-utils virtualx xdg
+
+MY_PN="${PN^}"
+MY_P="${MY_PN}-v${PV}"
+DESCRIPTION="An online/offline manga reader for GNOME"
+HOMEPAGE="https://gitlab.com/valos/Komikku"
+SRC_URI="https://gitlab.com/valos/${MY_PN}/-/archive/v${PV}/${MY_P}.tar.bz2"
+S="${WORKDIR}/${MY_P}"
+
+KEYWORDS="~amd64"
+LICENSE="GPL-3+"
+SLOT="0"
+IUSE="test"
+
+RESTRICT="test"
+PROPERTIES="test_network"
+
+DEPEND="
+	dev-libs/glib:2
+	dev-libs/gobject-introspection[${PYTHON_SINGLE_USEDEP}]
+	>=gui-libs/gtk-4.8.2:4
+	>=gui-libs/libadwaita-1.2.0[introspection]
+	net-libs/webkit-gtk:5[introspection]
+"
+RDEPEND="
+	${DEPEND}
+	$(python_gen_cond_dep '
+		app-arch/brotli[python,${PYTHON_USEDEP}]
+		dev-python/aiohttp[${PYTHON_USEDEP}]
+		dev-python/beautifulsoup4[${PYTHON_USEDEP}]
+		dev-python/cffi[${PYTHON_USEDEP}]
+		dev-python/cloudscraper[${PYTHON_USEDEP}]
+		dev-python/cryptography[${PYTHON_USEDEP}]
+		dev-python/dateparser[${PYTHON_USEDEP}]
+		dev-python/emoji[${PYTHON_USEDEP}]
+		dev-python/keyring[${PYTHON_USEDEP}]
+		dev-python/lxml[${PYTHON_USEDEP}]
+		dev-python/natsort[${PYTHON_USEDEP}]
+		dev-python/pillow[${PYTHON_USEDEP}]
+		dev-python/pure-protobuf[${PYTHON_USEDEP}]
+		dev-python/pygobject[${PYTHON_USEDEP}]
+		dev-python/python-magic[${PYTHON_USEDEP}]
+		dev-python/rarfile[compressed,${PYTHON_USEDEP}]
+		dev-python/requests[${PYTHON_USEDEP}]
+		dev-python/unidecode[${PYTHON_USEDEP}]
+	')
+"
+BDEPEND="
+	test? (
+		$(python_gen_cond_dep '
+			dev-python/pytest-steps[${PYTHON_USEDEP}]
+		')
+	)
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	default
+
+	# fix broken shebang
+	sed "s|py_installation.path()|'${PYTHON}'|" -i bin/meson.build || die
+}
+
+src_test() {
+	virtx epytest
+}
+
+src_install() {
+	meson_src_install
+	python_optimize
+}
+
+pkg_postinst() {
+	gnome2_schemas_update
+	xdg_pkg_postinst
+}
+
+pkg_postrm() {
+	gnome2_schemas_update
+	xdg_pkg_postrm
+}

diff --git a/app-text/komikku/metadata.xml b/app-text/komikku/metadata.xml
new file mode 100644
index 000000000..f267a16e3
--- /dev/null
+++ b/app-text/komikku/metadata.xml
@@ -0,0 +1,11 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>cyber+gentoo@sysrq.in</email>
+		<name>Anna</name>
+	</maintainer>
+	<upstream>
+		<remote-id type="gitlab">valos/Komikku</remote-id>
+	</upstream>
+</pkgmetadata>