[gentoo-commits] repo/gentoo:master commit in: net-dialup/accel-ppp/

["Sergey Popov" <pinkbyte@gentoo.org>]

commit:     80eb7853b6469f332b15795a354dcdfa62de0a55
Author:     Sergey Popov <pinkbyte <AT> gentoo <DOT> org>
AuthorDate: Sun Oct 30 13:08:50 2022 +0000
Commit:     Sergey Popov <pinkbyte <AT> gentoo <DOT> org>
CommitDate: Sun Oct 30 13:08:50 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=80eb7853

net-dialup/accel-ppp: version bump

Signed-off-by: Sergey Popov <pinkbyte <AT> gentoo.org>

 net-dialup/accel-ppp/Manifest                      |   1 +
 .../accel-ppp/accel-ppp-1.12.0_p20220830.ebuild    | 113 +++++++++++++++++++++
 2 files changed, 114 insertions(+)

diff --git a/net-dialup/accel-ppp/Manifest b/net-dialup/accel-ppp/Manifest
index bf502e82b4ff..6e5de43cd274 100644
--- a/net-dialup/accel-ppp/Manifest
+++ b/net-dialup/accel-ppp/Manifest
@@ -1 +1,2 @@
 DIST accel-ppp-1.12.0_p20210430.tar.bz2 1662172 BLAKE2B 7c9da06ca704d63afb16bc8d2bc64541e25d31a062a948c3014f340684a38c7ba55d15eba3458ced90b088788228f97553105fd5d0aebbb1e61fb1b1075ae521 SHA512 de690a44ebaad31c63ec604c306e3d5bc63bd02ea2c17a435c2166ddcc8a3c06b86d72d6ebd88d906093583345962569493231e1657f222d4e66d93bf1d0ca41
+DIST accel-ppp-1.12.0_p20220830.tar.bz2 1667889 BLAKE2B a6432e29953214202dc67822f358c12ade36eda3e1aaa24e8a2f427ac00ae8192216c76620f3c2946bcf88c95f6167ae9c27ce4a1895c36232110cd73c575a36 SHA512 f6e0baf7dcbf66d3d9eadffeb33216d73d6aa9eef461487d51a3811f042229b38bfec5f192742eb51cc7cfedd0a64ad02a3431bfac91ae37a9aab8c910fdcfa4

diff --git a/net-dialup/accel-ppp/accel-ppp-1.12.0_p20220830.ebuild b/net-dialup/accel-ppp/accel-ppp-1.12.0_p20220830.ebuild
new file mode 100644
index 000000000000..8ea237aff3e1
--- /dev/null
+++ b/net-dialup/accel-ppp/accel-ppp-1.12.0_p20220830.ebuild
@@ -0,0 +1,113 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+LUA_COMPAT=( lua5-1 )
+
+inherit cmake flag-o-matic linux-info linux-mod lua-single
+
+DESCRIPTION="High performance PPTP, PPPoE and L2TP server"
+HOMEPAGE="https://sourceforge.net/projects/accel-ppp/"
+SRC_URI="https://dev.gentoo.org/~pinkbyte/distfiles/snapshots/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="debug doc ipoe libtomcrypt lua postgres radius shaper snmp valgrind"
+
+RDEPEND="!libtomcrypt? ( dev-libs/openssl:0= )
+	libtomcrypt? ( dev-libs/libtomcrypt:0= )
+	lua? ( ${LUA_DEPS} )
+	postgres? ( dev-db/postgresql:* )
+	snmp? ( net-analyzer/net-snmp )
+	dev-libs/libpcre"
+DEPEND="${RDEPEND}
+	valgrind? ( dev-util/valgrind )"
+PDEPEND="net-dialup/ppp-scripts"
+
+DOCS=( README )
+
+CONFIG_CHECK="~L2TP ~PPPOE ~PPTP"
+
+REQUIRED_USE="lua? ( ${LUA_REQUIRED_USE} )
+	valgrind? ( debug )"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-1.11.1-socklen.patch"
+)
+
+S="${WORKDIR}"
+
+pkg_setup() {
+	if use ipoe; then
+		linux-mod_pkg_setup
+		set_arch_to_kernel
+	else
+		linux-info_pkg_setup
+	fi
+	use lua && lua-single_pkg_setup
+}
+
+src_prepare() {
+	sed -i  -e "/mkdir/d" \
+		-e "s: RENAME accel-ppp.conf.dist::" accel-pppd/CMakeLists.txt || die 'sed on accel-pppd/CMakeLists.txt failed'
+
+	# Do not install kernel modules like that - breaks sandbox!
+	sed -i -e '/modules_install/d' \
+		drivers/ipoe/CMakeLists.txt \
+		drivers/vlan_mon/CMakeLists.txt || die
+
+	# Fix version
+	sed -i -e "s/1.11/${PV}/" drivers/ipoe/ipoe.c || die
+	sed -i -e "s/1.11/${PV}/" drivers/vlan_mon/vlan_mon.c || die
+
+	# Bug #549918
+	append-ldflags -Wl,-z,lazy
+
+	cmake_src_prepare
+}
+
+src_configure() {
+	local libdir="$(get_libdir)"
+	local mycmakeargs=(
+		-DLIB_SUFFIX="${libdir#lib}"
+		-DBUILD_IPOE_DRIVER="$(usex ipoe)"
+		-DBUILD_PPTP_DRIVER=no
+		-DBUILD_VLAN_MON_DRIVER="$(usex ipoe)"
+		-DCRYPTO="$(usex libtomcrypt TOMCRYPT OPENSSL)"
+		-DLOG_PGSQL="$(usex postgres)"
+		-DLUA="$(usex lua TRUE FALSE)"
+		-DMEMDEBUG="$(usex debug)"
+		-DNETSNMP="$(usex snmp)"
+		-DRADIUS="$(usex radius)"
+		-DSHAPER="$(usex shaper)"
+		$(use debug && echo "-DVALGRIND=$(usex valgrind)")
+	)
+	cmake_src_configure
+}
+
+src_compile() {
+	cmake_src_compile
+}
+
+src_install() {
+	if use ipoe; then
+		local MODULE_NAMES="ipoe(accel-ppp:${BUILD_DIR}/drivers/ipoe/driver) vlan_mon(accel-ppp:${BUILD_DIR}/drivers/vlan_mon/driver)"
+		linux-mod_src_install
+	fi
+
+	cmake_src_install
+
+	use doc && dodoc -r rfc
+
+	if use snmp; then
+		insinto /usr/share/snmp/mibs
+		doins accel-pppd/extra/net-snmp/ACCEL-PPP-MIB.txt
+	fi
+
+	newinitd "${FILESDIR}"/${PN}.initd ${PN}d
+	newconfd "${FILESDIR}"/${PN}.confd ${PN}d
+
+	keepdir /var/log/accel-ppp
+}