[gentoo-commits] repo/gentoo:master commit in: app-emulation/vkd3d/

["Ionen Wolkens" <ionen@gentoo.org>]

commit:     8e35ed7a6db781eada9a4984c5ce63f8fddea6ee
Author:     Ionen Wolkens <ionen <AT> gentoo <DOT> org>
AuthorDate: Sat Sep 17 07:05:35 2022 +0000
Commit:     Ionen Wolkens <ionen <AT> gentoo <DOT> org>
CommitDate: Sat Sep 17 08:42:14 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=8e35ed7a

app-emulation/vkd3d: EAPI6->8, tidy, and update deps

Not a very useful package anymore (unless someone needs
vkd3d-compiler?), but still be in the tree for a while for
wine-7.0 and don't want to leave this deprecated EAPI=6.

This also removes static libs + .la files wrt bug #841590

Closes: https://bugs.gentoo.org/841590
Signed-off-by: Ionen Wolkens <ionen <AT> gentoo.org>

 app-emulation/vkd3d/vkd3d-1.4-r1.ebuild | 44 +++++++++++++++++++++++++++++++++
 app-emulation/vkd3d/vkd3d-1.4.ebuild    | 43 --------------------------------
 2 files changed, 44 insertions(+), 43 deletions(-)

diff --git a/app-emulation/vkd3d/vkd3d-1.4-r1.ebuild b/app-emulation/vkd3d/vkd3d-1.4-r1.ebuild
new file mode 100644
index 000000000000..5fc7999f8241
--- /dev/null
+++ b/app-emulation/vkd3d/vkd3d-1.4-r1.ebuild
@@ -0,0 +1,44 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit multilib-minimal
+
+DESCRIPTION="D3D12 to Vulkan translation library"
+HOMEPAGE="https://source.winehq.org/git/vkd3d.git/"
+SRC_URI="https://dl.winehq.org/vkd3d/source/${P}.tar.xz"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="ncurses spirv-tools"
+RESTRICT="test" #838655
+
+RDEPEND="
+	media-libs/vulkan-loader[${MULTILIB_USEDEP}]
+	ncurses? ( sys-libs/ncurses:= )
+	spirv-tools? ( dev-util/spirv-tools[${MULTILIB_USEDEP}] )"
+DEPEND="
+	${RDEPEND}
+	dev-util/spirv-headers
+	dev-util/vulkan-headers"
+BDEPEND="
+	sys-devel/flex
+	sys-devel/bison
+	virtual/pkgconfig"
+
+multilib_src_configure() {
+	local conf=(
+		$(multilib_native_use_with ncurses)
+		$(use_with spirv-tools)
+		--disable-doxygen-pdf
+		--without-xcb
+	)
+
+	ECONF_SOURCE=${S} econf "${conf[@]}"
+}
+
+multilib_src_install_all() {
+	find "${ED}" -type f -name '*.la' -delete || die
+}

diff --git a/app-emulation/vkd3d/vkd3d-1.4.ebuild b/app-emulation/vkd3d/vkd3d-1.4.ebuild
deleted file mode 100644
index e64cc1a24558..000000000000
--- a/app-emulation/vkd3d/vkd3d-1.4.ebuild
+++ /dev/null
@@ -1,43 +0,0 @@
-# Copyright 1999-2022 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=6
-
-inherit multilib-minimal
-
-if [[ "${PV}" == "9999" ]]; then
-	EGIT_REPO_URI="https://source.winehq.org/git/vkd3d.git"
-	inherit git-r3
-else
-	KEYWORDS="~amd64 ~x86"
-	SRC_URI="https://dl.winehq.org/vkd3d/source/${P}.tar.xz"
-fi
-
-#Tests fail: https://bugs.gentoo.org/838655
-RESTRICT="test"
-
-IUSE="spirv-tools"
-RDEPEND="spirv-tools? ( dev-util/spirv-tools:=[${MULTILIB_USEDEP}] )
-		media-libs/vulkan-loader[${MULTILIB_USEDEP},X]
-		x11-libs/xcb-util:=[${MULTILIB_USEDEP}]
-		x11-libs/xcb-util-keysyms:=[${MULTILIB_USEDEP}]
-		x11-libs/xcb-util-wm:=[${MULTILIB_USEDEP}]"
-
-DEPEND="${RDEPEND}
-		dev-util/spirv-headers
-		dev-util/vulkan-headers"
-
-DESCRIPTION="D3D12 to Vulkan translation library"
-HOMEPAGE="https://source.winehq.org/git/vkd3d.git/"
-
-LICENSE="LGPL-2.1"
-SLOT="0"
-
-multilib_src_configure() {
-	local myconf=(
-		$(use_with spirv-tools)
-		--disable-doxygen-pdf
-	)
-
-	ECONF_SOURCE=${S} econf "${myconf[@]}"
-}