[gentoo-commits] repo/gentoo:master commit in: media-libs/libpgf/

["Viorel Munteanu" <ceamac@gentoo.org>]

commit:     de6493aaab94e73c3ea16a7c49d5241b65eeddff
Author:     Viorel Munteanu <ceamac <AT> gentoo <DOT> org>
AuthorDate: Sun Nov 13 12:02:15 2022 +0000
Commit:     Viorel Munteanu <ceamac <AT> gentoo <DOT> org>
CommitDate: Tue Nov 15 05:32:39 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=de6493aa

media-libs/libpgf: Fix installation with USE=doc

Closes: https://bugs.gentoo.org/869806
Closes: https://github.com/gentoo/gentoo/pull/28253
Signed-off-by: Viorel Munteanu <ceamac <AT> gentoo.org>

 media-libs/libpgf/libpgf-7.21.7-r1.ebuild | 55 +++++++++++++++++++++++++++++++
 1 file changed, 55 insertions(+)

diff --git a/media-libs/libpgf/libpgf-7.21.7-r1.ebuild b/media-libs/libpgf/libpgf-7.21.7-r1.ebuild
new file mode 100644
index 000000000000..a1f9328144bb
--- /dev/null
+++ b/media-libs/libpgf/libpgf-7.21.7-r1.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools edos2unix
+
+DESCRIPTION="Library to load, handle and manipulate images in the PGF format"
+HOMEPAGE="https://www.libpgf.org/"
+SRC_URI="https://downloads.sourceforge.net/project/libpgf/libpgf/${PV}/libpgf.zip -> ${P}.zip"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="doc"
+
+BDEPEND="
+	app-arch/unzip
+	doc? (
+		app-doc/doxygen
+		dev-texlive/texlive-fontutils
+	)
+"
+
+S="${WORKDIR}/libpgf"
+
+src_prepare() {
+	default
+
+	# configure.ac has wrong version number
+	sed -i "s/7.15.32/${PV}/g" configure.ac || die
+
+	# many files, including configure.ac and Makefile.am, are saved in dos format, causing errors in autotools
+	edos2unix *.{am,ac,in,sh} */*.{am,in}
+
+	# the package does not respect --docdir and installs docs in /usr/share/doc/${PN}
+	sed -i -e 's/\$(DOC_DIR)/$(DESTDIR)@docdir@/' doc/Makefile.am || die
+
+	if ! use doc; then
+		sed -i -e "/HAS_DOXYGEN/{N;N;d}" Makefile.am || die
+	fi
+
+	eautoreconf
+}
+
+src_install() {
+	default
+
+	if use doc; then
+		docinto pdf
+		dodoc doc/*.pdf doc/latex/*.pdf
+	fi
+
+	find "${ED}" -name '*.la' -delete || die
+}