[gentoo-commits] repo/gentoo:master commit in: dev-lang/swig/

["Sam James" <sam@gentoo.org>]

commit:     1efa03e16371bee79207072b135485ae7e8cdad4
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Tue Oct 25 10:43:42 2022 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Tue Oct 25 10:43:53 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=1efa03e1

dev-lang/swig: add 4.1.0

Signed-off-by: Sam James <sam <AT> gentoo.org>

 dev-lang/swig/Manifest          |  1 +
 dev-lang/swig/swig-4.1.0.ebuild | 46 +++++++++++++++++++++++++++++++++++++++++
 2 files changed, 47 insertions(+)

diff --git a/dev-lang/swig/Manifest b/dev-lang/swig/Manifest
index 1abdded45bbd..761ed475304f 100644
--- a/dev-lang/swig/Manifest
+++ b/dev-lang/swig/Manifest
@@ -1 +1,2 @@
 DIST swig-4.0.2.tar.gz 8097014 BLAKE2B 4c36b7e9b9bf1663779aa31b0eda8a1fe443695d945bcc1642c3404b22e45440def85e58dd65dc18a2ca8c00ffdcfe0f1d75373b7becc0b0e5402fda90b8c29a SHA512 05e7da70ce6d9a733b96c0bcfa3c1b82765bd859f48c74759bbf4bb1467acb1809caa310cba5e2b3280cd704fca249eaa0624821dffae1d2a75097c7f55d14ed
+DIST swig-4.1.0.tar.gz 8600226 BLAKE2B 6e10c04251153bd7300145877e6f078f7cb30d0cd18642f9094574da5f0e9cc59e40b4c8a1bf17523dc5acfd112e45297c7ada00b445d2e7696a137f48664bc3 SHA512 a7d43d6aa764923826786081a3f2e25aa0f8345e1169c1e57bf02d01f6f41c92d8db0f360ec86e0e428ef5a21d1b5cd3edb7e4b71d0beff3e6611e344b5c22b1

diff --git a/dev-lang/swig/swig-4.1.0.ebuild b/dev-lang/swig/swig-4.1.0.ebuild
new file mode 100644
index 000000000000..a87f2a77cd6a
--- /dev/null
+++ b/dev-lang/swig/swig-4.1.0.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit toolchain-funcs
+
+DESCRIPTION="Simplified Wrapper and Interface Generator"
+HOMEPAGE="http://www.swig.org/ https://github.com/swig/swig"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-3+ BSD BSD-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-cygwin ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
+IUSE="ccache doc pcre"
+#RESTRICT="test"
+
+RDEPEND="
+	pcre? ( dev-libs/libpcre2 )
+	ccache? ( sys-libs/zlib )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+DOCS=( ANNOUNCE CHANGES CHANGES.current README TODO )
+
+src_configure() {
+	econf \
+		PKGCONFIG="$(tc-getPKG_CONFIG)" \
+		$(use_enable ccache) \
+		$(use_with pcre)
+}
+
+src_test() {
+	# The tests won't get run w/o an explicit call, broken Makefiles?
+	emake check
+}
+
+src_install() {
+	default
+
+	if use doc; then
+		docinto html
+		dodoc -r Doc/{Devel,Manual}
+	fi
+}