[gentoo-commits] proj/qt:master commit in: dev-qt/qtwebchannel/, dev-qt/qtpositioning/, dev-qt/qtbase/, dev-qt/qtwebengine/, ...

[gentoo-commits] proj/qt:master commit in: dev-qt/qtwebchannel/, dev-qt/qtpositioning/, dev-qt/qtbase/, dev-qt/qtwebengine/, ...

[Jimi Huotari]

commit:     9974490c91f5d5466f83adc9e933a6ccc41a2617
Author:     Jimi Huotari <chiitoo <AT> gentoo <DOT> org>
AuthorDate: Sun Sep 18 11:40:00 2022 +0000
Commit:     Jimi Huotari <chiitoo <AT> gentoo <DOT> org>
CommitDate: Sun Sep 18 11:54:24 2022 +0000
URL:        https://gitweb.gentoo.org/proj/qt.git/commit/?id=9974490c

dev-qt/*: add 6.4.9999

Signed-off-by: Jimi Huotari <chiitoo <AT> gentoo.org>

 dev-qt/qt5compat/qt5compat-6.4.9999.ebuild         |  18 ++
 dev-qt/qtbase/qtbase-6.4.9999.ebuild               | 178 +++++++++++++++
 dev-qt/qtdeclarative/qtdeclarative-6.4.9999.ebuild |  30 +++
 dev-qt/qtlocation/qtlocation-6.4.9999.ebuild       |  18 ++
 dev-qt/qtmultimedia/qtmultimedia-6.4.9999.ebuild   |  42 ++++
 dev-qt/qtnetworkauth/qtnetworkauth-6.4.9999.ebuild |  17 ++
 dev-qt/qtpositioning/qtpositioning-6.4.9999.ebuild |  19 ++
 dev-qt/qtquick3d/qtquick3d-6.4.9999.ebuild         |  32 +++
 .../qtquicktimeline-6.4.9999.ebuild                |  18 ++
 dev-qt/qtserialport/qtserialport-6.4.9999.ebuild   |  18 ++
 dev-qt/qtshadertools/qtshadertools-6.4.9999.ebuild |  17 ++
 dev-qt/qtsvg/qtsvg-6.4.9999.ebuild                 |  18 ++
 dev-qt/qttools/qttools-6.4.9999.ebuild             |  52 +++++
 dev-qt/qtwayland/qtwayland-6.4.9999.ebuild         |  22 ++
 dev-qt/qtwebchannel/qtwebchannel-6.4.9999.ebuild   |  19 ++
 dev-qt/qtwebengine/qtwebengine-6.4.9999.ebuild     | 242 +++++++++++++++++++++
 dev-qt/qtwebsockets/qtwebsockets-6.4.9999.ebuild   |  18 ++
 17 files changed, 778 insertions(+)

diff --git a/dev-qt/qt5compat/qt5compat-6.4.9999.ebuild b/dev-qt/qt5compat/qt5compat-6.4.9999.ebuild
new file mode 100644
index 00000000..2bf0684e
--- /dev/null
+++ b/dev-qt/qt5compat/qt5compat-6.4.9999.ebuild
@@ -0,0 +1,18 @@
+# Copyright 2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit qt6-build
+
+DESCRIPTION="Qt module containing the unsupported Qt 5 APIs"
+
+if [[ ${QT6_BUILD_TYPE} == release ]]; then
+	KEYWORDS="~amd64"
+fi
+
+DEPEND="
+	=dev-qt/qtbase-${PV}*[gui,network]
+	=dev-qt/qtdeclarative-${PV}*
+"
+RDEPEND="${DEPEND}"

diff --git a/dev-qt/qtbase/qtbase-6.4.9999.ebuild b/dev-qt/qtbase/qtbase-6.4.9999.ebuild
new file mode 100644
index 00000000..36931e0e
--- /dev/null
+++ b/dev-qt/qtbase/qtbase-6.4.9999.ebuild
@@ -0,0 +1,178 @@
+# Copyright 2021-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit qt6-build
+
+DESCRIPTION="Cross-platform application development framework"
+
+if [[ ${QT6_BUILD_TYPE} == release ]]; then
+	KEYWORDS="~amd64"
+fi
+
+# Qt Modules
+# TODO: Restore/patch xml flag support (seems fixed in 6.9999).
+IUSE="+concurrent +dbus +gui +network +sql opengl +widgets zstd"
+REQUIRED_USE="
+	opengl? ( gui )
+	widgets? ( gui )
+	X? ( || ( evdev libinput ) )
+"
+
+QTGUI_IUSE="accessibility egl eglfs evdev gles2-only +jpeg +libinput tslib tuio vulkan +X"
+QTNETWORK_IUSE="brotli gssapi libproxy sctp +ssl vnc"
+QTSQL_IUSE="freetds mysql oci8 odbc postgres +sqlite"
+IUSE+=" ${QTGUI_IUSE} ${QTNETWORK_IUSE} ${QTSQL_IUSE} cups gtk icu systemd +udev"
+# QtPrintSupport = QtGui + QtWidgets enabled.
+# ibus = xkbcommon + dbus, and xkbcommon needs either libinput or X
+REQUIRED_USE+="
+	$(printf '%s? ( gui ) ' ${QTGUI_IUSE//+/})
+	$(printf '%s? ( network ) ' ${QTNETWORK_IUSE//+/})
+	$(printf '%s? ( sql ) ' ${QTSQL_IUSE//+/})
+	accessibility? ( dbus X )
+	cups? ( gui widgets )
+	eglfs? ( egl )
+	gtk? ( widgets )
+	gui? ( || ( eglfs X ) || ( libinput X ) )
+	libinput? ( udev )
+	sql? ( || ( freetds mysql oci8 odbc postgres sqlite ) )
+	vnc? ( gui )
+	X? ( gles2-only? ( egl ) )
+"
+
+# TODO:
+# qtimageformats: mng not done yet, qtimageformats.git upstream commit 9443239c
+# qtnetwork: connman, networkmanager
+DEPEND="
+	app-crypt/libb2
+	dev-libs/double-conversion:=
+	dev-libs/glib:2
+	dev-libs/libpcre2:=[pcre16,unicode]
+	dev-util/gtk-update-icon-cache
+	media-libs/fontconfig
+	>=media-libs/freetype-2.6.1:2
+	>=media-libs/harfbuzz-1.6.0:=
+	media-libs/tiff:0
+	>=sys-apps/dbus-1.4.20
+	sys-libs/zlib:=
+	brotli? ( app-arch/brotli:= )
+	evdev? ( sys-libs/mtdev )
+	freetds? ( dev-db/freetds )
+	gles2-only? ( media-libs/libglvnd )
+	!gles2-only? ( media-libs/libglvnd[X] )
+	gssapi? ( virtual/krb5 )
+	gtk? (
+		x11-libs/gtk+:3
+		x11-libs/libX11
+		x11-libs/pango
+	)
+	gui? ( media-libs/libpng:0= )
+	icu? ( dev-libs/icu:= )
+	!icu? ( virtual/libiconv )
+	jpeg? ( media-libs/libjpeg-turbo:= )
+	libinput? (
+		dev-libs/libinput:=
+		>=x11-libs/libxkbcommon-0.5.0
+	)
+	libproxy? ( net-libs/libproxy )
+	mysql? ( dev-db/mysql-connector-c:= )
+	oci8? ( dev-db/oracle-instantclient:=[sdk] )
+	odbc? ( dev-db/unixODBC )
+	postgres? ( dev-db/postgresql:* )
+	sctp? ( kernel_linux? ( net-misc/lksctp-tools ) )
+	sqlite? ( dev-db/sqlite:3 )
+	ssl? ( dev-libs/openssl:= )
+	systemd? ( sys-apps/systemd:= )
+	tslib? ( >=x11-libs/tslib-1.21 )
+	udev? ( virtual/libudev:= )
+	vulkan? ( dev-util/vulkan-headers )
+	X? (
+		x11-libs/libdrm
+		x11-libs/libICE
+		x11-libs/libSM
+		x11-libs/libX11
+		>=x11-libs/libxcb-1.12:=[xkb]
+		>=x11-libs/libxkbcommon-0.5.0[X]
+		x11-libs/xcb-util-image
+		x11-libs/xcb-util-keysyms
+		x11-libs/xcb-util-renderutil
+		x11-libs/xcb-util-wm
+	)
+	zstd? ( app-arch/zstd:= )
+"
+RDEPEND="${DEPEND}"
+
+src_configure() {
+	local mycmakeargs=(
+		-DINSTALL_BINDIR=${QT6_BINDIR}
+		-DINSTALL_INCLUDEDIR=${QT6_HEADERDIR}
+		-DINSTALL_LIBDIR=${QT6_LIBDIR}
+		-DINSTALL_ARCHDATADIR=${QT6_ARCHDATADIR}
+		-DINSTALL_PLUGINSDIR=${QT6_PLUGINDIR}
+		-DINSTALL_LIBEXECDIR=${QT6_LIBEXECDIR}
+		-DINSTALL_QMLDIR=${QT6_QMLDIR}
+		-DINSTALL_DATADIR=${QT6_DATADIR}
+		-DINSTALL_DOCDIR=${QT6_DOCDIR}
+		-DINSTALL_TRANSLATIONSDIR=${QT6_TRANSLATIONDIR}
+		-DINSTALL_SYSCONFDIR=${QT6_SYSCONFDIR}
+		-DINSTALL_MKSPECSDIR=${QT6_ARCHDATADIR}/mkspecs
+		-DINSTALL_EXAMPLESDIR=${QT6_EXAMPLESDIR}
+		-DQT_FEATURE_androiddeployqt=OFF
+		$(qt_feature concurrent)
+		$(qt_feature dbus)
+		$(qt_feature gui)
+		$(qt_feature gui testlib)
+		$(qt_feature icu)
+		$(qt_feature network)
+		$(qt_feature sql)
+		$(qt_feature systemd journald)
+		$(qt_feature udev libudev)
+		$(qt_feature zstd)
+	)
+	use gui && mycmakeargs+=(
+		$(qt_feature accessibility accessibility_atspi_bridge)
+		$(qt_feature egl)
+		$(qt_feature eglfs eglfs_egldevice)
+		$(qt_feature eglfs eglfs_gbm)
+		$(qt_feature evdev)
+		$(qt_feature evdev mtdev)
+		-DQT_FEATURE_gif=ON
+		$(qt_feature jpeg)
+		$(qt_feature opengl)
+		$(qt_feature gles2-only opengles2)
+		$(qt_feature libinput)
+		$(qt_feature tslib)
+		$(qt_feature tuio tuiotouch)
+		$(qt_feature vulkan)
+		$(qt_feature widgets)
+		$(qt_feature X xcb)
+		$(qt_feature X xcb_xlib)
+	)
+	use widgets && mycmakeargs+=(
+		$(qt_feature cups)
+		$(qt_feature gtk gtk3)
+	)
+	if use libinput || use X; then
+		mycmakeargs+=( -DQT_FEATURE_xkbcommon=ON )
+	fi
+	use network && mycmakeargs+=(
+		$(qt_feature brotli)
+		$(qt_feature gssapi)
+		$(qt_feature libproxy)
+		$(qt_feature sctp)
+		$(qt_feature ssl openssl)
+		$(qt_feature vnc)
+	)
+	use sql && mycmakeargs+=(
+		$(qt_feature freetds sql_tds)
+		$(qt_feature mysql sql_mysql)
+		$(qt_feature oci8 sql_oci)
+		$(qt_feature odbc sql_odbc)
+		$(qt_feature postgres sql_psql)
+		$(qt_feature sqlite sql_sqlite)
+		$(qt_feature sqlite system_sqlite)
+	)
+
+	qt6-build_src_configure
+}

diff --git a/dev-qt/qtdeclarative/qtdeclarative-6.4.9999.ebuild b/dev-qt/qtdeclarative/qtdeclarative-6.4.9999.ebuild
new file mode 100644
index 00000000..e8ac7edd
--- /dev/null
+++ b/dev-qt/qtdeclarative/qtdeclarative-6.4.9999.ebuild
@@ -0,0 +1,30 @@
+# Copyright 2021-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit qt6-build
+
+DESCRIPTION="Qt Declarative (Quick 2)"
+
+if [[ ${QT6_BUILD_TYPE} == release ]]; then
+	KEYWORDS="~amd64"
+fi
+
+IUSE="opengl +sql +widgets"
+
+DEPEND="
+	=dev-qt/qtbase-${PV}*[network,opengl=,sql=,widgets=]
+	=dev-qt/qtshadertools-${PV}*
+"
+RDEPEND="${DEPEND}"
+
+src_configure() {
+	local mycmakeargs=(
+		$(qt_feature opengl)
+		$(qt_feature sql)
+		$(qt_feature widgets)
+	)
+
+	qt6-build_src_configure
+}

diff --git a/dev-qt/qtlocation/qtlocation-6.4.9999.ebuild b/dev-qt/qtlocation/qtlocation-6.4.9999.ebuild
new file mode 100644
index 00000000..5bfb8228
--- /dev/null
+++ b/dev-qt/qtlocation/qtlocation-6.4.9999.ebuild
@@ -0,0 +1,18 @@
+# Copyright 2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit qt6-build
+
+DESCRIPTION="Location (places, maps, navigation) library for the Qt6 framework"
+
+if [[ ${QT6_BUILD_TYPE} == release ]]; then
+	KEYWORDS="~amd64"
+fi
+
+DEPEND="
+	=dev-qt/qtbase-${PV}*
+	=dev-qt/qtdeclarative-${PV}*
+"
+RDEPEND="${DEPEND}"

diff --git a/dev-qt/qtmultimedia/qtmultimedia-6.4.9999.ebuild b/dev-qt/qtmultimedia/qtmultimedia-6.4.9999.ebuild
new file mode 100644
index 00000000..508673ac
--- /dev/null
+++ b/dev-qt/qtmultimedia/qtmultimedia-6.4.9999.ebuild
@@ -0,0 +1,42 @@
+# Copyright 2021-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit qt6-build
+
+DESCRIPTION="Qt Multimedia"
+
+if [[ ${QT6_BUILD_TYPE} == release ]]; then
+	KEYWORDS="~amd64"
+fi
+
+IUSE="gstreamer"
+
+RDEPEND="
+	=dev-qt/qtbase-${PV}*[gui,network,widgets]
+	=dev-qt/qtdeclarative-${PV}*
+	=dev-qt/qtshadertools-${PV}*
+	=dev-qt/qtsvg-${PV}*
+	gstreamer? (
+		dev-libs/glib:2
+		media-libs/gstreamer:1.0
+		media-libs/gst-plugins-bad:1.0
+		media-libs/gst-plugins-base:1.0
+		media-libs/libglvnd
+	)
+"
+DEPEND="${RDEPEND}
+	gstreamer? ( x11-base/xorg-proto )
+"
+
+src_configure() {
+	# TODO: linux_v4l automagic
+	local mycmakeargs=(
+		-DQT_FEATURE_alsa=off
+		-DQT_FEATURE_pulseaudio=off
+		$(qt_feature gstreamer)
+	)
+
+	qt6-build_src_configure
+}

diff --git a/dev-qt/qtnetworkauth/qtnetworkauth-6.4.9999.ebuild b/dev-qt/qtnetworkauth/qtnetworkauth-6.4.9999.ebuild
new file mode 100644
index 00000000..ed8b23db
--- /dev/null
+++ b/dev-qt/qtnetworkauth/qtnetworkauth-6.4.9999.ebuild
@@ -0,0 +1,17 @@
+# Copyright 2021-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit qt6-build
+
+DESCRIPTION="Network authorization library for the Qt6 framework"
+
+if [[ ${QT6_BUILD_TYPE} == release ]]; then
+	KEYWORDS="~amd64"
+fi
+
+DEPEND="
+	=dev-qt/qtbase-${PV}*[network,widgets]
+"
+RDEPEND="${DEPEND}"

diff --git a/dev-qt/qtpositioning/qtpositioning-6.4.9999.ebuild b/dev-qt/qtpositioning/qtpositioning-6.4.9999.ebuild
new file mode 100644
index 00000000..7be915ff
--- /dev/null
+++ b/dev-qt/qtpositioning/qtpositioning-6.4.9999.ebuild
@@ -0,0 +1,19 @@
+# Copyright 2021-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit qt6-build
+
+DESCRIPTION="Physical position determination library for the Qt6 framework"
+
+if [[ ${QT6_BUILD_TYPE} == release ]]; then
+	KEYWORDS="~amd64"
+fi
+
+DEPEND="
+	=dev-qt/qtbase-${PV}*[dbus,gui,widgets]
+	=dev-qt/qtdeclarative-${PV}*
+	=dev-qt/qtserialport-${PV}*
+"
+RDEPEND="${DEPEND}"

diff --git a/dev-qt/qtquick3d/qtquick3d-6.4.9999.ebuild b/dev-qt/qtquick3d/qtquick3d-6.4.9999.ebuild
new file mode 100644
index 00000000..6eb36dee
--- /dev/null
+++ b/dev-qt/qtquick3d/qtquick3d-6.4.9999.ebuild
@@ -0,0 +1,32 @@
+# Copyright 2021-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit qt6-build
+
+DESCRIPTION="Qt module and API for defining 3D content in Qt QuickTools"
+
+if [[ ${QT6_BUILD_TYPE} == release ]]; then
+	KEYWORDS="~amd64"
+elif [[ ${QT6_BUILD_TYPE} == live ]]; then
+	# Don't clone qtquick3d-assimp.
+	EGIT_SUBMODULES=()
+fi
+
+DEPEND="
+	=dev-qt/qtbase-${PV}*[concurrent,network,widgets]
+	=dev-qt/qtdeclarative-${PV}*
+	=dev-qt/qtshadertools-${PV}*
+	=dev-qt/qtquicktimeline-${PV}*
+	media-libs/assimp:=
+"
+RDEPEND="${DEPEND}"
+
+src_configure() {
+	local mycmakeargs=(
+		-DQT_FEATURE_system_assimp=ON
+	)
+
+	qt6-build_src_configure
+}

diff --git a/dev-qt/qtquicktimeline/qtquicktimeline-6.4.9999.ebuild b/dev-qt/qtquicktimeline/qtquicktimeline-6.4.9999.ebuild
new file mode 100644
index 00000000..0673606b
--- /dev/null
+++ b/dev-qt/qtquicktimeline/qtquicktimeline-6.4.9999.ebuild
@@ -0,0 +1,18 @@
+# Copyright 2021-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit qt6-build
+
+DESCRIPTION="Qt module for keyframe-based timeline construction"
+
+if [[ ${QT6_BUILD_TYPE} == release ]]; then
+	KEYWORDS="~amd64"
+fi
+
+DEPEND="
+	=dev-qt/qtbase-${PV}*
+	=dev-qt/qtdeclarative-${PV}*
+"
+RDEPEND="${DEPEND}"

diff --git a/dev-qt/qtserialport/qtserialport-6.4.9999.ebuild b/dev-qt/qtserialport/qtserialport-6.4.9999.ebuild
new file mode 100644
index 00000000..218a7f2d
--- /dev/null
+++ b/dev-qt/qtserialport/qtserialport-6.4.9999.ebuild
@@ -0,0 +1,18 @@
+# Copyright 2021-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit qt6-build
+
+DESCRIPTION="Serial port abstraction library for the Qt6 framework"
+
+if [[ ${QT6_BUILD_TYPE} == release ]]; then
+	KEYWORDS="~amd64"
+fi
+
+DEPEND="
+	=dev-qt/qtbase-${PV}*[gui,widgets]
+	virtual/libudev:=
+"
+RDEPEND="${DEPEND}"

diff --git a/dev-qt/qtshadertools/qtshadertools-6.4.9999.ebuild b/dev-qt/qtshadertools/qtshadertools-6.4.9999.ebuild
new file mode 100644
index 00000000..755d9ae0
--- /dev/null
+++ b/dev-qt/qtshadertools/qtshadertools-6.4.9999.ebuild
@@ -0,0 +1,17 @@
+# Copyright 2021-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit qt6-build
+
+DESCRIPTION="Qt APIs and Tools for Graphics Pipelines"
+
+if [[ ${QT6_BUILD_TYPE} == release ]]; then
+	KEYWORDS="~amd64"
+fi
+
+DEPEND="
+	=dev-qt/qtbase-${PV}*[gui]
+"
+RDEPEND="${DEPEND}"

diff --git a/dev-qt/qtsvg/qtsvg-6.4.9999.ebuild b/dev-qt/qtsvg/qtsvg-6.4.9999.ebuild
new file mode 100644
index 00000000..037c2eb0
--- /dev/null
+++ b/dev-qt/qtsvg/qtsvg-6.4.9999.ebuild
@@ -0,0 +1,18 @@
+# Copyright 2021-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit qt6-build
+
+DESCRIPTION="SVG rendering library for the Qt6 framework"
+
+if [[ ${QT6_BUILD_TYPE} == release ]]; then
+	KEYWORDS="~amd64"
+fi
+
+DEPEND="
+	=dev-qt/qtbase-${PV}*[gui,widgets]
+	sys-libs/zlib:=
+"
+RDEPEND="${DEPEND}"

diff --git a/dev-qt/qttools/qttools-6.4.9999.ebuild b/dev-qt/qttools/qttools-6.4.9999.ebuild
new file mode 100644
index 00000000..23e1c087
--- /dev/null
+++ b/dev-qt/qttools/qttools-6.4.9999.ebuild
@@ -0,0 +1,52 @@
+# Copyright 2021-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit qt6-build
+
+DESCRIPTION="Qt Tools Collection"
+
+if [[ ${QT6_BUILD_TYPE} == release ]]; then
+	KEYWORDS="~amd64"
+fi
+
+IUSE="
+	assistant designer distancefieldgenerator linguist pixeltool
+	qdbus qdoc qtattributionsscanner qtdiag qtplugininfo
+"
+REQUIRED_USE="linguist? ( designer )"
+
+DEPEND="
+	=dev-qt/qtbase-${PV}*[network]
+	assistant? ( =dev-qt/qtbase-${PV}*[sql,widgets] )
+	designer? ( =dev-qt/qtbase-${PV}*[widgets] )
+	distancefieldgenerator? (
+		=dev-qt/qtbase-${PV}*[widgets]
+		=dev-qt/qtdeclarative-${PV}*
+	)
+	pixeltool? ( =dev-qt/qtbase-${PV}*[widgets] )
+	qdbus? ( =dev-qt/qtbase-${PV}*[widgets] )
+	qdoc? ( sys-devel/clang:= )
+	qtdiag? ( =dev-qt/qtbase-${PV}*[opengl,widgets] )
+"
+RDEPEND="${DEPEND}"
+
+src_configure() {
+	local mycmakeargs=(
+		$(qt_feature assistant)
+		-DQT_FEATURE_commandlineparser=ON
+		$(qt_feature designer)
+		$(qt_feature distancefieldgenerator)
+		$(qt_feature linguist)
+		$(qt_feature pixeltool)
+		$(qt_feature qdbus)
+		$(qt_feature qdoc clang)
+		$(qt_feature qtattributionsscanner)
+		$(qt_feature qtdiag)
+		$(qt_feature qtplugininfo)
+		-DQT_FEATURE_thread=ON
+	)
+
+	qt6-build_src_configure
+}

diff --git a/dev-qt/qtwayland/qtwayland-6.4.9999.ebuild b/dev-qt/qtwayland/qtwayland-6.4.9999.ebuild
new file mode 100644
index 00000000..09413e55
--- /dev/null
+++ b/dev-qt/qtwayland/qtwayland-6.4.9999.ebuild
@@ -0,0 +1,22 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit qt6-build
+
+DESCRIPTION="Wayland platform plugin for Qt"
+
+if [[ ${QT6_BUILD_TYPE} == release ]]; then
+	KEYWORDS="~amd64"
+fi
+
+BDEPEND="dev-util/wayland-scanner"
+DEPEND="
+	dev-libs/wayland
+	=dev-qt/qtbase-${PV}*[gui,opengl]
+	=dev-qt/qtdeclarative-${PV}*
+	media-libs/libglvnd
+	x11-libs/libxkbcommon
+"
+RDEPEND="${DEPEND}"

diff --git a/dev-qt/qtwebchannel/qtwebchannel-6.4.9999.ebuild b/dev-qt/qtwebchannel/qtwebchannel-6.4.9999.ebuild
new file mode 100644
index 00000000..62dd2732
--- /dev/null
+++ b/dev-qt/qtwebchannel/qtwebchannel-6.4.9999.ebuild
@@ -0,0 +1,19 @@
+# Copyright 2021-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit qt6-build
+
+DESCRIPTION="Qt WebChannel"
+
+if [[ ${QT6_BUILD_TYPE} == release ]]; then
+	KEYWORDS="~amd64"
+fi
+
+DEPEND="
+	=dev-qt/qtbase-${PV}*[concurrent]
+	=dev-qt/qtdeclarative-${PV}*
+	=dev-qt/qtwebsockets-${PV}*
+"
+RDEPEND="${DEPEND}"

diff --git a/dev-qt/qtwebengine/qtwebengine-6.4.9999.ebuild b/dev-qt/qtwebengine/qtwebengine-6.4.9999.ebuild
new file mode 100644
index 00000000..22780c57
--- /dev/null
+++ b/dev-qt/qtwebengine/qtwebengine-6.4.9999.ebuild
@@ -0,0 +1,242 @@
+# Copyright 2021-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{9,10} )
+PYTHON_REQ_USE="xml(+)"
+CHROMIUM_VER="94.0.4606.126"
+CHROMIUM_PATCHES_VER="101.0.4951.64"
+
+inherit check-reqs estack flag-o-matic multiprocessing python-any-r1 qt6-build
+
+DESCRIPTION="Library for rendering dynamic web content in Qt6 C++ and QML applications"
+
+if [[ ${QT6_BUILD_TYPE} == release ]]; then
+	KEYWORDS="~amd64"
+fi
+
+IUSE="
+	alsa bindist designer geolocation +jumbo-build kerberos pipewire pulseaudio
+	+system-ffmpeg +system-icu widgets
+"
+REQUIRED_USE="designer? ( widgets )"
+
+BDEPEND="
+	$(python_gen_any_dep 'dev-python/html5lib[${PYTHON_USEDEP}]')
+	dev-util/gperf
+	dev-util/ninja
+	dev-util/re2c
+	net-libs/nodejs[ssl]
+	sys-devel/bison
+	sys-devel/flex
+"
+RDEPEND="
+	app-arch/snappy:=
+	dev-libs/glib:2
+	dev-libs/nspr
+	dev-libs/nss
+	dev-libs/expat
+	dev-libs/libevent:=
+	dev-libs/libxml2[icu]
+	dev-libs/libxslt
+	dev-libs/re2:=
+	=dev-qt/qtdeclarative-${PV}*
+	=dev-qt/qtwebchannel-${PV}*
+	media-libs/fontconfig
+	media-libs/freetype
+	media-libs/harfbuzz:=
+	media-libs/lcms:2
+	media-libs/libjpeg-turbo:=
+	media-libs/libpng:=
+	>=media-libs/libvpx-1.5:=[svc(+)]
+	media-libs/libwebp:=
+	media-libs/opus
+	sys-apps/dbus
+	sys-apps/pciutils
+	sys-libs/zlib[minizip]
+	virtual/libudev
+	x11-libs/libdrm
+	x11-libs/libX11
+	x11-libs/libXcomposite
+	x11-libs/libXcursor
+	x11-libs/libxcb:=
+	x11-libs/libXdamage
+	x11-libs/libXext
+	x11-libs/libXfixes
+	x11-libs/libXi
+	x11-libs/libxkbcommon
+	x11-libs/libxkbfile
+	x11-libs/libXrandr
+	x11-libs/libXrender
+	x11-libs/libXScrnSaver
+	x11-libs/libXtst
+	alsa? ( media-libs/alsa-lib )
+	geolocation? ( =dev-qt/qtpositioning-${PV}* )
+	kerberos? ( virtual/krb5 )
+	pipewire? ( media-video/pipewire:= )
+	pulseaudio? ( media-sound/pulseaudio:= )
+	system-ffmpeg? ( media-video/ffmpeg:= )
+	system-icu? ( >=dev-libs/icu-69.1:= )
+	widgets? (
+		=dev-qt/qtbase-${PV}*[widgets]
+	)
+"
+DEPEND="${RDEPEND}
+	media-libs/libglvnd
+"
+
+python_check_deps() {
+	python_has_version "dev-python/html5lib[${PYTHON_USEDEP}]"
+}
+
+qtwebengine_check-reqs() {
+	# bug #307861
+	eshopts_push -s extglob
+	if is-flagq '-g?(gdb)?([1-9])'; then
+		ewarn "You have enabled debug info (probably have -g or -ggdb in your CFLAGS/CXXFLAGS)."
+		ewarn "You may experience really long compilation times and/or increased memory usage."
+		ewarn "If compilation fails, please try removing -g/-ggdb before reporting a bug."
+	fi
+	eshopts_pop
+
+	[[ ${MERGE_TYPE} == binary ]] && return
+
+	# (check-reqs added for bug #570534)
+	#
+	# Estimate the amount of RAM required
+	# Multiplier is *10 because Bash doesn't do floating point maths.
+	# Let's crudely assume ~2GB per compiler job for GCC.
+	local multiplier=20
+
+	# And call it ~1.5GB for Clang.
+	if tc-is-clang ; then
+		multiplier=15
+	fi
+
+	local CHECKREQS_DISK_BUILD="7G"
+	local CHECKREQS_DISK_USR="150M"
+	if ! has "distcc" ${FEATURES} ; then
+		# bug #830661
+		# Not super realistic to come up with good estimates for distcc right now
+		local CHECKREQS_MEMORY=$(($(makeopts_jobs)*multiplier/10))G
+	fi
+
+	check-reqs_${EBUILD_PHASE_FUNC}
+}
+
+pkg_pretend() {
+	qtwebengine_check-reqs
+}
+
+pkg_setup() {
+	qtwebengine_check-reqs
+	python-any-r1_pkg_setup
+}
+
+pkg_preinst() {
+	elog "This version of Qt WebEngine is based on Chromium version ${CHROMIUM_VER}, with"
+	elog "additional security fixes up to ${CHROMIUM_PATCHES_VER}. Extensive as it is, the"
+	elog "list of backports is impossible to evaluate, but always bound to be behind"
+	elog "Chromium's release schedule."
+	elog "In addition, various online services may deny service based on an outdated"
+	elog "user agent version (and/or other checks). Google is already known to do so."
+	elog
+	elog "tldr: Your web browsing experience will be compromised."
+}
+
+src_unpack() {
+	# bug 307861
+	eshopts_push -s extglob
+	if is-flagq '-g?(gdb)?([1-9])'; then
+		ewarn
+		ewarn "You have enabled debug info (probably have -g or -ggdb in your CFLAGS/CXXFLAGS)."
+		ewarn "You may experience really long compilation times and/or increased memory usage."
+		ewarn "If compilation fails, please try removing -g/-ggdb before reporting a bug."
+		ewarn
+	fi
+	eshopts_pop
+
+	case ${QT6_BUILD_TYPE} in
+		live)    git-r3_src_unpack ;&
+		release) default ;;
+	esac
+}
+
+src_prepare() {
+	# bug 620444 - ensure local headers are used
+	find . -type f -name "*.pr[fio]" -exec \
+		sed -i -e 's|INCLUDEPATH += |&$${QTWEBENGINE_ROOT}_build/include $${QTWEBENGINE_ROOT}/include |' {} + || die
+
+	if use system-icu; then
+		# Sanity check to ensure that bundled copy of ICU is not used.
+		# Whole src/3rdparty/chromium/third_party/icu directory cannot be deleted because
+		# src/3rdparty/chromium/third_party/icu/BUILD.gn is used by build system.
+		# If usage of headers of bundled copy of ICU occurs, then lists of shim headers in
+		# shim_headers("icui18n_shim") and shim_headers("icuuc_shim") in
+		# src/3rdparty/chromium/third_party/icu/BUILD.gn should be updated.
+		local file
+		while read file; do
+			echo "#error This file should not be used!" > "${file}" || die
+		done < <(find src/3rdparty/chromium/third_party/icu -type f "(" -name "*.c" -o -name "*.cpp" -o -name "*.h" ")" 2>/dev/null)
+	fi
+
+	qt6-build_src_prepare
+}
+
+src_configure() {
+	export NINJA_PATH="${BROOT}"/usr/bin/ninja
+	export NINJAFLAGS="${NINJAFLAGS:--j$(makeopts_jobs) -l$(makeopts_loadavg "${MAKEOPTS}" 0) -v}"
+
+	local mycmakeargs=(
+		#-DQT_FEATURE_accessibility=off
+		#-DQT_FEATURE_force_asserts=off
+		#-DQT_FEATURE_opengl=off
+		#-DQT_FEATURE_printer=off
+		-DQT_FEATURE_qtpdf_build=off
+		-DQT_FEATURE_qtpdf_quick_build=off
+		-DQT_FEATURE_qtpdf_widgets_build=off
+		-DQT_FEATURE_qtwebengine_build=on
+		-DQT_FEATURE_qtwebengine_quick_build=on
+		-DQT_FEATURE_qtwebengine_widgets_build=on
+		#-DQT_FEATURE_ssl=off
+		#-DQT_FEATURE_static=off
+		#-DQT_FEATURE_system_zlib=off
+		#-DQT_FEATURE_system_png=off
+		#-DQT_FEATURE_system_jpeg=off
+		#-DQT_FEATURE_system_freetype=off
+		#-DQT_FEATURE_system_harfbuzz=off
+		#-DQT_FEATURE_use_gold_linker=off
+		#-DQT_FEATURE_use_lld_linker=off
+		-DQT_FEATURE_webengine_embedded_build=off
+		-DQT_FEATURE_webengine_extensions=on
+		#-DQT_FEATURE_webengine_full_debug_info=$(usex debug)
+		-DQT_FEATURE_webengine_geolocation=$(usex geolocation on off)
+		-DQT_FEATURE_webengine_jumbo_build=$(usex jumbo-build)
+		#-DQT_FEATURE_webengine_jumbo_file_merge_limit
+		-DQT_FEATURE_webengine_kerberos=$(usex kerberos on off)
+		-DQT_FEATURE_webengine_native_spellchecker=off
+		-DQT_FEATURE_webengine_ozone_x11=on
+		-DQT_FEATURE_webengine_pepper_plugins=on
+		-DQT_FEATURE_webengine_proprietary_codecs=$(usex bindist off on)
+		-DQT_FEATURE_webengine_printing_and_pdf=on
+		-DQT_FEATURE_webengine_sanitizer=on
+		-DQT_FEATURE_webengine_spellchecker=on
+		-DQT_FEATURE_webengine_system_opus=on
+		-DQT_FEATURE_webengine_system_libwebp=on
+		-DQT_FEATURE_webengine_system_alsa=$(usex alsa on off)
+		-DQT_FEATURE_webengine_system_ffmpeg=$(usex system-ffmpeg)
+		-DQT_FEATURE_webengine_system_icu=$(usex system-icu)
+		-DQT_FEATURE_webengine_system_libevent=on
+		-DQT_FEATURE_webengine_system_libpci=on
+		-DQT_FEATURE_webengine_system_libpng=on
+		-DQT_FEATURE_webengine_system_pulseaudio=$(usex pulseaudio on off)
+		-DQT_FEATURE_webengine_system_zlib=on
+		-DQT_FEATURE_webengine_webchannel=on
+		-DQT_FEATURE_webengine_webrtc=on
+		-DQT_FEATURE_webengine_webrtc_pipewire=$(usex pipewire on off)
+		#-DQT_FEATURE_xcb=off
+	)
+
+	qt6-build_src_configure
+}

diff --git a/dev-qt/qtwebsockets/qtwebsockets-6.4.9999.ebuild b/dev-qt/qtwebsockets/qtwebsockets-6.4.9999.ebuild
new file mode 100644
index 00000000..6b0e253a
--- /dev/null
+++ b/dev-qt/qtwebsockets/qtwebsockets-6.4.9999.ebuild
@@ -0,0 +1,18 @@
+# Copyright 2021-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit qt6-build
+
+DESCRIPTION="Implementation of the WebSocket protocol for the Qt6 framework"
+
+if [[ ${QT6_BUILD_TYPE} == release ]]; then
+	KEYWORDS="~amd64"
+fi
+
+DEPEND="
+	=dev-qt/qtbase-${PV}*[network]
+	=dev-qt/qtdeclarative-${PV}*
+"
+RDEPEND="${DEPEND}"