[gentoo-commits] repo/gentoo:master commit in: dev-python/automat/

["Michał Górny" <mgorny@gentoo.org>]

commit:     c161be7310e96239e5e245bdfc8b0728d32ad221
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Sun Oct 30 06:21:04 2022 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Sun Oct 30 06:39:05 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=c161be73

dev-python/automat: Bump to 22.10.0

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/automat/Manifest               |  1 +
 dev-python/automat/automat-22.10.0.ebuild | 52 +++++++++++++++++++++++++++++++
 2 files changed, 53 insertions(+)

diff --git a/dev-python/automat/Manifest b/dev-python/automat/Manifest
index ea4495e7655a..9420d3191849 100644
--- a/dev-python/automat/Manifest
+++ b/dev-python/automat/Manifest
@@ -1 +1,2 @@
 DIST Automat-20.2.0.tar.gz 61679 BLAKE2B 9dfb93a0bf0a348d8f7de0796b3e5715947eb84cc0aa507a453f438d2027ae877280ed6d7896192cee46f31c7d1c0eb6cb3dee36e1f13a315071513920c5b6d0 SHA512 715cb5dc087288492e6465a29e7d8502a84fadf451bc3d29da86335ea1c20f8efd9549f0c1eaac8800559dd8001dd73736c3bfacdc6321c83a35d2288d69632c
+DIST Automat-22.10.0.tar.gz 59099 BLAKE2B 509e64b1312f87f09a60243a00b832c8b3da4b09ef75151e82c8c406faabd24a56378baade87bd98685fa22922d1892ec20d81579eaf13e0315af68bb7909ac4 SHA512 5819cfe0687bf391949891562f3657f449cf9a8e8ea90c1537e89509dc618da1160856f92ab52dc450e0a7d51d0e4644bfe2db3d4108126a42ee1bea2f06bb7a

diff --git a/dev-python/automat/automat-22.10.0.ebuild b/dev-python/automat/automat-22.10.0.ebuild
new file mode 100644
index 000000000000..92b6538ddb0f
--- /dev/null
+++ b/dev-python/automat/automat-22.10.0.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..11} pypy3 )
+
+inherit distutils-r1
+
+MY_P=${P^}
+DESCRIPTION="Self-service finite-state machines for the programmer on the go"
+HOMEPAGE="
+	https://github.com/glyph/automat/
+	https://pypi.org/project/Automat/
+"
+SRC_URI="mirror://pypi/${MY_P::1}/${PN^}/${MY_P}.tar.gz"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~x64-macos"
+IUSE="examples"
+
+RDEPEND="
+	>=dev-python/attrs-19.2.0[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/setuptools_scm[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests pytest
+
+EPYTEST_IGNORE=(
+	benchmark
+)
+
+python_install_all() {
+	if use examples; then
+		docinto examples
+		dodoc docs/examples/*.py
+	fi
+
+	distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+	einfo "For additional visualization functionality install both these optional dependencies"
+	einfo "    >=dev-python/twisted-16.1.1"
+	einfo "    media-gfx/graphviz[python]"
+}