[gentoo-commits] repo/gentoo:master commit in: media-gfx/geeqie/

["Bernard Cafarelli" <voyageur@gentoo.org>]

commit:     ef464ab10edacff812f00f6cb4b2fecc1a70c8cb
Author:     Bernard Cafarelli <voyageur <AT> gentoo <DOT> org>
AuthorDate: Mon Oct 17 21:34:37 2022 +0000
Commit:     Bernard Cafarelli <voyageur <AT> gentoo <DOT> org>
CommitDate: Mon Oct 17 21:38:58 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=ef464ab1

media-gfx/geeqie: sync live ebuild

Signed-off-by: Bernard Cafarelli <voyageur <AT> gentoo.org>

 media-gfx/geeqie/geeqie-9999.ebuild | 103 +++++++++++++++++++++---------------
 1 file changed, 59 insertions(+), 44 deletions(-)

diff --git a/media-gfx/geeqie/geeqie-9999.ebuild b/media-gfx/geeqie/geeqie-9999.ebuild
index e97db26b4d23..2c4b54ad1991 100644
--- a/media-gfx/geeqie/geeqie-9999.ebuild
+++ b/media-gfx/geeqie/geeqie-9999.ebuild
@@ -1,10 +1,10 @@
-# Copyright 1999-2021 Gentoo Authors
+# Copyright 1999-2022 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=8
-LUA_COMPAT=( lua5-{1..3} )
+LUA_COMPAT=( lua5-{3,4} )
 
-inherit autotools git-r3 lua-single xdg
+inherit git-r3 lua-single meson optfeature xdg
 
 DESCRIPTION="A lightweight GTK image viewer forked from GQview"
 HOMEPAGE="http://www.geeqie.org"
@@ -15,80 +15,95 @@ EGIT_REPO_URI="https://github.com/BestImageViewer/geeqie.git"
 LICENSE="GPL-2"
 SLOT="0"
 KEYWORDS=""
-IUSE="debug doc exif ffmpegthumbnailer gpu-accel jpeg lcms lirc lua map nls pdf tiff xmp"
+IUSE="debug doc djvu exif ffmpegthumbnailer gpu-accel heif jpeg jpeg2k jpegxl lcms lua map pdf raw spell tiff webp xmp zip"
 
-RDEPEND="
+RDEPEND="gnome-extra/zenity
 	virtual/libintl
 	x11-libs/gtk+:3
-	doc? ( app-text/gnome-doc-utils )
+	djvu? ( app-text/djvu )
+	doc? ( app-text/yelp-tools )
+	exif? ( >=media-gfx/exiv2-0.17:=[xmp?] )
 	ffmpegthumbnailer? ( media-video/ffmpegthumbnailer )
 	gpu-accel? ( media-libs/clutter-gtk )
-	jpeg? ( virtual/jpeg:0 )
+	heif? ( >=media-libs/libheif-1.3.2 )
+	jpeg2k? ( >=media-libs/openjpeg-2.3.0:2 )
+	jpeg? ( media-libs/libjpeg-turbo:= )
+	jpegxl? ( >=media-libs/libjxl-0.3.7 )
 	lcms? ( media-libs/lcms:2 )
-	lirc? ( app-misc/lirc )
-	lua? ( ${LUA_DEPS} )
+	lua? ( ${LUA_DEPS}
+		doc? ( app-doc/doxygen ) )
 	map? ( media-libs/libchamplain:0.12 )
 	pdf? ( >=app-text/poppler-0.62[cairo] )
+	raw? ( >=media-libs/libraw-0.20 )
+	spell? ( app-text/gspell )
 	tiff? ( media-libs/tiff:0 )
-	xmp? ( >=media-gfx/exiv2-0.17:=[xmp] )
-	!xmp? ( exif? ( >=media-gfx/exiv2-0.17:= ) )"
+	webp? ( >=media-libs/libwebp-0.6.1 )
+	zip? ( >=app-arch/libarchive-3.4.0 )"
 DEPEND="${RDEPEND}"
 BDEPEND="
