[gentoo-commits] proj/sci:master commit in: sci-biology/ants/

["Horea Christian" <horea.christ@gmail.com>]

commit:     4d36e47773d01a0d4d91d2eee5d2701dcdebe9d0
Author:     Horea Christian <chr <AT> chymera <DOT> eu>
AuthorDate: Thu Sep 15 07:03:40 2022 +0000
Commit:     Horea Christian <horea.christ <AT> gmail <DOT> com>
CommitDate: Thu Sep 15 07:03:40 2022 +0000
URL:        https://gitweb.gentoo.org/proj/sci.git/commit/?id=4d36e477

sci-biology/ants: add 2.3.4

Signed-off-by: Horea Christian <chr <AT> chymera.eu>

 sci-biology/ants/ants-2.3.4.ebuild | 78 ++++++++++++++++++++++++++++++++++++++
 1 file changed, 78 insertions(+)

diff --git a/sci-biology/ants/ants-2.3.4.ebuild b/sci-biology/ants/ants-2.3.4.ebuild
new file mode 100644
index 000000000..95eb6355b
--- /dev/null
+++ b/sci-biology/ants/ants-2.3.4.ebuild
@@ -0,0 +1,78 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+CMAKE_MAKEFILE_GENERATOR="emake"
+
+inherit cmake
+
+MY_PN="ANTs"
+
+DESCRIPTION="Advanced Normalitazion Tools for neuroimaging"
+HOMEPAGE="http://stnava.github.io/ANTs/"
+SRC_URI="
+	https://github.com/ANTsX/ANTs/archive/v${PV}.tar.gz ->  ${P}.tar.gz
+	test? (
+		http://resources.chymera.eu/distfiles/ants_testdata-${PV}.tar.xz
+	)
+"
+
+SLOT="0"
+LICENSE="BSD"
+KEYWORDS="~amd64 ~x86"
+IUSE="test vtk"
+RESTRICT="!test? ( test )"
+
+DEPEND="
+	vtk? (
+		~sci-libs/itk-5.1.0[vtkglue]
+		sci-libs/vtk
+	)
+	!vtk? (	~sci-libs/itk-5.1.0 )
+"
+RDEPEND="${DEPEND}"
+
+PATCHES=(
+	"${FILESDIR}/${P}-version.patch"
+	"${FILESDIR}/${P}-libdir.patch"
+)
+
+S="${WORKDIR}/${MY_PN}-${PV}"
+
+src_unpack() {
+	default
+	if use test; then
+		mkdir -p "${S}/.ExternalData/MD5" || die "Could not create test data directory."
+		tar xvf "${DISTDIR}/ants_testdata-${PV}.tar.xz" -C "${S}/.ExternalData/MD5/" > /dev/null || die "Could not unpack test data."
+	fi
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DUSE_SYSTEM_ITK=ON
+		-DITK_DIR="${EPREFIX}/usr/include/ITK-5.1/"
+		-DBUILD_TESTING="$(usex test ON OFF)"
+		-DUSE_VTK=$(usex vtk ON OFF)
+		-DUSE_SYSTEM_VTK=$(usex vtk ON OFF)
+		-DANTS_SNAPSHOT_VERSION:STRING=${PV}
+	)
+	use vtk && mycmakeargs+=(
+		-DVTK_DIR="${EPREFIX}/usr/include/vtk-8.1/"
+	)
+	use test && mycmakeargs+=(
+		-DExternalData_OBJECT_STORES="${S}/.ExternalData/MD5"
+	)
+	cmake_src_configure
+}
+
+src_install() {
+	BUILD_DIR="${WORKDIR}/${P}_build/ANTS-build"
+	cmake_src_install
+	cd "${S}/Scripts" || die "scripts dir not found"
+	dobin *.sh
+	dodir /usr/$(get_libdir)/ants
+	insinto "/usr/$(get_libdir)/ants"
+	doins *
+	doenvd "${FILESDIR}"/99ants
+}