[gentoo-commits] repo/gentoo:master commit in: sys-apps/gnome-disk-utility/

["Matt Turner" <mattst88@gentoo.org>]

commit:     4d63fa67087c652028ad5a6a0a982a9c05dff008
Author:     Pascal Jäger <pascal.jaeger <AT> leimstift <DOT> de>
AuthorDate: Sat Sep 17 19:56:31 2022 +0000
Commit:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Mon Sep 19 02:13:10 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=4d63fa67

sys-apps/gnome-disk-utility: Version bump to 43.0

Closes: https://github.com/gentoo/gentoo/pull/27312
Signed-off-by: Pascal Jäger <pascal.jaeger <AT> leimstift.de>
Signed-off-by: Matt Turner <mattst88 <AT> gentoo.org>

 sys-apps/gnome-disk-utility/Manifest               |  1 +
 .../gnome-disk-utility-43.0.ebuild                 | 63 ++++++++++++++++++++++
 2 files changed, 64 insertions(+)

diff --git a/sys-apps/gnome-disk-utility/Manifest b/sys-apps/gnome-disk-utility/Manifest
index 2f58ee79e478..fb7803e4b3ac 100644
--- a/sys-apps/gnome-disk-utility/Manifest
+++ b/sys-apps/gnome-disk-utility/Manifest
@@ -1 +1,2 @@
 DIST gnome-disk-utility-42.0.tar.xz 1740332 BLAKE2B 4d05876364a475d1e16651569862fe3e9bb97549463146e69722c55922c0609069334e198eff91208448dc0baf7fcefe6bab56612e89fd7412fea42ba20549d2 SHA512 c47c37262295ba455b483a7ebe7799e92f94b97d177327817bb088cddcc3ff1f5840c3e270651287ff6a88257ec7cfcd1abe4167bf7454bbf55e145c8f1dc7c9
+DIST gnome-disk-utility-43.0.tar.xz 1752240 BLAKE2B 906183e7f61c4e9d2206fe2c99034f06a0aa3869d253587325ae18b336dffc6d8523a2f4d89c4338ed64947e73c5a24de15dfdb15a9d42d77fe51fd2321bf159 SHA512 8cb1b10fba21c90bceec9521103defe092dea9a4c89a39ae44e4d5981dd0d1958649e7a2743535f0135a3c9179cad0e0aced98dfc805e19bdec81651abcecf48

diff --git a/sys-apps/gnome-disk-utility/gnome-disk-utility-43.0.ebuild b/sys-apps/gnome-disk-utility/gnome-disk-utility-43.0.ebuild
new file mode 100644
index 000000000000..7151173932fa
--- /dev/null
+++ b/sys-apps/gnome-disk-utility/gnome-disk-utility-43.0.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit gnome.org gnome2-utils meson xdg
+
+DESCRIPTION="Disk Utility for GNOME using udisks"
+HOMEPAGE="https://wiki.gnome.org/Apps/Disks"
+
+LICENSE="GPL-2+"
+SLOT="0"
+IUSE="fat elogind gnome systemd"
+REQUIRED_USE="?? ( elogind systemd )"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~riscv ~sparc ~x86"
+
+DEPEND="
+	>=media-libs/libdvdread-4.2.0:0=
+	>=dev-libs/glib-2.31:2
+	>=x11-libs/gtk+-3.16.0:3
+	>=media-libs/libcanberra-0.1[gtk3]
+	>=gui-libs/libhandy-1.5.0:1
+	>=app-arch/xz-utils-5.0.5
+	>=x11-libs/libnotify-0.7
+	>=app-crypt/libsecret-0.7
+	>=dev-libs/libpwquality-1.0.0
+	>=sys-fs/udisks-2.7.6:2
+	elogind? ( >=sys-auth/elogind-209 )
+	systemd? ( >=sys-apps/systemd-209:0= )
+"
+RDEPEND="${DEPEND}
+	x11-themes/adwaita-icon-theme
+	fat? ( sys-fs/dosfstools )
+	gnome? ( >=gnome-base/gnome-settings-daemon-3.8 )
+"
+# libxml2 for xml-stripblanks in gresource
+BDEPEND="
+	dev-libs/libxml2:2
+	app-text/docbook-xsl-stylesheets
+	dev-libs/libxslt
+	dev-util/glib-utils
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+"
+
+src_configure() {
+	local emesonargs=(
+		-Dlogind=$(usex systemd libsystemd $(usex elogind libelogind none))
+		$(meson_use gnome gsd_plugin)
+		-Dman=true
+	)
+	meson_src_configure
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}