+	|| ( dev-util/xxdi app-editors/vim-core )
 	dev-util/glib-utils
 	dev-util/intltool
-	virtual/pkgconfig
-	nls? ( sys-devel/gettext )"
+	sys-devel/gettext
+	virtual/pkgconfig"
 
 REQUIRED_USE="lua? ( ${LUA_REQUIRED_USE} )
 	map? ( gpu-accel )"
 
+PATCHES=(
+	"${FILESDIR}/${PN}-2.0.1-allow_xxdi.patch"
+)
+
 src_prepare() {
 	default
 
-	# Remove -Werror (gcc changes may add new warnings)
-	sed -e '/CFLAGS/s/-Werror //g' -i configure.ac || die
-
-	eautoreconf
+	# Lua version
+	sed -e "s/lua5.[0-9]/${LUA_SINGLE_TARGET/-/.}/" -i meson.build || die
 }
 
 src_configure() {
-	local myeconfargs=(
-		--with-readmedir="${EPREFIX}"/usr/share/doc/${PF}
-		--enable-gtk3
-		$(use_enable debug debug-log)
-		$(use_enable ffmpegthumbnailer)
-		$(use_enable gpu-accel)
-		$(use_enable jpeg)
-		$(use_enable lcms)
-		$(use_enable lua)
-		$(use_enable lirc)
-		$(use_enable map)
-		$(use_enable nls)
-		$(use_enable pdf)
-		$(use_enable tiff)
+	local emesonargs=(
+		-Dgq_helpdir="share/doc/${PF}"
+		-Dgq_htmldir="share/doc/${PF}/html"
+		$(meson_use debug)
+		$(meson_feature zip archive)
+		$(meson_feature lcms cms)
+		$(meson_feature djvu)
+		$(meson_feature exif exiv2)
+		$(meson_feature ffmpegthumbnailer videothumbnailer)
+		$(meson_feature gpu-accel gps-map)
+		$(meson_feature heif)
+		$(meson_feature jpeg2k j2k)
+		$(meson_feature jpeg)
+		$(meson_feature jpegxl)
+		$(meson_feature raw libraw)
+		$(meson_feature lua)
+		$(meson_feature pdf)
+		$(meson_feature spell)
+		$(meson_feature tiff)
+		$(meson_feature webp)
 	)
 
-	if use exif || use xmp; then
-		myeconfargs+=( --enable-exiv2 )
-	else
-		myeconfargs+=( --disable-exiv2)
-	fi
-
-	econf "${myeconfargs[@]}"
+	meson_src_configure
 }
 
 src_install() {
-	default
+	meson_src_install
 
-	rm -f "${D}/usr/share/doc/${PF}/COPYING"
-	# Application needs access to the uncompressed file
+	# The application needs access to some uncompressed doc files.
+	docompress -x /usr/share/doc/${PF}/AUTHORS
+	docompress -x /usr/share/doc/${PF}/ChangeLog
 	docompress -x /usr/share/doc/${PF}/README.md
 }
 
 pkg_postinst() {
 	xdg_pkg_postinst
 
-	elog "Some plugins may require additional packages"
-	elog "- Image rotate plugin: media-gfx/fbida (JPEG), media-gfx/imagemagick (TIFF/PNG)"
-	elog "- RAW images plugin: media-gfx/ufraw"
+	optfeature "Camera import and tethered photography plugins" media-gfx/gphoto2
+	optfeature "Export JPEG plugin" media-gfx/exiv2
+	optfeature "Lens ID plugin" media-libs/exiftool
+	optfeature "Image crop plugin" "media-gfx/exiv2 media-libs/exiftool media-gfx/imagemagick"
+	optfeature "Image rotate plugin (JPEG)" "media-gfx/exiv2 media-gfx/fbida"
+	optfeature "Image rotate plugin (TIFF/PNG)" "media-gfx/exiv2 media-gfx/imagemagick"
+	optfeature "Print preview functionality" app-text/evince
 }