[gentoo-commits] repo/gentoo:master commit in: net-vpn/networkmanager-l2tp/

["Sam James" <sam@gentoo.org>]

commit:     5e4174f65f2a5edb087560edb406e965ca5dfba0
Author:     Alexander Kurakin <kuraga333 <AT> mail <DOT> ru>
AuthorDate: Wed Aug 10 15:26:57 2022 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Fri Aug 19 22:04:59 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=5e4174f6

net-vpn/networkmanager-l2tp: fix net-misc/networkmanager dependency

Closes: https://bugs.gentoo.org/864805
Signed-off-by: Alexander Kurakin <kuraga333 <AT> mail.ru>
Closes: https://github.com/gentoo/gentoo/pull/26811
Signed-off-by: Sam James <sam <AT> gentoo.org>

 .../networkmanager-l2tp-1.20.4-r1.ebuild           | 62 ++++++++++++++++++++++
 1 file changed, 62 insertions(+)

diff --git a/net-vpn/networkmanager-l2tp/networkmanager-l2tp-1.20.4-r1.ebuild b/net-vpn/networkmanager-l2tp/networkmanager-l2tp-1.20.4-r1.ebuild
new file mode 100644
index 000000000000..833b02cd5708
--- /dev/null
+++ b/net-vpn/networkmanager-l2tp/networkmanager-l2tp-1.20.4-r1.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+MY_PN="NetworkManager-l2tp"
+MY_P="${MY_PN}-${PV}"
+
+inherit autotools gnome.org
+
+DESCRIPTION="NetworkManager L2TP plugin"
+HOMEPAGE="https://github.com/nm-l2tp/network-manager-l2tp"
+SRC_URI="https://github.com/nm-l2tp/${MY_PN}/releases/download/${PV}/${MY_P}.tar.xz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="gnome static-libs"
+
+RDEPEND="
+	>=net-misc/networkmanager-1.20[ppp]
+	dev-libs/dbus-glib
+	net-dialup/ppp:=[eap-tls]
+	net-dialup/xl2tpd
+	>=dev-libs/glib-2.32
+	|| (
+		net-vpn/strongswan
+		net-vpn/libreswan
+	)
+	gnome? (
+		x11-libs/gtk+:3
+		app-crypt/libsecret
+		gnome-extra/nm-applet
+	)"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	sys-devel/gettext
+	dev-util/intltool
+	virtual/pkgconfig"
+
+S="${WORKDIR}/${MY_P}"
+
+src_prepare() {
+	default
+
+	eautoreconf
+}
+
+src_configure() {
+	local PPPD_VER=$(best_version net-dialup/ppp)
+	PPPD_VER=${PPPD_VER#*/*-} # reduce it to ${PV}-${PR}
+	PPPD_VER=${PPPD_VER%%[_-]*} # main version without beta/pre/patch/revision
+
+	local myeconfargs=(
+		--localstatedir=/var
+		--with-pppd-plugin-dir=/usr/$(get_libdir)/pppd/${PPPD_VER}
+		$(use_with gnome)
+		$(use_enable static-libs static)
+	)
+
+	econf "${myeconfargs[@]}"
+}