[gentoo-commits] repo/gentoo:master commit in: gnome-extra/cinnamon-session/

["Sam James" <sam@gentoo.org>]

commit:     2fe8457ff2d4793c0e8e88b96931239e10176ba6
Author:     Matthew S. Turnbull <sparky <AT> bluefang-logic <DOT> com>
AuthorDate: Fri Nov 18 05:55:08 2022 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Tue Nov 22 06:17:35 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=2fe8457f

gnome-extra/cinnamon-session: add 5.6.0

Signed-off-by: Matthew S. Turnbull <sparky <AT> bluefang-logic.com>
Signed-off-by: Sam James <sam <AT> gentoo.org>

 gnome-extra/cinnamon-session/Manifest              |  1 +
 .../cinnamon-session/cinnamon-session-5.6.0.ebuild | 72 ++++++++++++++++++++++
 2 files changed, 73 insertions(+)

diff --git a/gnome-extra/cinnamon-session/Manifest b/gnome-extra/cinnamon-session/Manifest
index c2899607dde3..4e2247cff911 100644
--- a/gnome-extra/cinnamon-session/Manifest
+++ b/gnome-extra/cinnamon-session/Manifest
@@ -1,2 +1,3 @@
 DIST cinnamon-session-5.2.0.tar.gz 200208 BLAKE2B 2efe8ef0cb5dc4a828866c91bc020ffcc8b400423f92ac8be8ab47391202001123805c947af8e82eda530675b89cf4960f082b06acf24c296f083d6bcb941217 SHA512 3962529fed8d6c4c74e2f4b75014529d1a9b3307cf2d014c90088d0e2d3066ce375ccc3bbf5f07e9a181c08bba5360b07d5800cdb6386796255b4f1cb5c4d385
 DIST cinnamon-session-5.4.0.tar.gz 199698 BLAKE2B 44856e577f1a42fa373bfeb9ad834f3b8b73ce51b8bf2aa794d1e98bb24dacea6fc31ced30965399bc9d9405a8cd29f45764462e2370765bbd21be2ba4a221c5 SHA512 073edd1909a92af6c4bd0951dcd2ee35b71bcbdc57ae57eabd8f5cb53fd136c00d88990aef78d0c61f1d31ff0a50094e7c7834feeabc116d8e3e39f3d484a61b
+DIST cinnamon-session-5.6.0.tar.gz 199389 BLAKE2B ecd8152af4784affc8c9b8ae7ca48adaecca4355c2db5d64ca577f44abc0ff35cf27ef324fa9d3520c125bc979727bbab67f99209e5a641ad0329a26025698b5 SHA512 260acb2a4e7016af3be2865d51eb947774020fc4e333e6a4ce72664d182c098f663d1878ac2194607f04517c3ea6916d2bfc5e55749f8252a38205b227d40335

diff --git a/gnome-extra/cinnamon-session/cinnamon-session-5.6.0.ebuild b/gnome-extra/cinnamon-session/cinnamon-session-5.6.0.ebuild
new file mode 100644
index 000000000000..2d063afc1a30
--- /dev/null
+++ b/gnome-extra/cinnamon-session/cinnamon-session-5.6.0.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{8,9,10,11} )
+
+inherit meson gnome2-utils python-any-r1 xdg-utils
+
+DESCRIPTION="Cinnamon session manager"
+HOMEPAGE="https://projects.linuxmint.com/cinnamon/ https://github.com/linuxmint/cinnamon-session"
+SRC_URI="https://github.com/linuxmint/cinnamon-session/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2+ LGPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86"
+IUSE="ipv6 systemd"
+
+DEPEND="
+	>=dev-libs/glib-2.37.3:2
+	media-libs/libcanberra[pulseaudio]
+	virtual/opengl
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf:2
+	>=x11-libs/gtk+-3:3
+	x11-libs/libICE
+	x11-libs/libSM
+	x11-libs/libX11
+	x11-libs/libXau
+	x11-libs/libXcomposite
+	x11-libs/libXext
+	x11-libs/libXrender
+	x11-libs/libXtst
+	x11-libs/pango[X]
+	>=x11-libs/xapp-2.4.1
+	x11-libs/xtrans
+
+	systemd? ( >=sys-apps/systemd-183 )
+	!systemd? ( sys-auth/elogind[policykit] )
+"
+RDEPEND="
+	${DEPEND}
+	>=gnome-extra/cinnamon-desktop-5.6:0=
+"
+BDEPEND="
+	${PYTHON_DEPS}
+	dev-util/gdbus-codegen
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	default
+	python_fix_shebang data
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use ipv6)
+		-Dxtrans=true
+	)
+	meson_src_configure
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+	gnome2_schemas_update
+}