[gentoo-commits] repo/gentoo:master commit in: games-arcade/cdogs-sdl/

["Ionen Wolkens" <ionen@gentoo.org>]

commit:     35e0736aa9d0ba1a8b3c4ce42f16aee2efa8f163
Author:     Ionen Wolkens <ionen <AT> gentoo <DOT> org>
AuthorDate: Wed Nov 16 18:45:51 2022 +0000
Commit:     Ionen Wolkens <ionen <AT> gentoo <DOT> org>
CommitDate: Wed Nov 16 18:56:31 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=35e0736a

games-arcade/cdogs-sdl: add 1.4.0

Signed-off-by: Ionen Wolkens <ionen <AT> gentoo.org>

 games-arcade/cdogs-sdl/Manifest               |  1 +
 games-arcade/cdogs-sdl/cdogs-sdl-1.4.0.ebuild | 47 +++++++++++++++++++++++++++
 2 files changed, 48 insertions(+)

diff --git a/games-arcade/cdogs-sdl/Manifest b/games-arcade/cdogs-sdl/Manifest
index 3d6382988cad..42765e12d518 100644
--- a/games-arcade/cdogs-sdl/Manifest
+++ b/games-arcade/cdogs-sdl/Manifest
@@ -1 +1,2 @@
 DIST cdogs-sdl-1.3.1.tar.gz 35202950 BLAKE2B 0f1da8a8475fec784042dc31d329361cc11266816a03e64a156362064e19a057908abf6d97cc5c7903307dae039713eeab27b87bba0764cf770cf49eaae806a1 SHA512 504736eddb6aa314072059ca76b65dcbc56c622dc217f78ca12a55a0fdf5e05b5c4cf49408d6af52d00d9cf8b7d3c2e246d7f44c98486520f31e94879e855e3e
+DIST cdogs-sdl-1.4.0.tar.gz 35203975 BLAKE2B 4966b6beacd8b0b83f6a59865a6347bea2ecabbc508317dd41bab286a25d06fe26de0e9cee0591f31c259a56c666734609ea4ce7710d820fcf446b280d6db42f SHA512 31a2802248cb4a16331181fa7c0cbc5b1cd5f85244554f5eccfeb1003a813452d08c6249521b7e9e800e48d636b0e7f8f8d592e54706bfcdf3dab88105ee0f28

diff --git a/games-arcade/cdogs-sdl/cdogs-sdl-1.4.0.ebuild b/games-arcade/cdogs-sdl/cdogs-sdl-1.4.0.ebuild
new file mode 100644
index 000000000000..3abc29134e7f
--- /dev/null
+++ b/games-arcade/cdogs-sdl/cdogs-sdl-1.4.0.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake flag-o-matic xdg
+
+DESCRIPTION="Classic overhead run-and-gun game"
+HOMEPAGE="https://cxong.github.io/cdogs-sdl/"
+SRC_URI="https://github.com/cxong/cdogs-sdl/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2+ BSD-2 CC-BY-3.0 CC-BY-4.0 CC-BY-SA-3.0 CC0-1.0 WTFPL-2 XMAME"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	media-libs/libsdl2[haptic,opengl]
+	media-libs/sdl2-image[png]
+	media-libs/sdl2-mixer[mp3,vorbis,wav]
+	net-libs/enet:1.3="
+DEPEND="${RDEPEND}"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-1.1.1-cmake.patch
+)
+
+src_configure() {
+	# LTO warnings, bug #858527
+	filter-lto
+
+	local mycmakeargs=(
+		-DCDOGS_DATA_DIR="${EPREFIX}"/usr/share/${PN}/
+		-DBUILD_EDITOR=OFF
+		-DUSE_SHARED_ENET=ON
+	)
+
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+
+	dodoc doc/{AUTHORS,original_readme.txt}
+
+	# CREDITS is used at runtime, rest is licenses or duplicates
+	find "${ED}"/usr/share/${PN}/doc -type f ! -name CREDITS -delete || die
+}